[gentoo-commits] gentoo-x86 commit in media-video/mediainfo: mediainfo-0.7.41.ebuild ChangeLog mediainfo-0.7.37.ebuild

[Tim Harder (radhermit)]

radhermit    11/01/30 22:56:14

  Modified:             ChangeLog
  Added:                mediainfo-0.7.41.ebuild
  Removed:              mediainfo-0.7.37.ebuild
  Log:
  Version bump and remove old. Bump to EAPI 3 and remove static USE flag until static linking is fixed.
  
  (Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 media-video/mediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	2 Dec 2010 12:50:42 -0000	1.9
+++ ChangeLog	30 Jan 2011 22:56:14 -0000	1.10
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/mediainfo
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.9 2010/12/02 12:50:42 hwoarang Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.10 2011/01/30 22:56:14 radhermit Exp $
+
+*mediainfo-0.7.41 (30 Jan 2011)
+
+  30 Jan 2011; Tim Harder <radhermit@g.o> -mediainfo-0.7.37.ebuild,
+  +mediainfo-0.7.41.ebuild:
+  Version bump and remove old. Bump to EAPI 3 and remove static USE flag until
+  static linking is fixed.
 
   02 Dec 2010; Markos Chandras <hwoarang@g.o> mediainfo-0.7.36.ebuild:
   Stable on amd64 wrt bug #347037



1.1                  media-video/mediainfo/mediainfo-0.7.41.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/mediainfo-0.7.41.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/mediainfo-0.7.41.ebuild?rev=1.1&content-type=text/plain

Index: mediainfo-0.7.41.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/mediainfo-0.7.41.ebuild,v 1.1 2011/01/30 22:56:14 radhermit Exp $

EAPI="3"

WX_GTK_VER="2.8"
inherit autotools wxwidgets multilib

DESCRIPTION="MediaInfo supplies technical and tag information about media files"
HOMEPAGE="http://mediainfo.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl debug libmms wxwidgets"

RDEPEND="sys-libs/zlib
	media-libs/libzen
	~media-libs/lib${P}[curl=,libmms=]
	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}/MediaInfo"

pkg_setup() {
	TARGETS="CLI"
	use wxwidgets && TARGETS+=" GUI"
}

src_prepare() {
	for x in ${TARGETS}; do
		cd "${S}/Project/GNU/${x}"
		eautoreconf
	done
}

src_configure() {
	for target in ${TARGETS}; do
		cd "${S}/Project/GNU/${target}"
		local myconf=""
		[[ ${target} == "GUI" ]] && myconf="${myconf} --with-wxwidgets --with-wx-gui"
		econf \
			${myconf} \
			--disable-dependency-tracking \
			--enable-shared \
			$(use_enable debug)
	done
}

src_compile() {
	for x in ${TARGETS}; do
		cd "${S}/Project/GNU/${x}"
		emake || die "emake failed for ${x}"
	done
}
src_install() {
	for x in ${TARGETS}; do
		cd "${S}/Project/GNU/${x}"
		emake DESTDIR="${D}" install || die "emake install failed"
		dodoc "${S}/History_${x}.txt" || die
		if [[ "${x}" = "GUI" ]]; then
			newicon "${S}/Source/Ressource/Image/MediaInfo.png" "${PN}.png"
			make_desktop_entry "${PN}-gui" "MediaInfo" "${PN}" "AudioVideo;GTK;"
		fi
	done

	dodoc "${S}/"*.html || die
}