[gentoo-commits] proj/sci:master commit in: sci-libs/matc/files/, sci-libs/matc/

[Justin Lecher]

commit:     8acff37f38cdd18556e8e407434f31057240b5da
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Tue Dec  3 08:45:44 2013 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Tue Dec  3 08:45:44 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/sci.git;a=commit;h=8acff37f

sci-libs/matc: Bump EAPI; fix license; fix DESCRIPTION; drop keywords from live ebuild; use correct phase functions; simplify configure; build shared libraries

Package-Manager: portage-2.2.7

---
 sci-libs/matc/ChangeLog                     | 12 ++++++
 sci-libs/matc/files/matc-5.4.1-shared.patch | 32 ++++++++++++++++
 sci-libs/matc/matc-5.4.1-r1.ebuild          | 56 ----------------------------
 sci-libs/matc/matc-5.4.1.ebuild             | 45 ++++++++++++++++++++++
 sci-libs/matc/matc-9999.ebuild              | 58 +++++++++++++----------------
 sci-libs/matc/metadata.xml                  |  5 +++
 6 files changed, 119 insertions(+), 89 deletions(-)

diff --git a/sci-libs/matc/ChangeLog b/sci-libs/matc/ChangeLog
new file mode 100644
index 0000000..57a9966
--- /dev/null
+++ b/sci-libs/matc/ChangeLog
@@ -0,0 +1,12 @@
+# ChangeLog for sci-libs/matc
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: $
+
+*matc-5.4.1 (03 Dec 2013)
+
+  03 Dec 2013; Justin Lecher <jlec@g.o> +matc-5.4.1.ebuild,
+  -matc-5.4.1-r1.ebuild, matc-9999.ebuild, +files/matc-5.4.1-shared.patch,
+  +metadata.xml:
+  Bump EAPI; fix license; fix DESCRIPTION; drop keywords from live ebuild; use
+  correct phase functions; simplify configure; build shared libraries
+

diff --git a/sci-libs/matc/files/matc-5.4.1-shared.patch b/sci-libs/matc/files/matc-5.4.1-shared.patch
new file mode 100644
index 0000000..a2287da
--- /dev/null
+++ b/sci-libs/matc/files/matc-5.4.1-shared.patch
@@ -0,0 +1,32 @@
+ configure.in    | 2 +-
+ src/Makefile.am | 6 +++---
+ 2 files changed, 4 insertions(+), 4 deletions(-)
+
+diff --git a/configure.in b/configure.in
+index 3e5cd27..1d8b065 100755
+--- a/configure.in
++++ b/configure.in
+@@ -4,7 +4,7 @@ dnl TODO: get fortran name mangling sceme and use it in the fortran api (spfortr
+ dnl using the convenience macros provided by automake
+ 
+ AC_INIT(src/eig.c)
+-
++LT_INIT
+ AC_CANONICAL_HOST
+ AC_CANONICAL_TARGET
+ 
+diff --git a/src/Makefile.am b/src/Makefile.am
+index 2e39c11..e10a91d 100755
+--- a/src/Makefile.am
++++ b/src/Makefile.am
+@@ -45,7 +45,7 @@ matc_SOURCES = main.c
+ 
+ endif
+ 
+-matc_LDADD = libmatc.a
++matc_LDADD = libmatc.la
+ 
+-lib_LIBRARIES = libmatc.a
+-libmatc_a_SOURCES = $(COMMON_SRCS)
++lib_LTLIBRARIES = libmatc.la
++libmatc_la_SOURCES = $(COMMON_SRCS)

diff --git a/sci-libs/matc/matc-5.4.1-r1.ebuild b/sci-libs/matc/matc-5.4.1-r1.ebuild
deleted file mode 100644
index 1af24ac..0000000
--- a/sci-libs/matc/matc-5.4.1-r1.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2007 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: $
-
-EAPI="4"
-
-inherit autotools eutils
-
-ELMER_ROOT="elmerfem"
-MY_PN=${PN/elmer-/}
-
-DESCRIPTION="Elmer is a collection of finite element programs, libraries, and visualization tools, math C lib"
-HOMEPAGE="http://www.csc.fi/english/pages/elmer"
-SRC_URI="http://elmerfem.svn.sourceforge.net/viewvc/${ELMER_ROOT}/release/${PV}/${MY_PN}/?view=tar -> ${P}.tar.gz
-doc? ( http://www.nic.funet.fi/pub/sci/physics/elmer/doc/MATCManual.pdf )"
-RESTRICT="mirror"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
-IUSE="doc debug"
-DEPEND="sys-libs/ncurses
-	sys-libs/readline
-	sys-libs/glibc"
-
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/${PV}/matc"
-
-src_unpack() {
-	#unpack ${ELMER_ROOT}/${PV}.tar.gz
-	unpack ${PV}.tar.gz
-	cd "${S}"
-	# we have to make configure executable. SVN snapshot...
-	chmod +x configure
-	eautoreconf
-}
-
-src_compile() {
-	cd "${S}"
-	local myconf
-	export FC="gfortran"
-	export F77="gfortran"
-	use debug &&
-		myconf="${myconf} --with-debug" ||
-		myconf="${myconf} --without-debug"
-	econf $myconf || die "econf failed"
-	emake || die "emake failed"
-}
-
-
-src_install() {
-	insinto /usr/share/doc/${PF}
-	use doc && doins ${DISTDIR}/MATCManual.pdf
-	emake DESTDIR="${D}" install || die "emake install failed"
-}

diff --git a/sci-libs/matc/matc-5.4.1.ebuild b/sci-libs/matc/matc-5.4.1.ebuild
new file mode 100644
index 0000000..077ea63
--- /dev/null
+++ b/sci-libs/matc/matc-5.4.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils
+
+ELMER_ROOT="elmerfem"
+MY_PN=${PN/elmer-/}
+
+DESCRIPTION="Finite element programs, libraries, and visualization tools - math C library"
+HOMEPAGE="http://www.csc.fi/english/pages/elmer"
+SRC_URI="
+	http://elmerfem.svn.sourceforge.net/viewvc/${ELMER_ROOT}/release/${PV}/${MY_PN}/?view=tar -> ${P}.tar.gz
+	doc? ( http://www.nic.funet.fi/pub/sci/physics/elmer/doc/MATCManual.pdf )"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc debug static-libs"
+
+RDEPEND="
+	sys-libs/ncurses
+	sys-libs/readline"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}"/${PN}
+
+PATCHES=( "${FILESDIR}"/${P}-shared.patch )
+
+src_configure() {
+	local myeconfargs=(
+		--enable-shared
+		$(use_with debug)
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	use doc && DOCS=( "${DISTDIR}"/MATCManual.pdf )
+	autotools-utils_src_install
+}

diff --git a/sci-libs/matc/matc-9999.ebuild b/sci-libs/matc/matc-9999.ebuild
index 4868fb1..265e19a 100644
--- a/sci-libs/matc/matc-9999.ebuild
+++ b/sci-libs/matc/matc-9999.ebuild
@@ -1,58 +1,50 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
-EAPI="4"
+EAPI=5
 
-inherit autotools eutils subversion
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils subversion
 
 ELMER_ROOT="elmerfem"
 MY_PN=${PN/elmer-/}
 
-DESCRIPTION="Elmer is a collection of finite element programs, libraries, and visualization tools, math C lib"
+DESCRIPTION="Finite element programs, libraries, and visualization tools - math C library"
 HOMEPAGE="http://www.csc.fi/english/pages/elmer"
-#SRC_URI="http://elmerfem.svn.sourceforge.net/viewvc/${ELMER_ROOT}/release/${PV}/${MY_PN}/?view=tar -> ${P}.tar.gz
-#doc? ( http://www.nic.funet.fi/pub/sci/physics/elmer/doc/MATCManual.pdf )"
 SRC_URI="doc? ( http://www.nic.funet.fi/pub/sci/physics/elmer/doc/MATCManual.pdf )"
-RESTRICT="mirror"
 ESVN_REPO_URI="https://elmerfem.svn.sourceforge.net/svnroot/elmerfem/trunk/${MY_PN}"
 ESVN_PROJECT="${MY_PN}"
 
-LICENSE="GPL-2"
+LICENSE="LGPL-2.1"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
-IUSE="doc debug"
-DEPEND="sys-libs/ncurses
-	sys-libs/readline
-	sys-libs/glibc"
+KEYWORDS=""
+IUSE="doc debug static-libs"
+
+RDEPEND="
+	sys-libs/ncurses
+	sys-libs/readline"
+DEPEND="${RDEPEND}"
 
-RDEPEND="${DEPEND}"
+S="${WORKDIR}"/${PN}
 
-S="${WORKDIR}/${PV}/matc"
+PATCHES=( "${FILESDIR}"/${PN}-5.4.1-shared.patch )
 
 src_prepare() {
-	#unpack ${ELMER_ROOT}/${PV}.tar.gz
-	#unpack ${PV}.tar.gz
-	cd "${S}"
-	# we have to make configure executable. SVN snapshot...
-	#chmod +x configure
-	eautoreconf
+	subversion_src_prepare
+	autotools-utils_src_prepare
 }
 
 src_configure() {
-	cd "${S}"
-	local myconf
-	export FC="gfortran"
-	export F77="gfortran"
-	use debug &&
-		myconf="${myconf} --with-debug" ||
-		myconf="${myconf} --without-debug"
-	econf $myconf || die "econf failed"
+	local myeconfargs=(
+		--enable-shared
+		$(use_with debug)
+	)
+	autotools-utils_src_configure
 }
 
-
 src_install() {
-	insinto /usr/share/doc/${PF}
-	use doc && doins ${DISTDIR}/MATCManual.pdf
-	emake DESTDIR="${D}" install || die "emake install failed"
+	use doc && DOCS=( "${DISTDIR}"/MATCManual.pdf )
+	autotools-utils_src_install
 }

diff --git a/sci-libs/matc/metadata.xml b/sci-libs/matc/metadata.xml
new file mode 100644
index 0000000..897aa2e
--- /dev/null
+++ b/sci-libs/matc/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <herd>sci</herd>
+</pkgmetadata>