[gentoo-commits] gentoo-x86 commit in media-video/noad: ChangeLog noad-0.7.0.20100119.ebuild

[Joerg Bornkessel (hd_brummy)]

hd_brummy    10/01/31 14:57:16

  Modified:             ChangeLog
  Added:                noad-0.7.0.20100119.ebuild
  Log:
  version bump
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.36                 media-video/noad/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/noad/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/noad/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/noad/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/noad/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	7 Jan 2010 21:11:38 -0000	1.35
+++ ChangeLog	31 Jan 2010 14:57:15 -0000	1.36
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/noad
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/noad/ChangeLog,v 1.35 2010/01/07 21:11:38 hd_brummy Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/noad/ChangeLog,v 1.36 2010/01/31 14:57:15 hd_brummy Exp $
+
+*noad-0.7.0.20100119 (31 Jan 2010)
+
+  31 Jan 2010; Joerg Bornkessel <hd_brummy@g.o>
+  +noad-0.7.0.20100119.ebuild:
+  version bump
 
   07 Jan 2010; Joerg Bornkessel <hd_brummy@g.o> noad-0.7.0.ebuild:
   missing patch added



1.1                  media-video/noad/noad-0.7.0.20100119.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/noad/noad-0.7.0.20100119.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/noad/noad-0.7.0.20100119.ebuild?rev=1.1&content-type=text/plain

Index: noad-0.7.0.20100119.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/noad/noad-0.7.0.20100119.ebuild,v 1.1 2010/01/31 14:57:15 hd_brummy Exp $
EAPI="2"

WANT_AUTOMAKE="latest"
WANT_AUTOCONF="latest"

inherit eutils autotools

DESCRIPTION="Mark commercial Breaks in VDR records"
HOMEPAGE="http://noad.heliohost.org/"
SRC_URI="http://vdr.websitec.de/download/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ffmpeg imagemagick"

DEPEND="media-libs/libmpeg2
	ffmpeg? ( >=media-video/ffmpeg-0.4.8 )
	imagemagick? ( >=media-gfx/imagemagick-6.2.4.2-r1 )"
RDEPEND="${DEPEND}"

src_prepare() {

	epatch "${FILESDIR}"/patches-0.6.0/hangcheck.diff

	if has_version ">=media-video/ffmpeg-0.4.9_p20080326" ; then
		sed -e "s:include/ffmpeg:include/libavcodec:g" -i configure.ac
	fi

	rm configure
	eautoreconf
}

src_configure() {

	econf \
		$(use_with ffmpeg) \
		$(use_with imagemagick magick) \
		--with-tools \
		--with-mpeginclude=/usr/include/mpeg2dec
}

src_compile() {

	emake noad || die "emake faild"
}

src_install() {

	dobin noad
#	fix me later!
#	dobin noad showindex
#	use imagemagick && dobin markpics

	dodoc README INSTALL
	# example scripts are installed as dokumentation
	dodoc allnewnoad allnoad allnoadnice clearlogos noadifnew stat2html

	CONF_SOURCE="${FILESDIR}/0.6.0-r7"
	newconfd "${CONF_SOURCE}"/confd_vdraddon.noad vdraddon.noad

	insinto /usr/share/vdr/record
	doins "${CONF_SOURCE}"/record-50-noad.sh

	insinto /usr/share/vdr/shutdown
	doins "${FILESDIR}"/pre-shutdown-15-noad.sh

	insinto /etc/vdr/reccmds
	doins "${CONF_SOURCE}"/reccmds.noad.conf

	exeinto /usr/share/vdr/bin
	doexe "${CONF_SOURCE}"/noad-reccmd
}

pkg_postinst() {

	elog
	elog "Congratulations, you have just installed noad!,"
	elog "To integrate noad in VDR you should do this:"
	elog
	elog "start and set Parameter in /etc/conf.d/vdraddon.noad"
	elog
	elog "Note: You can use here all pararmeters for noad,"
	elog "please look in the documentation of noad."
	elog
	elog "up from this version, noad works with .ts file structur"
	elog "used in comming up version >=vdr-1.7.4"
}