[gentoo-commits] gentoo-x86 commit in media-sound/banshee: ChangeLog banshee-1.6.0.ebuild

[Arun Raghavan (ford_prefect)]

ford_prefect    10/04/01 07:55:01

  Modified:             ChangeLog
  Added:                banshee-1.6.0.ebuild
  Log:
  Bump to 1.6.0. This is the latest stable version with a huge number of new features over the 1.4.x series. Just a bunch of bug fixes over 1.5.6. Enabled the gapless playback plugin since we have the required gst-plugins-base, and dropped unnecessary deps (thanks to suka on bug #310601).
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.110                media-sound/banshee/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/banshee/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/banshee/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/banshee/ChangeLog?r1=1.109&r2=1.110

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog	25 Mar 2010 21:05:58 -0000	1.109
+++ ChangeLog	1 Apr 2010 07:55:01 -0000	1.110
@@ -1,6 +1,16 @@
 # ChangeLog for media-sound/banshee
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v 1.109 2010/03/25 21:05:58 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/ChangeLog,v 1.110 2010/04/01 07:55:01 ford_prefect Exp $
+
+*banshee-1.6.0 (01 Apr 2010)
+
+  01 Apr 2010; Arun Raghavan <ford_prefect@g.o>
+  +banshee-1.6.0.ebuild:
+  Bump to 1.6.0. This is the latest stable version with a huge number of new
+  features over the 1.4.x series. Just a bunch of bug fixes over 1.5.6.
+  Enabled the gapless playback plugin since we have the required
+  gst-plugins-base, and dropped unnecessary deps (thanks to suka on bug
+  #310601).
 
 *banshee-1.5.6 (25 Mar 2010)
 



1.1                  media-sound/banshee/banshee-1.6.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/banshee/banshee-1.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/banshee/banshee-1.6.0.ebuild?rev=1.1&content-type=text/plain

Index: banshee-1.6.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/banshee/banshee-1.6.0.ebuild,v 1.1 2010/04/01 07:55:01 ford_prefect Exp $

EAPI=2

inherit eutils mono gnome2-utils fdo-mime versionator

GVER=0.10.7

DESCRIPTION="Import, organize, play, and share your music using a simple and powerful interface."
HOMEPAGE="http://banshee-project.org"

#BANSHEE_V2=$(get_version_component_range 2)
#[[ $((${BANSHEE_V2} % 2)) -eq 0 ]] && RELTYPE=stable || RELTYPE=unstable
#SRC_URI="http://download.banshee-project.org/${PN}/${RELTYPE}/${PV}/${PN}-1-${PV}.tar.bz2"
SRC_URI="http://download.banshee-project.org/${PN}/stable/${PV}/${PN}-1-${PV}.tar.bz2"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+aac +cdda boo daap doc +encode ipod karma mtp podcast test wikipedia youtube"

RDEPEND=">=dev-lang/mono-2.4.3
	gnome-base/gnome-settings-daemon
	x11-themes/gnome-icon-theme
	sys-apps/dbus
	>=dev-dotnet/gtk-sharp-2.12
	>=dev-dotnet/gconf-sharp-2.24.0
	>=dev-dotnet/notify-sharp-0.4.0_pre20080912-r1
	>=media-libs/gstreamer-0.10.21-r3
	>=media-libs/gst-plugins-base-0.10.25.2
	>=media-libs/gst-plugins-bad-${GVER}
	>=media-libs/gst-plugins-good-${GVER}
	>=media-libs/gst-plugins-ugly-${GVER}
	>=media-plugins/gst-plugins-meta-0.10-r2:0.10
	>=media-plugins/gst-plugins-gnomevfs-${GVER}
	>=media-plugins/gst-plugins-gconf-${GVER}
	cdda? (
		|| (
			>=media-plugins/gst-plugins-cdparanoia-${GVER}
			>=media-plugins/gst-plugins-cdio-${GVER}
		)
	)
	media-libs/musicbrainz:1
	>=dev-dotnet/dbus-glib-sharp-0.4.1
	>=dev-dotnet/dbus-sharp-0.6.1a
	>=dev-dotnet/mono-addins-0.4[gtk]
	>=dev-dotnet/taglib-sharp-2.0.3.7
	>=dev-db/sqlite-3.4
	karma? ( >=media-libs/libkarma-0.1.0-r1 )
	aac? ( >=media-plugins/gst-plugins-faad-${GVER} )
	boo? (
		>=dev-lang/boo-0.8.1
	)
	daap? (
		>=dev-dotnet/mono-zeroconf-0.8.0-r1
	)
	doc? (
		virtual/monodoc
	)
	encode? (
		>=media-plugins/gst-plugins-lame-${GVER}
		>=media-plugins/gst-plugins-taglib-${GVER}
	)
	ipod? (
		>=dev-dotnet/ipod-sharp-0.8.5
	)
	mtp? (
		media-libs/libmtp
	)
	wikipedia? (
		>=dev-dotnet/webkit-sharp-0.2
	)
	youtube? (
		>=dev-dotnet/google-gdata-sharp-1.4
	)"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

DOCS="AUTHORS ChangeLog HACKING NEWS README"

S=${WORKDIR}/${PN}-1-${PV}

src_configure() {
	local myconf="--disable-dependency-tracking --disable-static
		--enable-gnome --enable-schemas-install
		--with-gconf-schema-file-dir=/etc/gconf/schemas
		--with-vendor-build-id=Gentoo/${PN}/${PVR}
		--enable-gapless-playback
		--disable-torrent
		--disable-shave"

	econf \
		$(use_enable doc docs) \
		$(use_enable boo) \
		$(use_enable mtp) \
		$(use_enable daap) \
		$(use_enable ipod) \
		$(use_enable podcast) \
		$(use_enable karma) \
		$(use_enable wikipedia webkit) \
		$(use_enable youtube) \
		${myconf}
}

src_compile() {
	emake MCS=/usr/bin/gmcs
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install efailed"
	find "${D}" -name '*.la' -delete
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	ewarn
	ewarn "If ${PN} doesn't play some format, please check your"
	ewarn "USE flags on media-plugins/gst-plugins-meta"
	ewarn

	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}