[gentoo-commits] gentoo-x86 commit in x11-misc/redshift: redshift-1.5.ebuild ChangeLog

[Dror Levin (spatz)]

spatz       10/08/30 17:14:58

  Modified:             ChangeLog
  Added:                redshift-1.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2_rc72/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  x11-misc/redshift/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	31 Jul 2010 17:32:31 -0000	1.3
+++ ChangeLog	30 Aug 2010 17:14:58 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/redshift
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.3 2010/07/31 17:32:31 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.4 2010/08/30 17:14:58 spatz Exp $
+
+*redshift-1.5 (30 Aug 2010)
+
+  30 Aug 2010; Dror Levin <spatz@g.o> +redshift-1.5.ebuild:
+  Version bump.
 
   31 Jul 2010; Markos Chandras <hwoarang@g.o> redshift-1.4.1.ebuild:
   Stable on amd64 wrt bug #330347



1.1                  x11-misc/redshift/redshift-1.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.5.ebuild?rev=1.1&content-type=text/plain

Index: redshift-1.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/redshift-1.5.ebuild,v 1.1 2010/08/30 17:14:58 spatz Exp $

EAPI=3

PYTHON_DEPEND="gtk? 2:2.6"

inherit gnome2-utils python

DESCRIPTION="A screen color temperature adjusting software"
HOMEPAGE="http://jonls.dk/redshift/"
SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnome gtk nls"

COMMON_DEPEND="x11-libs/libX11[xcb]
	x11-libs/libXxf86vm
	x11-libs/libxcb
	gnome? ( dev-libs/glib:2
		>=gnome-base/gconf-2 )"
RDEPEND="${COMMON_DEPEND}
	gtk? ( >=dev-python/pygtk-2
		dev-python/pyxdg )"
DEPEND="${COMMON_DEPEND}
	nls? ( sys-devel/gettext )"

pkg_setup() {
	use gtk && python_set_active_version 2
}

src_prepare() {
	if use gtk; then
		ln -nfs $(type -P true) py-compile || die
		python_convert_shebangs 2 src/gtk-redshift/gtk-redshift
	fi
}

src_configure() {
	local myconf
	use gtk || myconf="--enable-gui=none"

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-randr \
		--enable-vidmode \
		$(use_enable gnome gnome-clock) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	use gtk && python_mod_optimize gtk_${PN}
}

pkg_postrm() {
	gnome2_icon_cache_update
	use gtk && python_mod_cleanup gtk_${PN}
}