[gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: ChangeLog opendkim-1.2.1.ebuild opendkim-1.2.0.ebuild opendkim-1.1.0.ebuild

[Daniel Black (dragonheart)]

dragonheart    10/01/08 13:12:45

  Modified:             ChangeLog
  Added:                opendkim-1.2.1.ebuild
  Removed:              opendkim-1.2.0.ebuild opendkim-1.1.0.ebuild
  Log:
  remove 1.2.0 - few too many bugs. remove old 1.1.0 version too. Thanks Diego for QA bug 299881. Petteri for bugs 297703 and 297698 related to emerge --config section and 297700 released to a broken statistics function upstream.
  (Portage version: 2.2_rc61/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  mail-filter/opendkim/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/opendkim/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	14 Dec 2009 03:05:11 -0000	1.4
+++ ChangeLog	8 Jan 2010 13:12:45 -0000	1.5
@@ -1,6 +1,19 @@
 # ChangeLog for mail-filter/opendkim
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.4 2009/12/14 03:05:11 dragonheart Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.5 2010/01/08 13:12:45 dragonheart Exp $
+
+*opendkim-1.2.1 (08 Jan 2010)
+
+  08 Jan 2010; Daniel Black <dragonheart@g.o> -opendkim-1.1.0.ebuild,
+  -files/opendkim-1.1.0-autoconf-automake.patch,
+  -files/opendkim-1.1.0-flockinclude.patch,
+  -files/opendkim-1.1.0-rep-querycache.patch,
+  -files/opendkim-1.1.0-vbr-booliscpp.patch, -opendkim-1.2.0.ebuild,
+  +opendkim-1.2.1.ebuild:
+  remove 1.2.0 - few too many bugs. remove old 1.1.0 version too. Thanks
+  Diego for QA bug 299881. Petteri for bugs 297703 and 297698 related to
+  emerge --config section and 297700 released to a broken statistics
+  function upstream.
 
 *opendkim-1.2.0 (14 Dec 2009)
 



1.1                  mail-filter/opendkim/opendkim-1.2.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/opendkim/opendkim-1.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-filter/opendkim/opendkim-1.2.1.ebuild?rev=1.1&content-type=text/plain

Index: opendkim-1.2.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-1.2.1.ebuild,v 1.1 2010/01/08 13:12:45 dragonheart Exp $

EAPI="2"

inherit eutils

DESCRIPTION="A milter-based application to provide DKIM signing and verification"
HOMEPAGE="http://opendkim.org"
SRC_URI="mirror://sourceforge/opendkim/${P}.tar.gz"

LICENSE="Sendmail-Open-Source BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+db asyncdns opendbx"

# FUTURE: unbound (dnssec lib) - bug #223103
# FUTURE: diffheaders (libtre error) - bug #296813

DEPEND="dev-libs/openssl
	db? ( >=sys-libs/db-3.2 )
	|| ( mail-filter/libmilter mail-mta/sendmail )
	opendbx? ( >=dev-db/opendbx-1.4.0 )"
#	diffheaders? ( dev-libs/tre )
RDEPEND="${DEPEND}"

pkg_setup() {
	enewgroup milter
	# mail-milter/spamass-milter creates milter user with this home directory
	# For consistency reasons, milter user must be created here with this home directory
	# even though this package doesn't need a home directory for this user (#280571)
	enewuser milter -1 -1 /var/lib/milter milter
}

src_prepare() {
	sed -i -e 's:/var/db/dkim:/etc/opendkim:g' \
	       -e 's:/etc/mail:/etc/opendkim:g' \
		   opendkim/opendkim.conf.sample
}

src_configure() {
	econf $(use_enable db bodylength_db) \
		$(use_enable db popauth) \
		$(use_enable db query_cache) \
		$(use_enable db report_intervals) \
		$(use_enable db stats) \
		$(use_enable asyncdns arlib) \
		$(use_enable asyncdns dnsupgrade) \
		$(use_with opendbx odbx) \
		--without-domainkeys \
		--enable-capture_unknown_errors \
		--enable-dkim_reputation \
		--enable-identity_header \
		--enable-redirect \
		--enable-resign \
		--enable-replace_rules \
		--enable-select_canonicalization \
		--enable-selector_header \
		--enable-sender_macro \
		--enable-vbr \
		--enable-ztags
#		$(use_enable diffheaders) \
}

src_install() {
	emake DESTDIR="${D}" install
	# file collision
	rm "${D}"/usr/share/man/man3/ar.3
	mv "${D}"/usr/share/doc/opendkim "${D}"/usr/share/doc/${PF}

	newinitd "${FILESDIR}/opendkim.init" opendkim
	dodir /etc/opendkim /var/run/opendkim /var/lib/opendkim
	fowners milter:milter /var/run/opendkim /etc/opendkim /var/lib/opendkim

	# default configuration
	if [ ! -f /etc/opendkim/opendkim.conf ]; then
		grep ^[^#] "${S}"/opendkim/opendkim.conf.sample \
			> "${D}"/etc/opendkim/opendkim.conf
		echo \# Socket local:/var/run/opendkim/opendkim.sock >> \
			"${D}"/etc/opendkim/opendkim.conf
		echo UserID milter >> "${D}"/etc/opendkim/opendkim.conf
		if use db; then
			echo Statistics /var/lib/opendkim/stats.db >> \
				"${D}"/etc/opendkim/opendkim.conf
		fi
	fi
}

pkg_postinst() {
	elog "If you want to sign your mail messages, you will have to run"
	elog "  emerge --config ${CATEGORY}/${PN}"
	elog "It will help you create your key and give you hints on how"
	elog "to configure your DNS and MTA."

	ewarn "Make sure your MTA has r/w access to the socket file."
	ewarn "This can be done either by setting UMask to 002 and adding MTA's user"
	ewarn "to milter group or you can simply set UMask to 000."
}

pkg_config() {
	local selector keysize pubkey

	read -p "Enter the selector name (default ${HOSTNAME}): " selector
	[[ -n "${selector}" ]] || selector=${HOSTNAME}
	if [[ -z "${selector}" ]]; then
		eerror "Oddly enough, you don't have a HOSTNAME."
		return 1
	fi
	if [[ -f "${ROOT}"etc/opendkim/${selector}.private ]]; then
		ewarn "The private key for this selector already exists."
	else
		einfo "Select the size of private key:"
		einfo "  [1] 512 bits"
		einfo "  [2] 1024 bits"
		while read -n 1 -s -p "  Press 1 or 2 on the keyboard to select the key size " keysize ; do
			[[ "${keysize}" == "1" || "${keysize}" == "2" ]] && echo && break
		done
		case ${keysize} in
			1) keysize=512 ;;
			*) keysize=1024 ;;
		esac

		# generate the private and public keys
		opendkim-genkey.sh -b ${keysize} -D "${ROOT}"etc/opendkim/ \
			-s ${selector} -d '(your domain)' && \
			chown milter:milter \
			"${ROOT}"etc/opendkim/"${selector}".private || \
				{ eerror "Failed to create private and public keys." ; return 1; }
		chmod go-r "${ROOT}"etc/opendkim/"${selector}".private
	fi

	# opendkim selector configuration
	echo
	einfo "Make sure you have the following settings in your /etc/opendkim/opendkim.conf:"
	einfo "  Keyfile /etc/opendkim/${selector}.private"
	einfo "  Selector ${selector}"

	# MTA configuration
	echo
	einfo "If you are using Postfix, add following lines to your main.cf:"
	einfo "  smtpd_milters     = unix:/var/run/opendkim/opendkim.sock"
	einfo "  non_smtpd_milters = unix:/var/run/opendkim/opendkim.sock"

	# DNS configuration
	einfo "After you configured your MTA, publish your key by adding this TXT record to your domain:"
	cat "${ROOT}"etc/opendkim/${selector}.txt
	einfo "t=y signifies you only test the DKIM on your domain. See following page for the complete list of tags:"
	einfo "  http://www.dkim.org/specs/rfc4871-dkimbase.html#key-text"
	einfo
	einfo "Also look at the ADSP http://tools.ietf.org/html/rfc5617"
}