[gentoo-commits] gentoo-x86 commit in gnome-base/gvfs: ChangeLog gvfs-1.14.2.ebuild gvfs-1.14.0.ebuild gvfs-1.12.2-r1.ebuild gvfs-1.10.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         12/11/22 23:09:01

  Modified:             ChangeLog
  Added:                gvfs-1.14.2.ebuild
  Removed:              gvfs-1.14.0.ebuild gvfs-1.12.2-r1.ebuild
                        gvfs-1.10.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.193                gnome-base/gvfs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gvfs/ChangeLog?rev=1.193&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gvfs/ChangeLog?rev=1.193&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gvfs/ChangeLog?r1=1.192&r2=1.193

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v
retrieving revision 1.192
retrieving revision 1.193
diff -u -r1.192 -r1.193
--- ChangeLog	28 Oct 2012 21:55:05 -0000	1.192
+++ ChangeLog	22 Nov 2012 23:09:01 -0000	1.193
@@ -1,6 +1,15 @@
 # ChangeLog for gnome-base/gvfs
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.192 2012/10/28 21:55:05 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.193 2012/11/22 23:09:01 eva Exp $
+
+*gvfs-1.14.2 (22 Nov 2012)
+
+  22 Nov 2012; Gilles Dartiguelongue <eva@g.o> -gvfs-1.10.1.ebuild,
+  -files/gvfs-1.10.1-libimobiledevice-1.1.2.patch,
+  -files/gvfs-1.10.1-unneeded-include.patch, -gvfs-1.12.2-r1.ebuild,
+  -files/gvfs-1.12.2-afp-g_clear_object.patch, -gvfs-1.14.0.ebuild,
+  +gvfs-1.14.2.ebuild:
+  Version bump.
 
 *gvfs-1.14.1 (28 Oct 2012)
 



1.1                  gnome-base/gvfs/gvfs-1.14.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gvfs/gvfs-1.14.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gvfs/gvfs-1.14.2.ebuild?rev=1.1&content-type=text/plain

Index: gvfs-1.14.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/gvfs-1.14.2.ebuild,v 1.1 2012/11/22 23:09:01 eva Exp $

EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"

inherit autotools bash-completion-r1 eutils gnome2
if [[ ${PV} = 9999 ]]; then
	inherit gnome2-live
fi

DESCRIPTION="GNOME Virtual Filesystem Layer"
HOMEPAGE="http://www.gnome.org"

LICENSE="LGPL-2+"
SLOT="0"

if [[ ${PV} = 9999 ]]; then
	KEYWORDS=""
	DOCS=""
else
	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
	DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README TODO" # ChangeLog.pre-1.2 README.commits
fi

SRC_URI="${SRC_URI}
	http://dev.gentoo.org/~tetromino/distfiles/aclocal/libgcrypt.m4.bz2"

IUSE="afp archive avahi bluetooth bluray cdda doc fuse gdu gnome-keyring gphoto2 gtk +http ios samba systemd +udev udisks"
REQUIRED_USE="systemd? ( udisks )"

# Can use libgphoto-2.5.0 as well. Automagic detection.
RDEPEND=">=dev-libs/glib-2.33.12:2
	sys-apps/dbus
	dev-libs/libxml2:2
	net-misc/openssh
	afp? ( >=dev-libs/libgcrypt-1.2.2 )
	archive? ( app-arch/libarchive )
	avahi? ( >=net-dns/avahi-0.6 )
	bluetooth? (
		>=app-mobilephone/obex-data-server-0.4.5
		dev-libs/dbus-glib
		net-wireless/bluez
		dev-libs/expat )
	bluray? ( media-libs/libbluray )
	fuse? ( >=sys-fs/fuse-2.8.0 )
	gdu? ( || (
		>=gnome-base/libgdu-3.0.2
		=sys-apps/gnome-disk-utility-3.0.2-r300
		=sys-apps/gnome-disk-utility-3.0.2-r200 ) )
	gnome-keyring? ( app-crypt/libsecret )
	gphoto2? ( >=media-libs/libgphoto2-2.4.7 )
	gtk? ( >=x11-libs/gtk+-3.0:3 )
	http? ( >=net-libs/libsoup-gnome-2.26.0 )
	ios? (
		>=app-pda/libimobiledevice-1.1.0
		>=app-pda/libplist-1 )
	samba? ( >=net-fs/samba-3.4.6[smbclient] )
	systemd? ( sys-apps/systemd )
	udev? (
		cdda? ( >=dev-libs/libcdio-0.78.2[-minimal] )
		|| ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-164-r2[extras] ) )
	udisks? ( >=sys-fs/udisks-1.97:2[systemd?] )"
DEPEND="${RDEPEND}
	dev-libs/libxslt
	>=dev-util/intltool-0.40
	virtual/pkgconfig
	dev-util/gtk-doc-am
	doc? ( >=dev-util/gtk-doc-1 )"

REQUIRED_USE="cdda? ( udev )"

src_prepare() {
	if use archive; then
		epatch "${FILESDIR}"/${PN}-1.2.2-expose-archive-backend.patch
		echo mount-archive.desktop.in >> po/POTFILES.in
		echo mount-archive.desktop.in.in >> po/POTFILES.in
	fi

	if ! use udev; then
		sed -e 's/gvfsd-burn/ /' \
			-e 's/burn.mount.in/ /' \
			-e 's/burn.mount/ /' \
			-i daemon/Makefile.am || die
	fi

	if use archive || ! use udev; then
		# libgcrypt.m4 needed for eautoreconf, bug #399043
		mv "${WORKDIR}/libgcrypt.m4" "${S}"/ || die

		[[ ${PV} = 9999 ]] || AT_M4DIR=. eautoreconf
	fi

	gnome2_src_prepare
}

src_configure() {
	# --enable-documentation installs man pages
	G2CONF="${G2CONF}
		--disable-bash-completion
		--disable-hal
		--with-dbus-service-dir="${EPREFIX}"/usr/share/dbus-1/services
		--enable-documentation
		$(use_enable afp)
		$(use_enable archive)
		$(use_enable avahi)
		$(use_enable bluetooth obexftp)
		$(use_enable bluray)
		$(use_enable cdda)
		$(use_enable fuse)
		$(use_enable gdu)
		$(use_enable gphoto2)
		$(use_enable gtk)
		$(use_enable ios afc)
		$(use_enable udev)
		$(use_enable udev gudev)
		$(use_enable http)
		$(use_enable gnome-keyring keyring)
		$(use_enable samba)
		$(use_enable systemd libsystemd-login)
		$(use_enable udisks udisks2)"
	gnome2_src_configure
}

src_install() {
	gnome2_src_install
	dobashcomp programs/completion/gvfs
}