[gentoo-commits] gentoo-x86 commit in app-forensics/openscap: openscap-1.0.8-r1.ebuild openscap-9999.ebuild ChangeLog openscap-1.0.8.ebuild openscap-1.0.1.ebuild

[Michal Gorny (mgorny)]

mgorny      14/08/27 18:26:53

  Modified:             openscap-9999.ebuild ChangeLog
  Added:                openscap-1.0.8-r1.ebuild
  Removed:              openscap-1.0.8.ebuild openscap-1.0.1.ebuild
  Log:
  Fix Python support. Remove USE=bash-completion and install the completion unconditionally. Remove redundant ||dies.
  
  (Portage version: 2.2.11_p165/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.6                  app-forensics/openscap/openscap-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-9999.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-9999.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-9999.ebuild?r1=1.5&r2=1.6

Index: openscap-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-forensics/openscap/openscap-9999.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- openscap-9999.ebuild	2 Apr 2014 18:11:50 -0000	1.5
+++ openscap-9999.ebuild	27 Aug 2014 18:26:53 -0000	1.6
@@ -1,13 +1,12 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/openscap-9999.ebuild,v 1.5 2014/04/02 18:11:50 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/openscap-9999.ebuild,v 1.6 2014/08/27 18:26:53 mgorny Exp $
 
 EAPI=5
 
-PYTHON_DEPEND="2"
 PYTHON_COMPAT=( python{2_5,2_6,2_7} )
 
-inherit bash-completion-r1 eutils multilib python-r1
+inherit bash-completion-r1 eutils multilib python-single-r1
 
 DESCRIPTION="Framework which enables integration with the Security Content Automation Protocol (SCAP)"
 HOMEPAGE="http://www.open-scap.org/"
@@ -25,7 +24,7 @@
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-IUSE="acl bash-completion caps debug doc gconf ldap nss pcre perl python rpm selinux sce sql test xattr"
+IUSE="acl caps debug doc gconf ldap nss pcre perl python rpm selinux sce sql test xattr"
 #RESTRICT="test"
 
 RDEPEND="!nss? ( dev-libs/libgcrypt:0 )
@@ -41,7 +40,8 @@
 	dev-libs/libpcre
 	dev-libs/libxml2
 	dev-libs/libxslt
-	net-misc/curl"
+	net-misc/curl
+	${PYTHON_DEPS}"
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )
 	perl? ( dev-lang/swig )
@@ -59,6 +59,8 @@
 	fi
 }
 
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
 src_prepare() {
 #	uncoment for debugging test
 #	sed -i 's,set -e,&;set -x,'	tests/API/XCCDF/unittests/test_remediate_simple.sh || die
@@ -147,14 +149,12 @@
 }
 
 src_install() {
-	emake install DESTDIR="${D}" || die
-	find "${D}" -name '*.la' -delete || die
+	emake install DESTDIR="${D}"
+	prune_libtool_files --all
 	if use doc ; then
-		dohtml -r docs/html/* || die
-		dodoc docs/examples/* || die
-	fi
-	if use bash-completion ; then
-		dobashcomp "${D}"/etc/bash_completion.d/oscap
+		dohtml -r docs/html/.
+		dodoc docs/examples/.
 	fi
+	dobashcomp "${D}"/etc/bash_completion.d/oscap
 	rm -rf "${D}"/etc/bash_completion.d || die
 }



1.30                 app-forensics/openscap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-forensics/openscap/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	2 Apr 2014 18:11:50 -0000	1.29
+++ ChangeLog	27 Aug 2014 18:26:53 -0000	1.30
@@ -1,6 +1,13 @@
 # ChangeLog for app-forensics/openscap
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/ChangeLog,v 1.29 2014/04/02 18:11:50 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/ChangeLog,v 1.30 2014/08/27 18:26:53 mgorny Exp $
+
+*openscap-1.0.8-r1 (27 Aug 2014)
+
+  27 Aug 2014; Michał Górny <mgorny@g.o> +openscap-1.0.8-r1.ebuild,
+  -openscap-1.0.1.ebuild, -openscap-1.0.8.ebuild, openscap-9999.ebuild:
+  Fix Python support. Remove USE=bash-completion and install the completion
+  unconditionally. Remove redundant ||dies.
 
   02 Apr 2014; Sven Vermeulen <swift@g.o> -openscap-0.9.8.ebuild,
   -openscap-0.9.12.ebuild, +openscap-1.0.8.ebuild, openscap-9999.ebuild:



1.1                  app-forensics/openscap/openscap-1.0.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-1.0.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-1.0.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: openscap-1.0.8-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/openscap-1.0.8-r1.ebuild,v 1.1 2014/08/27 18:26:53 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7} )

inherit bash-completion-r1 eutils multilib python-single-r1

DESCRIPTION="Framework which enables integration with the Security Content Automation Protocol (SCAP)"
HOMEPAGE="http://www.open-scap.org/"
SRC_URI="https://fedorahosted.org/releases/o/p/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="acl caps debug doc gconf ldap nss pcre perl python rpm selinux sce sql test xattr"
#RESTRICT="test"

RDEPEND="!nss? ( dev-libs/libgcrypt:0 )
	nss? ( dev-libs/nss )
	acl? ( virtual/acl )
	caps? ( sys-libs/libcap )
	gconf? ( gnome-base/gconf )
	ldap? ( net-nds/openldap )
	pcre? ( dev-libs/libpcre )
	rpm? ( >=app-arch/rpm-4.9 )
	sql? ( dev-db/opendbx )
	xattr? ( sys-apps/attr )
	dev-libs/libpcre
	dev-libs/libxml2
	dev-libs/libxslt
	net-misc/curl
	${PYTHON_DEPS}"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	perl? ( dev-lang/swig )
	python? ( dev-lang/swig )
	test? (
		app-arch/unzip
		dev-perl/XML-XPath
		net-misc/ipcalc
		sys-apps/grep )"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

src_prepare() {
#	uncoment for debugging test
#	sed -i 's,set -e,&;set -x,'	tests/API/XCCDF/unittests/test_remediate_simple.sh || die
#	sed -i 's,^    bash,    LC_ALL=C bash,'	tests/probes/process/test_probes_process.sh || die

	sed -i 's/uname -p/uname -m/' tests/probes/uname/test_probes_uname.xml.sh || die

	#probe runlevel for non-centos/redhat/fedora is not implemented
	sed -i 's,.*runlevel_test.*,echo "runlevel test bypassed",' tests/mitre/test_mitre.sh || die
	sed -i 's,probecheck "runlevel,probecheck "runlevellllll,' tests/probes/runlevel/test_probes_runlevel.sh || die

	#According to comment of theses tests, we must modify it. For the moment disable it
	sed -i 's,.*linux-def_inetlisteningservers_test,#&,' tests/mitre/test_mitre.sh || die
	sed -i 's,.*ind-def_environmentvariable_test,#&,' tests/mitre/test_mitre.sh || die

	# theses tests are hardcoded for checking hald process...,
	# but no good solution for the moment, disabling them with a fake echo
	# because encased in a if then
#	sed -i 's,ha.d,/sbin/udevd --daemon,g' tests/mitre/unix-def_process_test.xml || die
#	sed -i 's,ha.d,/sbin/udevd --daemon,g' tests/mitre/unix-def_process58_test.xml || die
	sed -i 's,.*process_test.*,echo "process test bypassed",' tests/mitre/test_mitre.sh || die
	sed -i 's,.*process58_test.*,echo "process58 test bypassed",' tests/mitre/test_mitre.sh || die

	#This test fail
	sed -i 's,.*generate report: xccdf,#&,' tests/API/XCCDF/unittests/all.sh ||	die

	if ! use rpm ; then
		sed -i 's,probe_rpminfo_req_deps_ok=yes,probe_rpminfo_req_deps_ok=no,' configure || die
		sed -i 's,probe_rpminfo_opt_deps_ok=yes,probe_rpminfo_opt_deps_ok=no,' configure || die
		sed -i 's,probe_rpmverify_req_deps_ok=yes,probe_rpmverify_req_deps_ok=no,' configure || die
		sed -i 's,probe_rpmverify_opt_deps_ok=yes,probe_rpmverify_opt_deps_ok=no,' configure || die
		sed -i 's,^probe_rpm.*_deps_missing=,&disabled_by_USE_flag,' configure || die
		sed -i 's,.*rpm.*,#&,' tests/mitre/test_mitre.sh || die
	fi
	if ! use selinux ; then
		einfo "Disabling SELinux probes"
		sed -i 's,.*selinux.*,	echo "SELinux test bypassed",' tests/mitre/test_mitre.sh || die
		#process58 need selinux
		sed -i 's,.*process58,#&,' tests/mitre/test_mitre.sh || die
	fi
	if ! use ldap; then
		einfo "Disabling LDAP probes"
		sed -i 's,ldap.h,ldapp.h,g' configure || die
	fi

	epatch_user
}

src_configure() {
	python_setup
	local myconf
	if use debug ; then
		myconf+=" --enable-debug"
	fi
	if use python ; then
		myconf+=" --enable-python"
	else
		myconf+=" --enable-python=no"
	fi
	if use perl ; then
		myconf+=" --enable-perl"
	fi
	if use nss ; then
		myconf+=" --with-crypto=nss3"
	else
		myconf+=" --with-crypto=gcrypt"
	fi
	if use sce ; then
		myconf+=" --enable-sce"
	else
		myconf+=" --enable-sce=no"
	fi
	econf ${myconf}
}

src_compile() {
	emake
	if use doc ; then
		cd docs && doxygen Doxyfile || die
	fi
}

src_install() {
	emake install DESTDIR="${D}"
	prune_libtool_files --all
	if use doc ; then
		dohtml -r docs/html/.
		dodoc docs/examples/.
	fi
	dobashcomp "${D}"/etc/bash_completion.d/oscap
	rm -rf "${D}"/etc/bash_completion.d || die
}