[gentoo-commits] gentoo-x86 commit in dev-libs/libhid: ChangeLog libhid-0.2.16-r2.ebuild libhid-0.2.16-r1.ebuild

[Matsuu Takuto (matsuu)]

matsuu      10/04/04 14:56:17

  Modified:             ChangeLog
  Added:                libhid-0.2.16-r2.ebuild
  Removed:              libhid-0.2.16-r1.ebuild
  Log:
  Removed -Werror, bug #260884. Fixed python dependency, bug #312189.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  dev-libs/libhid/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libhid/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libhid/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libhid/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libhid/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	23 Sep 2009 23:53:21 -0000	1.2
+++ ChangeLog	4 Apr 2010 14:56:17 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libhid
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libhid/ChangeLog,v 1.2 2009/09/23 23:53:21 matsuu Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libhid/ChangeLog,v 1.3 2010/04/04 14:56:17 matsuu Exp $
+
+*libhid-0.2.16-r2 (04 Apr 2010)
+
+  04 Apr 2010; MATSUU Takuto <matsuu@g.o> -libhid-0.2.16-r1.ebuild,
+  +libhid-0.2.16-r2.ebuild:
+  Removed -Werror, bug #260884. Fixed python dependency, bug #312189.
 
 *libhid-0.2.16-r1 (23 Sep 2009)
 



1.1                  dev-libs/libhid/libhid-0.2.16-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libhid/libhid-0.2.16-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libhid/libhid-0.2.16-r2.ebuild?rev=1.1&content-type=text/plain

Index: libhid-0.2.16-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libhid/libhid-0.2.16-r2.ebuild,v 1.1 2010/04/04 14:56:17 matsuu Exp $

EAPI="2"

PYTHON_DEPEND="python? 2"

inherit autotools python

DESCRIPTION="Provides a generic and flexible way to access and interact with USB HID devices"
HOMEPAGE="http://libhid.alioth.debian.org/"
SRC_URI="http://beta.magicaltux.net/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc python"

RDEPEND="virtual/libusb:0"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	python? ( dev-lang/swig )"

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	# Bug #260884
	sed -i -e 's/-Werror//' m4/md_conf_compiler.m4 || die
	eautoconf
}

src_configure() {
	local myconf

	myconf="${myconf} $(use_with doc doxygen)"
	myconf="${myconf} $(use_enable debug)"
	myconf="${myconf} $(use_enable python swig)"

	if use python; then
		# libhid includes its own python detection m4 from
		# http://autoconf-archive.cryp.to/ac_python_devel.html
		# As it seems to detect python in the wrong place, we'll force it by
		# passing the right environnement variables, only if we have the python
		# flag
		PYTHON_LDFLAGS="$(python-config --ldflags)" econf ${myconf} || die
	else
		# avoid libhid running swig if it finds it automatically as long as the
		# "python" use flag is not set
		econf ${myconf} || die
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"

	dodoc AUTHORS ChangeLog NEWS README README.licence TODO || die
	if use doc; then
		dohtml -r doc/html/* || die
	fi
}