[gentoo-commits] gentoo-x86 commit in sys-apps/less: less-479.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/07/07 04:18:22

  Modified:             ChangeLog
  Added:                less-479.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.199                sys-apps/less/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.199&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.199&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?r1=1.198&r2=1.199

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v
retrieving revision 1.198
retrieving revision 1.199
diff -u -r1.198 -r1.199
--- ChangeLog	7 Jul 2015 04:18:03 -0000	1.198
+++ ChangeLog	7 Jul 2015 04:18:22 -0000	1.199
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/less
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.198 2015/07/07 04:18:03 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.199 2015/07/07 04:18:22 vapier Exp $
+
+*less-479 (07 Jul 2015)
+
+  07 Jul 2015; Mike Frysinger <vapier@g.o> +less-479.ebuild:
+  Version bump.
 
   07 Jul 2015; Mike Frysinger <vapier@g.o> less-478.ebuild:
   Mark arm64/ia64/m68k/s390/sh stable #553692.



1.1                  sys-apps/less/less-479.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-479.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-479.ebuild?rev=1.1&content-type=text/plain

Index: less-479.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/less-479.ebuild,v 1.1 2015/07/07 04:18:22 vapier Exp $

EAPI="4"

inherit eutils

CODE2COLOR_PV="0.2"
CODE2COLOR_P="code2color-${CODE2COLOR_PV}"
DESCRIPTION="Excellent text file viewer"
HOMEPAGE="http://www.greenwoodsoftware.com/less/"
SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz
	http://www-zeuthen.desy.de/~friebel/unix/less/code2color -> ${CODE2COLOR_P}"

LICENSE="|| ( GPL-3 BSD-2 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="pcre unicode"

DEPEND=">=app-misc/editor-wrapper-3
	>=sys-libs/ncurses-5.2
	pcre? ( dev-libs/libpcre )"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${P}.tar.gz
	cp "${DISTDIR}"/${CODE2COLOR_P} "${S}"/code2color || die
}

src_prepare() {
	epatch "${FILESDIR}"/${CODE2COLOR_P}.patch
	chmod a+x configure || die
}

src_configure() {
	export ac_cv_lib_ncursesw_initscr=$(usex unicode)
	export ac_cv_lib_ncurses_initscr=$(usex !unicode)
	econf \
		--with-regex=$(usex pcre pcre posix) \
		--with-editor="${EPREFIX}"/usr/libexec/editor
}

src_install() {
	default

	dobin code2color
	newbin "${FILESDIR}"/lesspipe.sh lesspipe
	dosym lesspipe /usr/bin/lesspipe.sh
	newenvd "${FILESDIR}"/less.envd 70less

	dodoc "${FILESDIR}"/README.Gentoo
}

pkg_postinst() {
	elog "lesspipe offers colorization options.  Run 'lesspipe -h' for info."
}