[gentoo-commits] gentoo-x86 commit in sys-apps/kmscon: metadata.xml kmscon-7.ebuild ChangeLog

[Alexey Shvetsov (alexxy)]

alexxy      13/03/27 04:08:22

  Added:                metadata.xml kmscon-7.ebuild ChangeLog
  Log:
  Import to tree bug #431872
  
  (Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key F82F92E6)

Revision  Changes    Path
1.1                  sys-apps/kmscon/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmscon/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmscon/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>x11</herd>
	<use>
		<flag name='drm'>Enable Linux DRM for backend</flag>
		<flag name='fbdev'>Enable Linux FBDev for backend</flag>
		<flag name='gles2'>Enable GLES2 for backend</flag>
		<flag name='pango'>Enable pango font rendering</flag>
		<flag name='pixman'>Enable pixman font rendering</flag>
		<flag name='multiseat'>Enable multiseat support via systemd</flag>
		<flag name='optimizations'>Enable optimizations</flag>
	</use>
</pkgmetadata>



1.1                  sys-apps/kmscon/kmscon-7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmscon/kmscon-7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmscon/kmscon-7.ebuild?rev=1.1&content-type=text/plain

Index: kmscon-7.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmscon/kmscon-7.ebuild,v 1.1 2013/03/27 04:08:22 alexxy Exp $

EAPI=5

if [[ $PV = *9999* ]]; then
	scm_eclass=git-2
	EGIT_REPO_URI="
				git://people.freedesktop.org/~dvdhrm/${PN}
				git://github.com/dvdhrm/${PN}.git
				git://github.com/dvdhrm/${PN}.git"
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://www.freedesktop.org/software/${PN}/releases/${P}.tar.bz2"
	KEYWORDS="~amd64 ~x86"
fi

inherit eutils autotools systemd flag-o-matic ${scm_eclass}

DESCRIPTION="KMS/DRM based virtual Console Emulator"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/kmscon"

LICENSE="MIT LGPL-2.1 BSD-2"
SLOT="0"
IUSE="cairo dbus debug doc +drm +fbdev +gles2 multiseat +optimizations +pango pixman
static-libs systemd truetype udev +unicode wayland"

RDEPEND="
	dev-libs/glib:2
	>=virtual/udev-172
	x11-libs/libxkbcommon
	dbus? ( sys-apps/dbus )
	drm? ( x11-libs/libdrm
		>=media-libs/mesa-8.0.3[egl,gbm] )
	truetype? ( media-libs/freetype:2 )
	gles2? ( >=media-libs/mesa-8.0.3[gles2] )
	pango? ( x11-libs/pango )
	systemd? ( sys-apps/systemd )
	udev? ( virtual/udev )
	cairo? ( x11-libs/cairo )
	pixman? ( x11-libs/pixman )
	wayland? ( dev-libs/wayland )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	x11-proto/xproto
	doc? ( dev-util/gtk-doc )"

REQUIRED_USE="gles2? ( drm )
	multiseat? ( systemd )"

# args - names of renderers to enable
renderers_enable() {
	if [[ "x${RENDER}" == "x" ]]; then
		RENDER="$1"
		shift
	else
		for i in $@; do
			RENDER+=",${i}"
		done
	fi
}

# args - names of font renderer backends to enable
fonts_enable() {
	if [[ "x${FONTS}" == "x" ]]; then
		FONTS="$1"
		shift
	else
		for i in $@; do
			FONTS+=",${i}"
		done
	fi
}

# args - names of video backends to enable
video_enable() {
	if [[ "x${VIDEO}" == "x" ]]; then
		VIDEO="$1"
		shift
	else
		for i in $@; do
			VIDEO+=",${i}"
		done
	fi
}

src_prepare() {
	eautoreconf
}

src_configure() {
	# Video backends

	if use fbdev; then
		video_enable fbdev
	fi

	if use drm; then
		video_enable drm2d
	fi

	if use gles2; then
		video_enable drm3d
	fi

	# Font rendering backends 

	if use unicode; then
		fonts_enable unifont
	fi

	if use truetype; then
		fonts_enable freetype2
	fi

	if use pango; then
		fonts_enable pango
	fi

	# Console rendering backends

	renderers_enable bbulk

	if use gles2; then
		renderers_enable gltex
	fi

	if use cairo; then
		renderers_enable cairo
	fi

	if use pixman; then
		renderers_enable pixman
	fi

	# kmscon sets -ffast-math unconditionally
	strip-flags

	# xkbcommon not in portage
	econf \
		$(use_enable static-libs static) \
		$(use_enable udev hotplug) \
		$(use_enable dbus eloop-dbus) \
		$(use_enable debug) \
		$(use_enable optimizations) \
		$(use_enable multiseat multi-seat) \
		$(use_enable wayland wlterm) \
		--htmldir=/usr/share/doc/${PF}/html \
		--with-video=${VIDEO} \
		--with-fonts=${FONTS} \
		--with-renderers=${RENDER} \
		--with-sessions=dummy,terminal \
		--enable-kmscon
}

src_install() {
	emake DESTDIR="${D}" install

	if use systemd; then
		systemd_dounit "${S}/docs"/kmscon{,vt@}.service
	fi
}



1.1                  sys-apps/kmscon/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmscon/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/kmscon/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-apps/kmscon
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmscon/ChangeLog,v 1.1 2013/03/27 04:08:22 alexxy Exp $

*kmscon-7 (27 Mar 2013)

  27 Mar 2013; Alexey Shvetsov <alexxy@g.o> +kmscon-7.ebuild,
  +metadata.xml:
  Import to tree bug #431872