[gentoo-commits] gentoo-x86 commit in media-gfx/xsane: ChangeLog xsane-0.996.ebuild

[Patrick Kursawe (phosphan)]

phosphan    08/09/29 11:40:29

  Modified:             ChangeLog
  Added:                xsane-0.996.ebuild
  Log:
  Version bump. Does not install the HTML documentation twice any more and uses the .desktop file from upstream.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.72                 media-gfx/xsane/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/xsane/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	10 Aug 2008 17:14:54 -0000	1.71
+++ ChangeLog	29 Sep 2008 11:40:28 -0000	1.72
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/xsane
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/xsane/ChangeLog,v 1.71 2008/08/10 17:14:54 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/xsane/ChangeLog,v 1.72 2008/09/29 11:40:28 phosphan Exp $
+
+*xsane-0.996 (29 Sep 2008)
+
+  29 Sep 2008; Patrick Kursawe <phosphan@g.o> +xsane-0.996.ebuild:
+  Version bump. Does not install the HTML documentation twice any more and
+  uses the .desktop file from upstream.
 
   10 Aug 2008; Tobias Klausmann <klausman@g.o> xsane-0.995.ebuild:
   Stable on alpha, bug #231189



1.1                  media-gfx/xsane/xsane-0.996.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/xsane-0.996.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/xsane/xsane-0.996.ebuild?rev=1.1&content-type=text/plain

Index: xsane-0.996.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/xsane/xsane-0.996.ebuild,v 1.1 2008/09/29 11:40:28 phosphan Exp $

inherit eutils

DESCRIPTION="graphical scanning frontend"
HOMEPAGE="http://www.xsane.org/"
SRC_URI="http://www.xsane.org/download/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="nls jpeg png tiff gimp lcms"

RDEPEND="media-gfx/sane-backends
	>=x11-libs/gtk+-2.0
	jpeg? ( media-libs/jpeg )
	png? ( media-libs/libpng )
	tiff? ( media-libs/tiff )
	gimp? ( media-gfx/gimp )
	lcms? ( media-libs/lcms )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	export OLDXSANE
	if has_version '<=media-gfx/xsane-0.93'; then
		OLDXSANE="yes"
	else
		OLDXSANE="no"
	fi
}

src_compile() {
	local extraCPPflags
	if use lcms; then
		extraCPPflags="-I /usr/include/lcms"
	fi
	CPPFLAGS="${CPPFLAGS} ${extraCPPflags}" econf --enable-gtk2 \
		$(use_enable nls) \
		$(use_enable jpeg) \
		$(use_enable png) \
		$(use_enable tiff) \
		$(use_enable gimp) \
		$(use_enable lcms) \
		|| die
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc xsane.*
	# link xsane so it is seen as a plugin in gimp
	if use gimp; then
		local plugindir
		if [ -x /usr/bin/gimptool ]; then
			plugindir="$(gimptool --gimpplugindir)/plug-ins"
		elif [ -x /usr/bin/gimptool-2.0 ]; then
			plugindir="$(gimptool-2.0 --gimpplugindir)/plug-ins"
		else
			die "Can't find GIMP plugin directory."
		fi
		dodir "${plugindir}"
		dosym /usr/bin/xsane "${plugindir}"
	fi
	newicon src/xsane-48x48.png ${PN}.png
	make_desktop_entry xsane "X-Sane" ${PN}
}

pkg_postinst() {
	if [ x${OLDXSANE} = 'xyes' ]; then
		ewarn "If you are upgrading from <=xsane-0.93, please make sure to"
		ewarn "remove ~/.sane/xsane/xsane.rc _before_ you start xsane for"
		ewarn "the first time."
	fi
}