[gentoo-commits] gentoo-x86 commit in app-misc/subsurface: subsurface-9999.ebuild subsurface-4.0.ebuild ChangeLog

[Tom Wijsman (tomwij)]

tomwij      13/12/23 16:57:35

  Modified:             subsurface-9999.ebuild ChangeLog
  Added:                subsurface-4.0.ebuild
  Log:
  Version bump to 4.0, uses Qt 4 now; fixes bug #495098, proxied commit by Martin Gysel (bearsh).
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.4                  app-misc/subsurface/subsurface-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/subsurface-9999.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/subsurface-9999.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/subsurface-9999.ebuild?r1=1.3&r2=1.4

Index: subsurface-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/subsurface/subsurface-9999.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- subsurface-9999.ebuild	16 Nov 2013 15:15:16 -0000	1.3
+++ subsurface-9999.ebuild	23 Dec 2013 16:57:35 -0000	1.4
@@ -1,41 +1,43 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/subsurface/subsurface-9999.ebuild,v 1.3 2013/11/16 15:15:16 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/subsurface/subsurface-9999.ebuild,v 1.4 2013/12/23 16:57:35 tomwij Exp $
 
 EAPI="5"
 
 if [[ ${PV} = *9999* ]]; then
 	EGIT_REPO_URI="git://subsurface.hohndel.org/subsurface.git"
 	GIT_ECLASS="git-2"
+	KEYWORDS=""
+	SRC_URI=""
 	LIBDC_V="0.4.1"
 else
-	SRC_URI="http://subsurface.hohndel.org/downloads/Subsurface-${PV}.tgz -> ${P}.tar.gz"
+	MY_P=${P/s/S}
+	SRC_URI="http://subsurface.hohndel.org/downloads/${MY_P}.tgz https://bitbucket.org/bearsh/bearshlay/downloads/${MY_P}.tgz"
 	KEYWORDS="~amd64 ~x86"
 	LIBDC_V="0.4.1"
-	S="${WORKDIR}/${P/s/S}"
 fi
 
-inherit eutils qt4-r2 ${GIT_ECLASS}
+PLOCALES="bg_BG da_DK de_CH de_DE es_ES et_EE fi_FI fr_FR he it_IT nb_NO nl_NL
+	pl_PL pt_BR pt_PT ru_RU sk_SK sv_SE zh_TW"
+
+inherit eutils l10n qt4-r2 ${GIT_ECLASS}
 
 DESCRIPTION="An open source dive log program"
 HOMEPAGE="http://subsurface.hohndel.org"
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="doc usb"
-for LINGUA in ${LINGUAS}; do
-	IUSE+=" linguas_${LINGUA}"
-done
+IUSE="debug doc usb"
 
 RDEPEND="dev-db/sqlite:3
 	dev-libs/glib:2
-	dev-libs/libxml2:2
-	dev-libs/libxslt:0
-	dev-libs/libzip:0
+	dev-libs/libxml2
+	dev-libs/libxslt
+	dev-libs/libzip
 	dev-qt/qtcore:4
 	dev-qt/qtgui:4
 	dev-qt/qtsvg:4
 	dev-qt/qtwebkit:4
-	kde-base/marble:4
+	kde-base/marble
 "
 DEPEND="${RDEPEND}
 	>=dev-libs/libdivecomputer-${LIBDC_V}[static-libs,usb?]
@@ -50,22 +52,23 @@
 		git-2_src_unpack
 	else
 		unpack ${A}
+		mv ${MY_P}* ${P} || die "failed to mv the files to ${P}"
 	fi
 }
 
-src_compile() {
-	emake CC="$(tc-getCC)"
-
-	if use doc; then
-		cd "Documentation" && emake user-manual.xhtml
-	fi
+rm_trans() {
+	rm "${ED}/usr/share/${PN}/translations/${PN}_${1}.qm" || die "rm ${PN}_${1}.qm failed"
 }
 
 src_install() {
 	qt4-r2_src_install
 
-	if use doc; then
-		mv "${ED}/usr/share/doc/${PN}/"* "${ED}/usr/share/doc/${PF}/". || die "doc mv failed"
+	l10n_for_each_disabled_locale_do rm_trans
+
+	# this is not a translation but present (no need to die if not present)
+	rm "${ED}/usr/share/${PN}/translations/${PN}_source.qm"
+
+	if ! use doc; then
+		rm -R "${ED}/usr/share/${PN}/Documentation"* || die "rm doc failed"
 	fi
-	rm -Rf "${ED}/usr/share/doc/${PN}"
 }



1.7                  app-misc/subsurface/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/subsurface/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	16 Nov 2013 15:15:16 -0000	1.6
+++ ChangeLog	23 Dec 2013 16:57:35 -0000	1.7
@@ -1,6 +1,13 @@
 # ChangeLog for app-misc/subsurface
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/subsurface/ChangeLog,v 1.6 2013/11/16 15:15:16 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/subsurface/ChangeLog,v 1.7 2013/12/23 16:57:35 tomwij Exp $
+
+*subsurface-4.0 (23 Dec 2013)
+
+  23 Dec 2013; Tom Wijsman <TomWij@g.o> +subsurface-4.0.ebuild,
+  subsurface-9999.ebuild:
+  Version bump to 4.0, uses Qt 4 now; fixes bug #495098, proxied commit by
+  Martin Gysel (bearsh).
 
 *subsurface-3.1.1 (16 Nov 2013)
 



1.1                  app-misc/subsurface/subsurface-4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/subsurface-4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/subsurface/subsurface-4.0.ebuild?rev=1.1&content-type=text/plain

Index: subsurface-4.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/subsurface/subsurface-4.0.ebuild,v 1.1 2013/12/23 16:57:35 tomwij Exp $

EAPI="5"

if [[ ${PV} = *9999* ]]; then
	EGIT_REPO_URI="git://subsurface.hohndel.org/subsurface.git"
	GIT_ECLASS="git-2"
	KEYWORDS=""
	SRC_URI=""
	LIBDC_V="0.4.1"
else
	MY_P=${P/s/S}
	SRC_URI="http://subsurface.hohndel.org/downloads/${MY_P}.tgz https://bitbucket.org/bearsh/bearshlay/downloads/${MY_P}.tgz"
	KEYWORDS="~amd64 ~x86"
	LIBDC_V="0.4.1"
fi

PLOCALES="bg_BG da_DK de_CH de_DE es_ES et_EE fi_FI fr_FR he it_IT nb_NO nl_NL
	pl_PL pt_BR pt_PT ru_RU sk_SK sv_SE zh_TW"

inherit eutils l10n qt4-r2 ${GIT_ECLASS}

DESCRIPTION="An open source dive log program"
HOMEPAGE="http://subsurface.hohndel.org"
LICENSE="GPL-2"
SLOT="0"
IUSE="debug doc usb"

RDEPEND="dev-db/sqlite:3
	dev-libs/glib:2
	dev-libs/libxml2
	dev-libs/libxslt
	dev-libs/libzip
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	dev-qt/qtsvg:4
	dev-qt/qtwebkit:4
	kde-base/marble
"
DEPEND="${RDEPEND}
	>=dev-libs/libdivecomputer-${LIBDC_V}[static-libs,usb?]
	virtual/pkgconfig
	doc? ( app-text/asciidoc )
"

DOCS="README"

src_unpack() {
	if [[ ${PV} = *9999* ]]; then
		git-2_src_unpack
	else
		unpack ${A}
		mv ${MY_P}* ${P} || die "failed to mv the files to ${P}"
	fi
}

rm_trans() {
	rm "${ED}/usr/share/${PN}/translations/${PN}_${1}.qm" || die "rm ${PN}_${1}.qm failed"
}

src_install() {
	qt4-r2_src_install

	l10n_for_each_disabled_locale_do rm_trans

	# this is not a translation but present (no need to die if not present)
	rm "${ED}/usr/share/${PN}/translations/${PN}_source.qm"

	if ! use doc; then
		rm -R "${ED}/usr/share/${PN}/Documentation"* || die "rm doc failed"
	fi
}