[gentoo-commits] gentoo-x86 commit in gnome-extra/evolution-data-server: ChangeLog evolution-data-server-2.22.2.ebuild evolution-data-server-1.12.1.ebuild evolution-data-server-2.22.0.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/05/26 21:13:08

  Modified:             ChangeLog
  Added:                evolution-data-server-2.22.2.ebuild
  Removed:              evolution-data-server-1.12.1.ebuild
                        evolution-data-server-2.22.0.ebuild
  Log:
  New version for GNOME-2.22.2. Bug fixes and translation updates. Cleaning up old revisions.
  (Portage version: 2.1.5)

Revision  Changes    Path
1.179                gnome-extra/evolution-data-server/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.179&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.179&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?r1=1.178&r2=1.179

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v
retrieving revision 1.178
retrieving revision 1.179
diff -u -r1.178 -r1.179
--- ChangeLog	2 May 2008 18:45:42 -0000	1.178
+++ ChangeLog	26 May 2008 21:13:08 -0000	1.179
@@ -1,6 +1,37 @@
 # ChangeLog for gnome-extra/evolution-data-server
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.178 2008/05/02 18:45:42 dang Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.179 2008/05/26 21:13:08 eva Exp $
+
+*evolution-data-server-2.22.2 (26 May 2008)
+
+  26 May 2008; Gilles Dartiguelongue <eva@g.o>
+  -evolution-data-server-1.12.1.ebuild,
+  -evolution-data-server-2.22.0.ebuild,
+  +evolution-data-server-2.22.2.ebuild:
+  New version for GNOME-2.22.2. Bug fixes and translation updates. Cleaning
+  up old revisions.
+  #325882: If a parent window was given, make the password dialog transient
+  for the parent and center it over the parent. (Matthew Barnes)
+  #354923: Store passwords in the keyring by server, username and protocol
+  (Matthew Barnes)
+  #388579: (Novell Bugzilla) Exchange crashes everytime on startup. A
+  regression patch for the leak fixes. (Chenthill Palanisamy)
+  #517244: Add test for nl_langinfo(CODESET). Defines HAVE_CODESET (Matthew
+  Barnes)
+  #523541: Fix a memory leak (Milan Crha)
+  #530514: Added a necessary condition to handle a specific server response
+  and to prevent a crash (Sankar P)
+  #530543: Large memory leak while syncing mails for offline usage (Sankar
+  P)
+  #530763: Return NULL if the value of dest_folder is disturbed to prevent
+  the crash (Bharath Acharya)
+  #531009: Use the right iterator to prevent a crash in offline mail
+  movement (Sankar P)
+  #531439: Prevent GPG passphrases from destroying other passwords (Matthew
+  Barnes)
+  #532284: Fixes a double free (Sankar P)
+  #533058: Enable GROUPWISE_DEBUG logs. (Sankar P)
+  #534077: Don't use freed memory (Paul Smith)
 
 *evolution-data-server-2.22.1.1 (02 May 2008)
 



1.1                  gnome-extra/evolution-data-server/evolution-data-server-2.22.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-2.22.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-2.22.2.ebuild?rev=1.1&content-type=text/plain

Index: evolution-data-server-2.22.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-2.22.2.ebuild,v 1.1 2008/05/26 21:13:08 eva Exp $

inherit db-use eutils flag-o-matic gnome2 autotools

DESCRIPTION="Evolution groupware backend"
HOMEPAGE="http://www.gnome.org/projects/evolution/"

LICENSE="LGPL-2 Sleepycat"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc ipv6 kerberos gnome-keyring krb4 ldap ssl"

RDEPEND=">=dev-libs/glib-2.15.3
	>=x11-libs/gtk+-2.10
	>=gnome-base/orbit-2.9.8
	>=gnome-base/gnome-vfs-2.4
	>=gnome-base/libbonobo-2.20.3
	>=gnome-base/gconf-2
	>=gnome-base/libglade-2
	>=gnome-base/libgnome-2
	>=dev-libs/libxml2-2
	>=net-libs/libsoup-2.4
	gnome-keyring? ( >=gnome-base/gnome-keyring-2.20 )
	ssl? (
		>=dev-libs/nspr-4.4
		>=dev-libs/nss-3.9 )
	>=gnome-base/libgnomeui-2
	sys-libs/zlib
	=sys-libs/db-4*
	ldap? ( >=net-nds/openldap-2.0 )
	kerberos? ( virtual/krb5 )
	krb4? ( virtual/krb5 )"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35.5
	>=gnome-base/gnome-common-2
	>=dev-util/gtk-doc-am-1.9
	doc? ( >=dev-util/gtk-doc-1.9 )"

DOCS="ChangeLog MAINTAINERS NEWS TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_with ldap openldap)
		$(use_with kerberos krb5 /usr)
		$(use_enable ssl nss)
		$(use_enable ssl smime)
		$(use_enable ipv6)
		$(use_enable gnome-keyring)
		--with-libdb=/usr/$(get_libdir)"

	if use krb4 && ! built_with_use virtual/krb5 krb4; then
		ewarn
		ewarn "In order to add kerberos 4 support, you have to emerge"
		ewarn "virtual/krb5 with the 'krb4' USE flag enabled as well."
		ewarn
		ewarn "Skipping for now."
		ewarn
		G2CONF="${G2CONF} --without-krb4"
	else
		G2CONF="${G2CONF} $(use_with krb4 krb4 /usr)"
	fi
}

src_unpack() {
	gnome2_src_unpack

	# Adjust to gentoo's /etc/service
	epatch "${FILESDIR}"/${PN}-1.2.0-gentoo_etc_services.patch

	# Fix broken libdb build
	epatch "${FILESDIR}"/${PN}-1.11.3-no-libdb.patch

	# Resolve symbols at execution time for setgid binaries
	epatch "${FILESDIR}"/${PN}-no_lazy_bindings.patch

	# Rewind in camel-disco-diary to fix a crash
	epatch "${FILESDIR}"/${PN}-1.8.0-camel-rewind.patch

	# Don't assume that endian.h and byteswap.h exist on all non sun os's
	epatch "${FILESDIR}"/${PN}-2.21.90-icaltz-util.patch

	# Don't error out if gtkdoc-rebase doesn't exist.
	epatch "${FILESDIR}"/${PN}-2.21.4-gtkdoc-rebase.patch

	# Fix building evo-exchange with --as-needed
	epatch "${FILESDIR}"/${PN}-2.21.4-as-needed.patch

	# gtk-doc-am and gnome-common needed for this
	eautoreconf
}

src_compile() {
	# Use NSS/NSPR only if 'ssl' is enabled.
	if use ssl ; then
		sed -i -e "s|mozilla-nss|nss|
		s|mozilla-nspr|nspr|" "${S}"/configure
		G2CONF="${G2CONF} --enable-nss=yes"
	else
		G2CONF="${G2CONF} --without-nspr-libs --without-nspr-includes \
		--without-nss-libs --without-nss-includes"
	fi

	# /usr/include/db.h is always db-1 on FreeBSD
	# so include the right dir in CPPFLAGS
	append-cppflags "-I$(db_includedir)"

	cd "${S}"
	gnome2_src_compile
}



-- 
gentoo-commits@l.g.o mailing list