[gentoo-commits] gentoo-x86 commit in app-admin/system-config-printer-common: ChangeLog system-config-printer-common-1.3.9-r3.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/07/05 09:09:03

  Modified:             ChangeLog
  Added:                system-config-printer-common-1.3.9-r3.ebuild
  Log:
  Fix compability with sys-fs/udev >= 185 wrt #423423 by Maksim Melnikau
  
  (Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

Revision  Changes    Path
1.74                 app-admin/system-config-printer-common/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.74&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?rev=1.74&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/ChangeLog?r1=1.73&r2=1.74

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v
retrieving revision 1.73
retrieving revision 1.74
diff -u -r1.73 -r1.74
--- ChangeLog	25 Jun 2012 07:57:31 -0000	1.73
+++ ChangeLog	5 Jul 2012 09:09:03 -0000	1.74
@@ -1,6 +1,13 @@
 # ChangeLog for app-admin/system-config-printer-common
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.73 2012/06/25 07:57:31 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/ChangeLog,v 1.74 2012/07/05 09:09:03 ssuominen Exp $
+
+*system-config-printer-common-1.3.9-r3 (05 Jul 2012)
+
+  05 Jul 2012; Samuli Suominen <ssuominen@g.o>
+  +system-config-printer-common-1.3.9-r3.ebuild,
+  +files/system-config-printer-common-1.3.9-udev185.patch:
+  Fix compability with sys-fs/udev >= 185 wrt #423423 by Maksim Melnikau
 
   25 Jun 2012; Alexandre Rostovtsev <tetromino@g.o>
   system-config-printer-common-1.3.9-r2.ebuild:



1.1                  app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r3.ebuild?rev=1.1&content-type=text/plain

Index: system-config-printer-common-1.3.9-r3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/system-config-printer-common/system-config-printer-common-1.3.9-r3.ebuild,v 1.1 2012/07/05 09:09:03 ssuominen Exp $

EAPI=4

PYTHON_DEPEND="2:2.6"
WANT_AUTOMAKE="1.11"

inherit autotools eutils python

MY_P=${PN%-common}-${PV}

DESCRIPTION="Common modules of Red Hat's printer administration tool"
HOMEPAGE="http://cyberelk.net/tim/software/system-config-printer/"
SRC_URI="http://cyberelk.net/tim/data/${PN/-common}/${PV%.*}/${MY_P}.tar.xz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
SLOT="0"
IUSE="doc policykit"

# Needs cups running, bug 284005
RESTRICT="test"

# system-config-printer split since 1.1.3
COMMON_DEPEND="
	>=dev-libs/glib-2
	dev-libs/libxml2[python]
	dev-python/dbus-python
	>=dev-python/pycups-1.9.60
	dev-python/pycurl
	>=dev-python/pygobject-2.21.5:2
	>=net-print/cups-1.4.6[dbus]
	>=sys-fs/udev-164-r2
	virtual/libusb:0
"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	virtual/pkgconfig
	doc? ( dev-python/epydoc )
"
RDEPEND="${COMMON_DEPEND}
	!<app-admin/system-config-printer-gnome-${PV}
	policykit? ( >=sys-auth/polkit-0.104-r1 )
"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-1.3.9-split.patch \
		"${FILESDIR}"/${PN}-1.3.9-cups_filters_path.patch \
		"${FILESDIR}"/${PN}-1.3.9-udev185.patch
	eautoreconf
}

src_configure() {
	econf \
		--disable-nls \
		--with-udev-rules
}

src_compile() {
	emake
	use doc && emake html
}

src_install() {
	emake \
		DESTDIR="${D}" \
		udevhelperdir=/lib/udev \
		udevrulesdir=/lib/udev/rules.d \
		install

	dodoc AUTHORS ChangeLog README
	use doc && dohtml -r html/

	python_convert_shebangs -q -r $(python_get_version) "${ED}"
}

pkg_postinst() {
	python_mod_optimize cupshelpers
}

pkg_postrm() {
	python_mod_cleanup cupshelpers /usr/share/system-config-printer
}