[gentoo-commits] gentoo-x86 commit in dev-libs/cloog: cloog-0.18.4.ebuild cloog-9999.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    15/07/28 12:53:43

  Modified:             cloog-9999.ebuild ChangeLog
  Added:                cloog-0.18.4.ebuild
  Log:
  Version bump: gmp-6.0.0 and above required.  isl-0.15 is bundled, we match version with the system isl.  Patch to avoid use of undocumented isl print functions committed uptream f38b4fa.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.6                  dev-libs/cloog/cloog-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild?r1=1.5&r2=1.6

Index: cloog-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- cloog-9999.ebuild	17 Mar 2015 05:29:23 -0000	1.5
+++ cloog-9999.ebuild	28 Jul 2015 12:53:43 -0000	1.6
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild,v 1.5 2015/03/17 05:29:23 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/cloog-9999.ebuild,v 1.6 2015/07/28 12:53:43 blueness Exp $
 
 EAPI="5"
 
@@ -21,8 +21,8 @@
 SLOT="0/4"
 IUSE="static-libs"
 
-RDEPEND=">=dev-libs/gmp-5.1.3-r1[${MULTILIB_USEDEP}]
-	>=dev-libs/isl-0.14:0/14[${MULTILIB_USEDEP}]
+RDEPEND=">=dev-libs/gmp-6.0.0[${MULTILIB_USEDEP}]
+	>=dev-libs/isl-0.15:0=[${MULTILIB_USEDEP}]
 	!dev-libs/cloog-ppl"
 DEPEND="${DEPEND}
 	virtual/pkgconfig"
@@ -38,6 +38,9 @@
 		# sed to avoid eautoreconf
 		sed -i -e '/Libs:/s:@LDFLAGS@ ::' configure || die
 	fi
+
+	# Make sure we always use the system isl.
+	rm -rf isl
 }
 
 multilib_src_configure() {
@@ -48,6 +51,12 @@
 		$(use_enable static-libs static)
 }
 
+# The default src_test() fails, so we'll just run these directly
+multilib_src_test () {
+	echo ">>> Test phase [check]: ${CATEGORY}/${PF}"
+	emake -j1 check
+}
+
 multilib_src_install_all() {
 	einstalldocs
 	prune_libtool_files



1.34                 dev-libs/cloog/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/cloog/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	15 Jul 2015 08:39:03 -0000	1.33
+++ ChangeLog	28 Jul 2015 12:53:43 -0000	1.34
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/cloog
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/ChangeLog,v 1.33 2015/07/15 08:39:03 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/ChangeLog,v 1.34 2015/07/28 12:53:43 blueness Exp $
+
+*cloog-0.18.4 (28 Jul 2015)
+
+  28 Jul 2015; Anthony G. Basile <blueness@g.o> +cloog-0.18.4.ebuild,
+  cloog-9999.ebuild:
+  Version bump: gmp-6.0.0 and above required.  isl-0.15 is bundled, we match
+  version with the system isl.  Patch to avoid use of undocumented isl print
+  functions committed uptream f38b4fa.
 
   15 Jul 2015; Mike Frysinger <vapier@g.o>
   files/cloog-0.18.3-isl-0.15.patch:



1.1                  dev-libs/cloog/cloog-0.18.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/cloog-0.18.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/cloog/cloog-0.18.4.ebuild?rev=1.1&content-type=text/plain

Index: cloog-0.18.4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/cloog/cloog-0.18.4.ebuild,v 1.1 2015/07/28 12:53:43 blueness Exp $

EAPI="5"

inherit eutils multilib-minimal

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://repo.or.cz/cloog.git"
	inherit autotools git-2
else
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
	SRC_URI="http://www.bastoul.net/cloog/pages/download/${P}.tar.gz"
fi

DESCRIPTION="A loop generator for scanning polyhedra"
HOMEPAGE="http://www.bastoul.net/cloog/"

LICENSE="LGPL-2.1"
SLOT="0/4"
IUSE="static-libs"

RDEPEND=">=dev-libs/gmp-6.0.0[${MULTILIB_USEDEP}]
	>=dev-libs/isl-0.15:0=[${MULTILIB_USEDEP}]
	!dev-libs/cloog-ppl"
DEPEND="${DEPEND}
	virtual/pkgconfig"

DOCS=( README )

src_prepare() {
	if [[ ${PV} == "9999" ]] ; then
		./get_submodules.sh
		eautoreconf -i
	else
		# m4/ax_create_pkgconfig_info.m4 includes LDFLAGS
		# sed to avoid eautoreconf
		sed -i -e '/Libs:/s:@LDFLAGS@ ::' configure || die
	fi

	# Make sure we always use the system isl.
	rm -rf isl
}

multilib_src_configure() {
	ECONF_SOURCE="${S}" econf \
		--with-gmp=system \
		--with-isl=system \
		--with-osl=no \
		$(use_enable static-libs static)
}

# The default src_test() fails, so we'll just run these directly
multilib_src_test () {
	echo ">>> Test phase [check]: ${CATEGORY}/${PF}"
	emake -j1 check
}

multilib_src_install_all() {
	einstalldocs
	prune_libtool_files
}