[gentoo-commits] repo/gentoo:master commit in: sys-apps/flatpak/

[Zac Medico]

commit:     c0184c779020f3c6353bbc99b38309e184605511
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 19 18:01:53 2021 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Sun Sep 19 18:01:59 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c0184c77

sys-apps/flatpak: Bump to version 1.11.3

Closes: https://bugs.gentoo.org/809398
Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 sys-apps/flatpak/Manifest              |   1 +
 sys-apps/flatpak/flatpak-1.11.3.ebuild | 101 +++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+)

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index 43a31dd972b..b6a0be925aa 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -2,3 +2,4 @@ DIST flatpak-1.10.0.tar.xz 1504300 BLAKE2B 213fb5449b075250cbec9f43ea5b02afae809
 DIST flatpak-1.10.2.tar.xz 1507856 BLAKE2B b19b04d536b43a7bbb7f479e495538137402ff46bee3be5d180d12983c4e69b8726628bb69aea64917163a4722a34987b631a073c94083cae50d79dd7d74db20 SHA512 c932b9aa2803aa5b453917174bf282d82924aca7341d72555e2557fc588ccefa0eaf32b956f75752c17cd8f73b687d4a688ebd64df36680b80b5ff5750468597
 DIST flatpak-1.10.3.tar.xz 1507484 BLAKE2B 862d42db1395b8542bee0c9502392fe617d9dc17d002f70c95a168a23aaf31ae9ab8cbb72b63234fab95f3ed2e165362ebdfc4f0694152a1740aa2643dfece1d SHA512 ff51383d4ead0f39926125eec706e5a4d38a739874a9d499adf432cfa05685643cfa411f7a247c8512ec10af8440deda0be06f4cc0808e8ba80941b07e49b633
 DIST flatpak-1.11.1.tar.xz 1534700 BLAKE2B 811ac946fe6616d201ffc621881b396b6787ce435bdceb34c9fa3e162f20eba966d88695bcd6e3716b1f949976ac628a085249785c4e39989be5139cd89fdfaf SHA512 0121b4fcf159311c7480d1be29cd169a39ae61fcea9532f25b266b585038a07a930ff418a9c5b9645aab2510de78ad32c8ae8556991c8d2d7c08ab1e3cc819d1
+DIST flatpak-1.11.3.tar.xz 1544504 BLAKE2B 7a2f8e2dbbddf3e0afb355b98d3995f1276c7ff1b27ef873a3f262f8b34024c191d61c1dca33d58f50e19c18b2557b7de61a732f188470f4cfa751e5f3b64479 SHA512 5f0f6e42c8aec80fda348782742075dfaabf00c516c610e08f89a053a818011d52d5a459887d6f7490b1cc58899544e7ceb300e86cce8da55f24e1c53ee9dd17

diff --git a/sys-apps/flatpak/flatpak-1.11.3.ebuild b/sys-apps/flatpak/flatpak-1.11.3.ebuild
new file mode 100644
index 00000000000..a931e50425a
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.11.3.ebuild
@@ -0,0 +1,101 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit autotools linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc gtk kde introspection policykit seccomp systemd"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	>=net-libs/libsoup-2.4:=
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	x11-apps/xauth
+	x11-libs/gdk-pixbuf:2=
+	x11-libs/libXau:=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--enable-xauth
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}