[gentoo-commits] repo/gentoo:master commit in: net-nds/nsscache/

[Robin H. Johnson]

commit:     3c8d7e6a7eb3851c79c9699bce6a34a4bd8a79a3
Author:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 10 21:12:29 2022 +0000
Commit:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
CommitDate: Sat Sep 10 21:12:44 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3c8d7e6a

net-nds/nsscache: bump, needs more testing before ~keywording

Signed-off-by: Robin H. Johnson <robbat2 <AT> gentoo.org>

 net-nds/nsscache/Manifest                |  1 +
 net-nds/nsscache/nsscache-0.39-r1.ebuild | 66 +++++++++++++++++++++++++++++
 net-nds/nsscache/nsscache-0.47.ebuild    | 72 ++++++++++++++++++++++++++++++++
 3 files changed, 139 insertions(+)

diff --git a/net-nds/nsscache/Manifest b/net-nds/nsscache/Manifest
index 6686a51026c0..e7b222c0c8a1 100644
--- a/net-nds/nsscache/Manifest
+++ b/net-nds/nsscache/Manifest
@@ -1,2 +1,3 @@
 DIST nsscache-0.30-r3-gentoo-authorized-keys-command.py 11974 BLAKE2B 4272bab8d85ef0f39c8b26fd035009d3c77dd629fd7853e0072232393d329af1885ce44c4877d7718a37154661d9c85bb1f5276463875f9dfbbd023106d9d15a SHA512 b660a6ae19e6e42efbb07d0a368704706b0a0bd1bf0b2c84855f0d1c00d4cda80872432f5a25384d0c27e99bf60072beb12975bcfa0201b52fa040d0e6bc2da2
 DIST nsscache-0.39.tar.gz 127896 BLAKE2B 8383ca53ee5cf2f84e4485722d35598b624005bb32073696a23daa1061c0b057d26333cdee9c97cedcb99daa8c61362719d80b01b216c163a327cd4edeabeefd SHA512 f93cec949302f21bc5989ab3192302a32349ee4ae98e2f05f169cca8a16a821f39857cb0fff52c7b54552828684b4723d22e44f97525a01577ab89bd159e0376
+DIST nsscache-0.47.tar.gz 126225 BLAKE2B f238d4a6565038420dee7359edadf348a0e5fb581b8238b23d3835cc10ad9676917bfa6573c6a1d462d7afee36398954744ff2d498b4c1ed3459666b3aa6ad5c SHA512 94cd9a62169146f1e10f78476a950dfc708b6c2063cffed3617bbfa9c43aaf134b1f038a94079df408e168877d32f07b64b61f048d34fed283828cc75e7dd2cf

diff --git a/net-nds/nsscache/nsscache-0.39-r1.ebuild b/net-nds/nsscache/nsscache-0.39-r1.ebuild
new file mode 100644
index 000000000000..7f30d2de2a53
--- /dev/null
+++ b/net-nds/nsscache/nsscache-0.39-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="commandline tool to sync directory services to local cache"
+HOMEPAGE="https://github.com/google/nsscache"
+SCRIPT_A='nsscache-0.30-r3-gentoo-authorized-keys-command.py'
+SRC_URI="
+	https://github.com/google/nsscache/archive/version/${PV}.tar.gz -> ${P}.tar.gz
+	https://dev.gentoo.org/~robbat2/${SCRIPT_A}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="berkdb nsscache s3"
+RESTRICT="test" # requires network
+
+DEPEND="
+	dev-python/ldap3[${PYTHON_USEDEP}]
+	dev-python/pycurl[${PYTHON_USEDEP}]
+	berkdb? ( dev-python/bsddb3[${PYTHON_USEDEP}] )
+	s3? ( dev-python/boto3[${PYTHON_USEDEP}] )"
+RDEPEND="${DEPEND}
+	nsscache? ( >=sys-auth/libnss-cache-0.10 )"
+
+S="${WORKDIR}/${PN}-version-${PV}"
+
+python_prepare_all() {
+	sed -i \
+		-e "/setup_requires/s,'pytest-runner',,g" \
+		-e '/tests_require/s,\[.*\],[],g' \
+		setup.py || die
+	sed -i \
+		-e '/test=pytest/d' \
+		setup.cfg || die
+	sed -i \
+		-e '/pytest/d' \
+		requirements.txt || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile --verbose
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	python_scriptinto /usr/libexec/nsscache
+	python_newexe "${DISTDIR}"/"${SCRIPT_A}" authorized-keys-command.py
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doman nsscache.1 nsscache.conf.5
+	dodoc THANKS nsscache.cron CONTRIBUTING.md README.md
+
+	keepdir /var/lib/nsscache
+}

diff --git a/net-nds/nsscache/nsscache-0.47.ebuild b/net-nds/nsscache/nsscache-0.47.ebuild
new file mode 100644
index 000000000000..9d67d529c0be
--- /dev/null
+++ b/net-nds/nsscache/nsscache-0.47.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="commandline tool to sync directory services to local cache"
+HOMEPAGE="https://github.com/google/nsscache"
+SCRIPT_A='nsscache-0.30-r3-gentoo-authorized-keys-command.py'
+SRC_URI="
+	https://github.com/google/nsscache/archive/version/${PV}.tar.gz -> ${P}.tar.gz
+	https://dev.gentoo.org/~robbat2/${SCRIPT_A}"
+
+LICENSE="GPL-2"
+SLOT="0"
+#KEYWORDS="~amd64 ~x86"
+KEYWORDS="" # pending infra testing
+IUSE="nsscache s3 test"
+RESTRICT="test" # requires network
+
+#test? ( dev-python/pytest-cov[${PYTHON_USEDEP}] dev-python/mox3[${PYTHON_USEDEP}] )
+DEPEND="
+	dev-python/ldap3[${PYTHON_USEDEP}]
+	dev-python/pycurl[${PYTHON_USEDEP}]
+	s3? ( dev-python/boto3[${PYTHON_USEDEP}] )"
+RDEPEND="${DEPEND}
+	nsscache? ( >=sys-auth/libnss-cache-0.10 )"
+
+S="${WORKDIR}/${PN}-version-${PV}"
+
+python_prepare_all() {
+	# If tests are disabled in the ebuild, disable in setup
+	if [[ "${RESTRICT/test}" != "$RESTRICT" ]]; then
+		sed -i \
+			-e "/setup_requires/s,'pytest-runner',,g" \
+			-e '/tests_require/s,\[.*\],[],g' \
+			setup.py || die
+		sed -i \
+			-e '/test=pytest/d' \
+			setup.cfg || die
+		sed -i \
+			-e '/pytest/d' \
+			requirements.txt || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile --verbose
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	python_scriptinto /usr/libexec/nsscache
+	python_newexe "${DISTDIR}"/"${SCRIPT_A}" authorized-keys-command.py
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doman nsscache.1 nsscache.conf.5
+	dodoc THANKS nsscache.cron CONTRIBUTING.md README.md
+
+	keepdir /var/lib/nsscache
+}
+
+[[ "${RESTRICT/test}" != "$RESTRICT" ]] && distutils_enable_tests pytest