[gentoo-commits] repo/proj/guru:dev commit in: sys-cluster/cinder/

[Alessandro Barbieri]

commit:     93bcb1b70a9742874944b64e297f0282b67bd955
Author:     Alessandro Barbieri <lssndrbarbieri <AT> gmail <DOT> com>
AuthorDate: Mon Apr  4 19:20:34 2022 +0000
Commit:     Alessandro Barbieri <lssndrbarbieri <AT> gmail <DOT> com>
CommitDate: Mon Apr  4 19:32:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=93bcb1b7

sys-cluster/cinder: add 20.0.0

Signed-off-by: Alessandro Barbieri <lssndrbarbieri <AT> gmail.com>

 sys-cluster/cinder/Manifest             |   1 +
 sys-cluster/cinder/cinder-20.0.0.ebuild | 207 ++++++++++++++++++++++++++++++++
 2 files changed, 208 insertions(+)

diff --git a/sys-cluster/cinder/Manifest b/sys-cluster/cinder/Manifest
index 8b474a5d9..e9fdf3984 100644
--- a/sys-cluster/cinder/Manifest
+++ b/sys-cluster/cinder/Manifest
@@ -1 +1,2 @@
 DIST cinder-20.0.0.0rc1.tar.gz 5948385 BLAKE2B f8f2e2b4b88f4c81db61bc209b1408bf8c49db54b8b89095828d5baf3a1e6789889093ecb29b9494ec580c5878cd2cffcd5930992794d970a7582f190db5c134 SHA512 90e6845d96e896ddf40bd9992e80864a8441a74b265bdf559ada75f0a95af9f3041ee75d16312a9ae3871e35a23719248c7ed879b1511688afb3bf8b09239ab1
+DIST cinder-20.0.0.tar.gz 5950094 BLAKE2B 6370f2ea4f1bfecf3602d313b46436a100b5957754750c5ed5f282ec7bdb1797fa4df7764d7eb946d01a47345fc4611bcc8ed565f076556aedf094eec994f89b SHA512 1d7d8cc26b88b1243c7c03c607591815120120257f06355d75f2aab5cc7566470d0f37f2bfc7bc1f51a36a38c8b7016fc5996de9b42d36ebe7f393585a877bb2

diff --git a/sys-cluster/cinder/cinder-20.0.0.ebuild b/sys-cluster/cinder/cinder-20.0.0.ebuild
new file mode 100644
index 000000000..8ba86ad84
--- /dev/null
+++ b/sys-cluster/cinder/cinder-20.0.0.ebuild
@@ -0,0 +1,207 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MYP="${P/_rc/rc}"
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit distutils-r1 linux-info systemd tmpfiles
+
+DESCRIPTION="Cinder is the OpenStack Block storage service, a spin out of nova-volumes"
+HOMEPAGE="
+	https://launchpad.net/cinder
+	https://opendev.org/openstack/cinder/
+	https://pypi.org/project/cinder/
+	https://github.com/openstack/cinder
+"
+SRC_URI="https://tarballs.openstack.org/${PN}/${MYP}.tar.gz"
+KEYWORDS="~amd64"
+
+LICENSE="Apache-2.0 GPL-2"
+SLOT="0"
+IUSE="+api +scheduler +volume infiniband iscsi lvm mysql +memcached postgres rdma sqlite +tcp test +tgt"
+
+# qemu is needed for image conversion
+RDEPEND="
+	>=dev-python/pbr-5.8.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.2[${PYTHON_USEDEP}]
+	>=dev-python/eventlet-0.30.1[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.4.16[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.18.1[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.12[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-9.1.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.5.2[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-4.1.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-8.3.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-4.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-11.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-12.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-4.1.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-3.8.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-privsep-2.6.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-reports-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-rootwrap-6.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-2.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-upgradecheck-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.12.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-versionedobjects-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/osprofiler-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.2[${PYTHON_USEDEP}]
+	>=dev-python/paste-3.4.3[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.7.2[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.4.7[${PYTHON_USEDEP}]
+	>=dev-python/python-barbicanclient-5.0.1[${PYTHON_USEDEP}]
+	>=dev-python/python-glanceclient-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-4.1.1[${PYTHON_USEDEP}]
+	>=dev-python/python-novaclient-17.2.1[${PYTHON_USEDEP}]
+	>=dev-python/python-swiftclient-3.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.25.1[${PYTHON_USEDEP}]
+	>=dev-python/routes-2.4.1[${PYTHON_USEDEP}]
+	>=dev-python/taskflow-4.5.0[${PYTHON_USEDEP}]
+	>=dev-python/rtslib-fb-2.1.74[${PYTHON_USEDEP}]
+	>=dev-python/six-1.15.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-migrate-0.13.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/tabulate-0.8.7[${PYTHON_USEDEP}]
+	>=dev-python/tenacity-6.3.1[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.8.6[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-vmware-3.10.0[${PYTHON_USEDEP}]
+	>=dev-python/os-brick-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/os-win-5.5.0[${PYTHON_USEDEP}]
+	>=dev-python/tooz-2.7.1[${PYTHON_USEDEP}]
+	>=dev-python/google-api-python-client-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/castellan-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.1[${PYTHON_USEDEP}]
+	>=dev-python/cursive-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/zstd-1.4.5.1[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.16.51[${PYTHON_USEDEP}]
+
+	iscsi? (
+		tgt? ( sys-block/tgt )
+		sys-block/open-iscsi
+	)
+	lvm? ( sys-fs/lvm2 )
+	memcached? ( net-misc/memcached )
+	mysql? (
+		>=dev-python/pymysql-0.7.6[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.4.23[${PYTHON_USEDEP}]
+	)
+	sqlite? (
+		>=dev-python/sqlalchemy-1.4.23[sqlite,${PYTHON_USEDEP}]
+	)
+	postgres? (
+		>=dev-python/psycopg-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.4.23[${PYTHON_USEDEP}]
+	)
+
+	acct-user/cinder
+	acct-group/cinder
+	app-emulation/qemu
+	sys-fs/sysfsutils
+"
+DEPEND="
+	${RDEPEND}
+	app-admin/sudo
+"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-4.5.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.4.0[${PYTHON_USEDEP}]
+	)
+"
+
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	|| ( mysql postgres sqlite )
+	iscsi? ( tgt )
+	infiniband? ( rdma )
+	test? ( mysql postgres )
+"
+
+pkg_pretend() {
+	linux-info_pkg_setup
+	CONFIG_CHECK_MODULES=""
+	if use tcp; then
+		CONFIG_CHECK_MODULES+="SCSI_ISCSI_ATTRS ISCSI_TCP "
+	fi
+	if use rdma; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_ISER "
+	fi
+	if use infiniband; then
+		CONFIG_CHECK_MODULES+="INFINIBAND_IPOIB INFINIBAND_USER_MAD INFINIBAND_USER_ACCESS"
+	fi
+	if linux_config_exists; then
+		for module in ${CONFIG_CHECK_MODULES}; do
+			linux_chkconfig_present ${module} || ewarn "${module} needs to be enabled"
+		done
+	fi
+}
+
+python_prepare_all() {
+	sed -i '/^hacking/d' test-requirements.txt || die
+	# only used for docs
+	sed -i '/^sphinx-feature-classification/d' requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	oslo-config-generator --config-file=tools/config/cinder-config-generator.conf || die
+	oslopolicy-sample-generator --config-file=tools/config/cinder-policy-generator.conf || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	keepdir /etc/cinder
+	dodir /etc/cinder/rootwrap.d
+
+	for svc in api backup scheduler volume; do
+		newinitd "${FILESDIR}/cinder.initd" "cinder-${svc}"
+		systemd_dounit "${FILESDIR}/openstack-cinder-${svc}.service"
+	done
+
+	insinto /etc/cinder
+	insopts -m 0640 -o cinder -g cinder
+	doins "etc/cinder/api-httpd.conf"
+	doins "etc/cinder/logging_sample.conf"
+	doins "etc/cinder/rootwrap.conf"
+	doins "etc/cinder/api-paste.ini"
+	doins "etc/cinder/resource_filters.json"
+	doins "etc/cinder/cinder.conf.sample"
+	doins "etc/cinder/policy.yaml.sample"
+	insinto /etc/cinder/rootwrap.d
+	doins "etc/cinder/rootwrap.d/volume.filters"
+
+	dodir /var/log/cinder
+	fowners cinder:cinder /var/log/cinder
+
+	#add sudoers definitions for user cinder
+	insinto /etc/sudoers.d/
+	insopts -m 0440 -o root -g root
+	newins "${FILESDIR}/cinder.sudoersd" cinder
+
+	newtmpfiles "${FILESDIR}/cinder.tmpfile" cinder.conf
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/cinder.logrotate" cinder.conf
+
+	rm -r "${ED}/usr/etc"
+}
+
+pkg_postinst() {
+	if use iscsi ; then
+		elog "Cinder needs tgtd to be installed and running to work with iscsi"
+		elog "it also needs 'include /var/lib/cinder/volumes/*' in /etc/tgt/targets.conf"
+	fi
+}