[gentoo-commits] repo/gentoo:master commit in: media-gfx/eog/

[Matt Turner]

commit:     1cddb51c54f613746b0773bf54fca38fc3eb886c
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 16 01:47:51 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 16 01:47:51 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1cddb51c

media-gfx/eog: Version bump to 40.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/eog/Manifest        |  1 +
 media-gfx/eog/eog-40.0.ebuild | 71 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/media-gfx/eog/Manifest b/media-gfx/eog/Manifest
index 6a6204208bb..c8e224ae17d 100644
--- a/media-gfx/eog/Manifest
+++ b/media-gfx/eog/Manifest
@@ -1 +1,2 @@
 DIST eog-3.38.2.tar.xz 3614956 BLAKE2B ab442006b2eca1550d072c57af989e748f130b07088e724ccf8e2d6e6b2cf132e06ff2ff89d9333f6fa3cd701c27cdb616dabf125f14dc5a4d1b92d14a85be56 SHA512 f9af91a76b85b8e1250f3ecf04cfc30ae35892282fe65c810358d27cc7e0aac3cafe50dcf815c54c6056c24eb1107d6f5ecf8131f78559095cda5024d255ebe6
+DIST eog-40.0.tar.xz 3601476 BLAKE2B 149b173cb46c46c445b72cc118456e5fb957e48179176daafd3f1726a75353b30fb8750af2fd259235378127c48c2d44e769744c84b7ab9c3d57c679c7ef5828 SHA512 8f395caf4a5eb9ba9f5da6d7dd60c4383b029fc10041abc559afe7c45953f4ef8ddddc64604807df59d61178fa8a16e5a62526e91bfc19c8c57fbf654612d7d9

diff --git a/media-gfx/eog/eog-40.0.ebuild b/media-gfx/eog/eog-40.0.ebuild
new file mode 100644
index 00000000000..e0fd2241d63
--- /dev/null
+++ b/media-gfx/eog/eog-40.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="The Eye of GNOME image viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome"
+
+LICENSE="GPL-2+"
+SLOT="1"
+
+IUSE="+exif gtk-doc +introspection +jpeg lcms +svg xmp tiff"
+REQUIRED_USE="exif? ( jpeg )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.53.4:2
+	>=dev-libs/libpeas-0.7.4:=[gtk]
+	>=gnome-base/gnome-desktop-2.91.2:3=
+	>=gnome-base/gsettings-desktop-schemas-2.91.92
+	>=x11-misc/shared-mime-info-0.20
+	>=x11-libs/gdk-pixbuf-2.36.5:2[jpeg?,tiff?]
+	>=x11-libs/gtk+-3.22.0:3[introspection,X]
+	sys-libs/zlib
+
+	exif? ( >=media-libs/libexif-0.6.14 )
+	lcms? ( media-libs/lcms:2 )
+	xmp? ( media-libs/exempi:2 )
+	jpeg? ( virtual/jpeg:0 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	svg? ( >=gnome-base/librsvg-2.44.0:2 )
+
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gtk-doc-1.16
+		app-text/docbook-xml-dtd:4.1.2 )
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif libexif)
+		$(meson_use lcms cms)
+		$(meson_use xmp)
+		$(meson_use jpeg libjpeg)
+		$(meson_use svg librsvg)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dinstalled_tests=false
+		-Dlibportal=false # Not packaged
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}