[gentoo-commits] repo/gentoo:master commit in: dev-python/colorama/

[Michał Górny]

commit:     0604c9a10a3bf768a700110ba8b2193b1354e159
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed May 11 16:49:46 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed May 11 17:54:35 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0604c9a1

dev-python/colorama: EAPI 8, PEP517

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/colorama/colorama-0.4.4-r1.ebuild | 48 ++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-python/colorama/colorama-0.4.4-r1.ebuild b/dev-python/colorama/colorama-0.4.4-r1.ebuild
new file mode 100644
index 000000000000..081e4bc98702
--- /dev/null
+++ b/dev-python/colorama/colorama-0.4.4-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="ANSI escape character sequences for colored terminal text & cursor positioning"
+HOMEPAGE="
+	https://pypi.org/project/colorama/
+	https://github.com/tartley/colorama/
+"
+# https://github.com/tartley/colorama/pull/183
+SRC_URI="https://github.com/tartley/${PN}/archive/${PV}.tar.gz -> ${P}.github.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc -r demos/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# Some tests require stdout to be a TTY
+	# https://github.com/tartley/colorama/issues/169
+	script -eqc "${EPYTHON} -m pytest -vv -s" /dev/null \
+		|| die "tests failed with ${EPYTHON}"
+}