[gentoo-commits] repo/gentoo:master commit in: dev-scheme/chez/

[Maciej Barć]

commit:     1f1a479005c1052500b9e0cfbc4d6b1ebd54d047
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 25 16:23:00 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Thu Aug 25 16:23:37 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f1a4790

dev-scheme/chez: drop old 9.5.8

remove the superseded revision

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/chez/chez-9.5.8.ebuild | 69 ---------------------------------------
 1 file changed, 69 deletions(-)

diff --git a/dev-scheme/chez/chez-9.5.8.ebuild b/dev-scheme/chez/chez-9.5.8.ebuild
deleted file mode 100644
index 2d9538ba01d5..000000000000
--- a/dev-scheme/chez/chez-9.5.8.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 2021-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CSV="csv${PV}"
-
-inherit toolchain-funcs
-
-DESCRIPTION="A programming language based on R6RS"
-HOMEPAGE="https://cisco.github.io/ChezScheme/ https://github.com/cisco/ChezScheme"
-SRC_URI="https://github.com/cisco/ChezScheme/releases/download/v${PV}/${CSV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${CSV}"
-
-# Chez Scheme itself is Apache 2.0, but it vendors LZ4 (BSD-2),
-# Nanopass (MIT), stex (MIT), and zlib (ZLIB).
-LICENSE="Apache-2.0 BSD-2 MIT ZLIB"
-SLOT="0/${PV}"
-KEYWORDS="amd64 ~x86"
-IUSE="X examples ncurses threads"
-
-BDEPEND="virtual/pkgconfig"
-RDEPEND="
-	X? ( x11-libs/libX11 )
-	ncurses? ( sys-libs/ncurses:= )
-"
-DEPEND="${RDEPEND}"
-
-src_prepare() {
-	tc-export AR CC CXX LD RANLIB
-
-	default
-
-	if use ncurses ; then
-		local nclibs="\"$($(tc-getPKG_CONFIG) --libs ncurses)\""
-		sed -i "s|ncursesLib=-lncurses|ncursesLib=${nclibs}|g" configure || die
-	fi
-
-	# Remove -Werror
-	sed -i "/^C = /s|-Werror||g" c/Mf-* || die
-}
-
-src_configure() {
-	local myconfargs=(
-		$(usex threads '--threads' '')
-		$(usex ncurses '' '--disable-curses')
-		$(usex X '' '--disable-x11')
-		--installprefix="/usr"
-		--installbin="/usr/bin"
-		--installlib="/usr/$(get_libdir)"
-		--installman="/usr/share/man"
-		--installschemename=chezscheme
-		--installpetitename=chezscheme-petite
-		--installscriptname=chezscheme-script
-		--nogzip-man-pages
-	)
-	sh ./configure "${myconfargs[@]}" || die
-}
-
-src_install() {
-	# TempRoot == DESTDIR
-	emake TempRoot="${D}" install
-
-	if ! use examples; then
-		rm -r "${D}/usr/$(get_libdir)/${CSV}/examples" || die
-	fi
-
-	einstalldocs
-}