[gentoo-commits] gentoo-x86 commit in net-proxy/dansguardian: ChangeLog dansguardian-2.10-r2.ebuild

[Alin Nastac (mrness)]

mrness      08/12/01 21:08:01

  Modified:             ChangeLog
  Added:                dansguardian-2.10-r2.ebuild
  Log:
  Fix broken build when compiled using uclibc++, thanks to Natanael Copa <natanael dot copa at gmail dot com> (#247547).
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.42                 net-proxy/dansguardian/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/dansguardian/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/dansguardian/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/dansguardian/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	13 Nov 2008 00:42:14 -0000	1.41
+++ ChangeLog	1 Dec 2008 21:08:01 -0000	1.42
@@ -1,6 +1,13 @@
 # ChangeLog for net-proxy/dansguardian
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/ChangeLog,v 1.41 2008/11/13 00:42:14 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/ChangeLog,v 1.42 2008/12/01 21:08:01 mrness Exp $
+
+*dansguardian-2.10-r2 (01 Dec 2008)
+
+  01 Dec 2008; Alin Năstac <mrness@g.o>
+  +files/dansguardian-2.10-uclibc++.patch, +dansguardian-2.10-r2.ebuild:
+  Fix broken build when compiled using uclibc++, thanks to Natanael Copa
+  <natanael dot copa at gmail dot com> (#247547).
 
   13 Nov 2008; Brent Baude <ranger@g.o> dansguardian-2.10-r1.ebuild:
   stable ppc64, bug 245680



1.1                  net-proxy/dansguardian/dansguardian-2.10-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/dansguardian/dansguardian-2.10-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/dansguardian/dansguardian-2.10-r2.ebuild?rev=1.1&content-type=text/plain

Index: dansguardian-2.10-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/dansguardian/dansguardian-2.10-r2.ebuild,v 1.1 2008/12/01 21:08:01 mrness Exp $

inherit eutils

DESCRIPTION="Web content filtering via proxy"
HOMEPAGE="http://dansguardian.org"
SRC_URI="http://dansguardian.org/downloads/2/Stable/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="clamav kaspersky debug ntlm pcre"

RDEPEND="sys-libs/zlib
	pcre? ( dev-libs/libpcre )
	clamav? ( >=app-antivirus/clamav-0.93 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	if has_version "<${CATEGORY}/${PN}-2.9" ; then
		ewarn "This version introduces brand new USE flags:"
		ewarn "   clamav kaspersky ntlm pcre"
		echo

		local f="${ROOT}/etc/dansguardian"
		f=${f//\/\///}
		if [ -d "${f}" ] ; then
			eerror "The structure of ${f} has changed in this version!"
			eerror "For avoiding confusion, you must either move or delete the old ${f},"
			eerror "then continue with the upgrade:"
			eerror "   mv '${f}' '${f}.old'"
			eerror "   emerge --resume"
			die "Obsolete config files detected"
		fi
	fi
}

src_unpack() {
	unpack ${A}
	
	epatch "${FILESDIR}"/${P}-uclibc++.patch
}

src_compile() {
	local myconf="--with-logdir=/var/log/dansguardian
		--with-piddir=/var/run
		--docdir=/usr/share/doc/${PF}
		--htmldir=/usr/share/doc/${PF}/html
		$(use_enable pcre)
		$(use_enable ntlm)
		--enable-fancydm
		--enable-email"
	if use clamav; then
		myconf="${myconf} --enable-clamd --enable-clamav
			--with-proxyuser=clamav
			--with-proxygroup=clamav"
	fi
	if use kaspersky; then
		myconf="${myconf} --enable-kavd"
	fi
	if use debug; then
		myconf="${myconf} --with-dgdebug=on"
	fi

	econf ${myconf} || die "configure failed"

	emake OPTIMISE="${CFLAGS}" || die "emake failed"
}

src_install() {
	make "DESTDIR=${D}" install || die "make install failed"

	# Move html documents to html dir
	mkdir "${D}"/usr/share/doc/${PF}/html \
		&& mv "${D}"/usr/share/doc/${PF}/*.html "${D}"/usr/share/doc/${PF}/html \
		|| die "no html docs found in docdir"

	# Copying init script
	newinitd "${FILESDIR}/dansguardian.init" dansguardian

	if use clamav; then
		sed -r -i -e 's/[ \t]+use dns/& clamd/' "${D}/etc/init.d/dansguardian"
		sed -r -i -e 's/^#( *contentscanner *=.*clamdscan[.]conf.*)/\1/' "${D}/etc/dansguardian/dansguardian.conf"
		sed -r -i -e 's/^#( *clamdudsfile *=.*)/\1/' "${D}/etc/dansguardian/contentscanners/clamdscan.conf"
	elif use kaspersky; then
		sed -r -i -e 's/^#( *contentscanner *=.*kavdscan[.]conf.*)/\1/' "${D}/etc/dansguardian/dansguardian.conf"
	fi

	# Copying logrotation file
	insinto /etc/logrotate.d
	newins "${FILESDIR}/dansguardian.logrotate" dansguardian

	keepdir /var/log/dansguardian
	fperms o-rwx /var/log/dansguardian
}

pkg_postinst() {
	local runas="nobody:nobody"
	if use clamav ; then
		runas="clamav:clamav"
	fi
	einfo "The dansguardian daemon will run by default as ${runas}"

	if [ -d "${ROOT}/var/log/dansguardian" ] ; then
		chown -R ${runas} "${ROOT}/var/log/dansguardian"
		chmod o-rwx "${ROOT}/var/log/dansguardian"
	fi
}