[gentoo-commits] repo/gentoo:master commit in: www-misc/fcgiwrap/

[Marek Szuba]

commit:     25215eb92428e29ff11b69350afaa7202c960914
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 27 15:09:02 2021 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sat Nov 27 16:01:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=25215eb9

www-misc/fcgiwrap: update EAPI 5 -> 8

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 www-misc/fcgiwrap/fcgiwrap-1.1.0-r2.ebuild | 53 ++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/www-misc/fcgiwrap/fcgiwrap-1.1.0-r2.ebuild b/www-misc/fcgiwrap/fcgiwrap-1.1.0-r2.ebuild
new file mode 100644
index 000000000000..5280d34fc373
--- /dev/null
+++ b/www-misc/fcgiwrap/fcgiwrap-1.1.0-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools systemd toolchain-funcs
+
+DESCRIPTION="Simple FastCGI wrapper for CGI scripts (CGI support for nginx)"
+HOMEPAGE="https://github.com/gnosek/fcgiwrap"
+SRC_URI="https://github.com/gnosek/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0"
+IUSE="systemd"
+
+RDEPEND="
+	dev-libs/fcgi
+	systemd? ( sys-apps/systemd )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( README.rst )
+
+src_prepare() {
+	sed -e "s/-Werror//" \
+		-i configure.ac || die "sed failed"
+
+	sed -e '/man8dir = $(DESTDIR)/s/@prefix@//' \
+		-i Makefile.in || die "sed failed"
+
+	sed -e "s/libsystemd-daemon/libsystemd/" \
+		-i configure.ac || die "sed failed"
+	tc-export CC
+
+	# Fix systemd units for Gentoo
+	sed -i -e '/User/d' systemd/fcgiwrap.service || die
+	sed -i -e '/Group/d' systemd/fcgiwrap.service || die
+
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with systemd) \
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+}
+
+pkg_postinst() {
+	einfo "You may want to install www-servers/spawn-fcgi to use with fcgiwrap."
+}