Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Patrick Lauer (patrick)" <patrick@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in app-emulation/virtualbox-ose: ChangeLog virtualbox-ose-3.0.10.ebuild
Date: Tue, 03 Nov 2009 08:13:51
Message-Id: E1N5EWT-000289-6s@stork.gentoo.org
1 patrick 09/11/03 08:13:49
2
3 Modified: ChangeLog
4 Added: virtualbox-ose-3.0.10.ebuild
5 Log:
6 Bump to 3.0.10, fixes #291214 #290296 #285749 #286163
7 (Portage version: 2.2_rc48/cvs/Linux x86_64)
8
9 Revision Changes Path
10 1.34 app-emulation/virtualbox-ose/ChangeLog
11
12 file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.34&view=markup
13 plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?rev=1.34&content-type=text/plain
14 diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog?r1=1.33&r2=1.34
15
16 Index: ChangeLog
17 ===================================================================
18 RCS file: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v
19 retrieving revision 1.33
20 retrieving revision 1.34
21 diff -u -r1.33 -r1.34
22 --- ChangeLog 19 Oct 2009 01:46:15 -0000 1.33
23 +++ ChangeLog 3 Nov 2009 08:13:48 -0000 1.34
24 @@ -1,6 +1,12 @@
25 # ChangeLog for app-emulation/virtualbox-ose
26 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
27 -# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.33 2009/10/19 01:46:15 fauli Exp $
28 +# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/ChangeLog,v 1.34 2009/11/03 08:13:48 patrick Exp $
29 +
30 +*virtualbox-ose-3.0.10 (03 Nov 2009)
31 +
32 + 03 Nov 2009; Patrick Lauer <patrick@g.o>
33 + +virtualbox-ose-3.0.10.ebuild, +files/virtualbox-ose-3-wrapper:
34 + Bump to 3.0.10, fixes #291214 #290296 #285749 #286163
35
36 19 Oct 2009; Christian Faulhammer <fauli@g.o>
37 virtualbox-ose-3.0.8-r1.ebuild:
38
39
40
41 1.1 app-emulation/virtualbox-ose/virtualbox-ose-3.0.10.ebuild
42
43 file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.0.10.ebuild?rev=1.1&view=markup
44 plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.0.10.ebuild?rev=1.1&content-type=text/plain
45
46 Index: virtualbox-ose-3.0.10.ebuild
47 ===================================================================
48 # Copyright 1999-2009 Gentoo Foundation
49 # Distributed under the terms of the GNU General Public License v2
50 # $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-ose/virtualbox-ose-3.0.10.ebuild,v 1.1 2009/11/03 08:13:48 patrick Exp $
51
52 EAPI=2
53
54 inherit eutils fdo-mime flag-o-matic linux-info pax-utils qt4 toolchain-funcs
55
56 if [[ ${PV} == "9999" ]] ; then
57 # XXX: should finish merging the -9999 ebuild into this one ...
58 ESVN_REPO_URI="http://www.virtualbox.org/svn/vbox/trunk"
59 inherit linux-mod subversion
60 else
61 MY_P=VirtualBox-${PV}-OSE
62 SRC_URI="http://download.virtualbox.org/virtualbox/${PV}/${MY_P}.tar.bz2"
63 S=${WORKDIR}/${MY_P/-OSE/_OSE}
64 fi
65
66 DESCRIPTION="Software family of powerful x86 virtualization"
67 HOMEPAGE="http://www.virtualbox.org/"
68
69 LICENSE="GPL-2"
70 SLOT="0"
71 KEYWORDS="~amd64 ~x86"
72 IUSE="+additions alsa +hal headless pulseaudio +opengl python +qt4 sdk vboxwebsrv"
73
74 RDEPEND="!app-emulation/virtualbox-bin
75 ~app-emulation/virtualbox-modules-${PV}
76 dev-libs/libIDL
77 >=dev-libs/libxslt-1.1.19
78 net-misc/curl
79 !headless? (
80 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 )
81 opengl? ( virtual/opengl virtual/glut )
82 x11-libs/libXcursor
83 media-libs/libsdl[X,video]
84 x11-libs/libXt
85 )"
86 DEPEND="${RDEPEND}
87 >=dev-util/kbuild-0.1.5-r1
88 >=dev-lang/yasm-0.6.2
89 sys-devel/bin86
90 sys-devel/dev86
91 sys-power/iasl
92 media-libs/libpng
93 sys-libs/libcap
94 dev-util/pkgconfig
95 alsa? ( >=media-libs/alsa-lib-1.0.13 )
96 hal? ( sys-apps/hal )
97 pulseaudio? ( media-sound/pulseaudio )
98 python? ( >=dev-lang/python-2.3 )
99 vboxwebsrv? ( >=net-libs/gsoap-2.7.13 )"
100 RDEPEND="${RDEPEND}
101 additions? ( ~app-emulation/virtualbox-ose-additions-${PV} )"
102
103 QA_TEXTRELS_x86="usr/lib/virtualbox-ose/VBoxGuestPropSvc.so
104 usr/lib/virtualbox-ose/VBoxSDL.so
105 usr/lib/virtualbox-ose/VBoxPython2_4.so
106 usr/lib/virtualbox-ose/VBoxSharedFolders.so
107 usr/lib/virtualbox-ose/VBoxDD2.so
108 usr/lib/virtualbox-ose/VBoxOGLrenderspu.so
109 usr/lib/virtualbox-ose/VBoxPython.so
110 usr/lib/virtualbox-ose/VBoxDD.so
111 usr/lib/virtualbox-ose/VBoxDDU.so
112 usr/lib/virtualbox-ose/VBoxREM64.so
113 usr/lib/virtualbox-ose/VBoxSharedClipboard.so
114 usr/lib/virtualbox-ose/VBoxHeadless.so
115 usr/lib/virtualbox-ose/VBoxRT.so
116 usr/lib/virtualbox-ose/VBoxREM.so
117 usr/lib/virtualbox-ose/VBoxSettings.so
118 usr/lib/virtualbox-ose/VBoxKeyboard.so
119 usr/lib/virtualbox-ose/VBoxSharedCrOpenGL.so
120 usr/lib/virtualbox-ose/VBoxVMM.so
121 usr/lib/virtualbox-ose/VirtualBox.so
122 usr/lib/virtualbox-ose/VBoxOGLhosterrorspu.so
123 usr/lib/virtualbox-ose/components/VBoxC.so
124 usr/lib/virtualbox-ose/components/VBoxSVCM.so
125 usr/lib/virtualbox-ose/components/VBoxDDU.so
126 usr/lib/virtualbox-ose/components/VBoxRT.so
127 usr/lib/virtualbox-ose/components/VBoxREM.so
128 usr/lib/virtualbox-ose/components/VBoxVMM.so
129 usr/lib/virtualbox-ose/VBoxREM32.so
130 usr/lib/virtualbox-ose/VBoxPython2_5.so
131 usr/lib/virtualbox-ose/VBoxXPCOMC.so
132 usr/lib/virtualbox-ose/VBoxOGLhostcrutil.so
133 usr/lib/virtualbox-ose/VBoxNetDHCP.so"
134
135 pkg_setup() {
136 if ! use headless && ! use qt4 ; then
137 einfo "No USE=\"qt4\" selected, this build will not include"
138 einfo "any Qt frontend."
139 elif use headless && use qt4 ; then
140 einfo "You selected USE=\"headless qt4\", defaulting to"
141 einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
142 fi
143
144 if ! use opengl ; then
145 einfo "No USE=\"opengl\" selected, this build will lack"
146 einfo "the OpenGL feature."
147 fi
148 }
149
150 src_prepare() {
151 # Remove shipped binaries (kBuild,yasm), see bug #232775
152 rm -rf kBuild/bin tools
153
154 # Disable things unused or split into separate ebuilds
155 sed -e "s/MY_LIBDIR/$(get_libdir)/" \
156 "${FILESDIR}"/${PN}-2-localconfig > LocalConfig.kmk || die
157
158 # unset useless/problematic mesa checks in configure
159 epatch "${FILESDIR}/${PN}-3.0.0-mesa-check.patch"
160
161 # stupid hal being stupid code
162 use hal || epatch "${FILESDIR}/${P}-without-hal-fix.patch"
163 }
164
165 src_configure() {
166 local myconf
167 use alsa || myconf="${myconf} --disable-alsa"
168 use opengl || myconf="${myconf} --disable-opengl"
169 use pulseaudio || myconf="${myconf} --disable-pulse"
170 use python || myconf="${myconf} --disable-python"
171 use hal || myconf="${myconf} --disable-dbus"
172 use vboxwebsrv && myconf="${myconf} --enable-webservice"
173 if ! use headless ; then
174 use qt4 || myconf="${myconf} --disable-qt4"
175 else
176 myconf="${myconf} --build-headless --disable-opengl"
177 fi
178 # not an autoconf script
179 ./configure \
180 --with-gcc="$(tc-getCC)" \
181 --with-g++="$(tc-getCXX)" \
182 --disable-kmods \
183 ${myconf} \
184 || die "configure failed"
185 }
186
187 src_compile() {
188 source ./env.sh
189
190 # Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
191 # and strip all flags
192 strip-flags
193
194 MAKE="kmk" emake \
195 TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
196 TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
197 TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
198 TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
199 TOOL_YASM_AS=yasm KBUILD_PATH="${S}/kBuild" \
200 all || die "kmk failed"
201 }
202
203 src_install() {
204 cd "${S}"/out/linux.*/release/bin || die
205
206 # Create configuration files
207 insinto /etc/vbox
208 newins "${FILESDIR}/${PN}-2-config" vbox.cfg
209
210 # Set the right libdir
211 sed -i \
212 -e "s/MY_LIBDIR/$(get_libdir)/" \
213 "${D}"/etc/vbox/vbox.cfg || die "vbox.cfg sed failed"
214
215 # Symlink binaries to the shipped wrapper
216 exeinto /usr/$(get_libdir)/${PN}
217 newexe "${FILESDIR}/${PN}-3-wrapper" "VBox" || die
218 fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBox
219 fperms 0750 /usr/$(get_libdir)/${PN}/VBox
220
221 dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxManage
222 dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxVRDP
223 dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxHeadless
224 dosym /usr/$(get_libdir)/${PN}/VBoxTunctl /usr/bin/VBoxTunctl
225
226 # Install binaries and libraries
227 insinto /usr/$(get_libdir)/${PN}
228 doins -r components || die
229
230 if use sdk ; then
231 doins -r sdk || die
232 fi
233
234 if use vboxwebsrv ; then
235 doins vboxwebsrv || die
236 fowners root:vboxusers /usr/$(get_libdir)/${PN}/vboxwebsrv
237 fperms 0750 /usr/$(get_libdir)/${PN}/vboxwebsrv
238 dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/vboxwebsrv
239 newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
240 newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
241 fi
242
243 for each in VBox{Manage,SVC,XPCOMIPCD,Tunctl,NetAdpCtl,NetDHCP} *so *r0 *gc ; do
244 doins $each || die
245 fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
246 fperms 0750 /usr/$(get_libdir)/${PN}/${each}
247 done
248 # VBoxNetAdpCtl binary needs to be suid root in any case..
249 fperms 4750 /usr/$(get_libdir)/${PN}/VBoxNetAdpCtl
250
251 if ! use headless ; then
252 for each in VBox{SDL,Headless} ; do
253 doins $each || die
254 fowners root:vboxusers /usr/$(get_libdir)/${PN}/${each}
255 fperms 4750 /usr/$(get_libdir)/${PN}/${each}
256 pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/${each}
257 done
258
259 if use opengl ; then
260 doins VBoxTestOGL || die
261 fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxTestOGL
262 fperms 0750 /usr/$(get_libdir)/${PN}/VBoxTestOGL
263 fi
264
265 dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VBoxSDL
266
267 if use qt4 ; then
268 doins VirtualBox || die
269 fowners root:vboxusers /usr/$(get_libdir)/${PN}/VirtualBox
270 fperms 4750 /usr/$(get_libdir)/${PN}/VirtualBox
271 pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VirtualBox
272
273 dosym /usr/$(get_libdir)/${PN}/VBox /usr/bin/VirtualBox
274 fi
275
276 newicon "${S}"/src/VBox/Frontends/VirtualBox/images/OSE/VirtualBox_32px.png ${PN}.png
277 domenu "${FILESDIR}"/${PN}.desktop
278 else
279 doins VBoxHeadless || die
280 fowners root:vboxusers /usr/$(get_libdir)/${PN}/VBoxHeadless
281 fperms 4750 /usr/$(get_libdir)/${PN}/VBoxHeadless
282 pax-mark -m "${D}"/usr/$(get_libdir)/${PN}/VBoxHeadless
283 fi
284
285 insinto /usr/share/${PN}
286 if ! use headless && use qt4 ; then
287 doins -r nls
288 fi
289 }
290
291 pkg_postinst() {
292 fdo-mime_desktop_database_update
293 if ! use headless && use qt4 ; then
294 elog "To launch VirtualBox just type: \"VirtualBox\""
295 fi
296 elog "You must be in the vboxusers group to use VirtualBox."
297 elog ""
298 elog "The latest user manual is available for download at:"
299 elog "http://download.virtualbox.org/virtualbox/${PV}/UserManual.pdf"
300 elog ""
301 elog "For advanced networking setups you should emerge:"
302 elog "net-misc/bridge-utils and sys-apps/usermode-utilities"
303 }
304
305 pkg_postrm() {
306 fdo-mime_desktop_database_update
307 }
Report Message
Find on MARC Find on Google Groups