[gentoo-commits] gentoo-x86 commit in x11-wm/compiz: metadata.xml ChangeLog compiz-0.8.2-r3.ebuild compiz-0.8.2.ebuild compiz-0.8.2-r1.ebuild compiz-0.6.2-r1.ebuild compiz-0.8.2-r2.ebuild

[Romain Perier (mrpouet)]

mrpouet     09/08/29 12:28:11

  Modified:             metadata.xml ChangeLog
  Added:                compiz-0.8.2-r3.ebuild
  Removed:              compiz-0.8.2.ebuild compiz-0.8.2-r1.ebuild
                        compiz-0.6.2-r1.ebuild compiz-0.8.2-r2.ebuild
  Log:
  Fix libGL.so.1.2 path in compiz-manager (bug #274762), update KDE4 dependencies (bug #277016), fix missing gconf flags in gnome plugin (bug #282807). Fix QA warnings, Drop old revisions.
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  x11-wm/compiz/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/compiz/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	6 Jan 2009 07:27:52 -0000	1.3
+++ metadata.xml	29 Aug 2009 12:28:11 -0000	1.4
@@ -3,7 +3,7 @@
 <pkgmetadata>
 <use>
 	<flag name="fuse">Enables support for the filesystem in userspace plugin through <pkg>sys-fs/fuse</pkg>.</flag>
-	<flag name="kde4">Compile the kde4 window decorator and add support for <pkg>kde-base/kdebase-startkde:4.1</pkg>.</flag>
+	<flag name="kde3">Compile the kde3 window decorator and add support for KDE3</flag>
 </use>
 <herd>desktop-effects</herd>
 <longdescription>



1.44                 x11-wm/compiz/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	12 Jun 2009 03:09:39 -0000	1.43
+++ ChangeLog	29 Aug 2009 12:28:11 -0000	1.44
@@ -1,6 +1,17 @@
 # ChangeLog for x11-wm/compiz
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.43 2009/06/12 03:09:39 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.44 2009/08/29 12:28:11 mrpouet Exp $
+
+*compiz-0.8.2-r3 (29 Aug 2009)
+
+  29 Aug 2009; Romain Perier <mrpouet@g.o>
+  -compiz-0.6.2-r1.ebuild, -compiz-0.8.2.ebuild, -compiz-0.8.2-r1.ebuild,
+  -compiz-0.8.2-r2.ebuild, +compiz-0.8.2-r3.ebuild,
+  +files/compiz-0.8.2-gtk-gnome-missing-gconf-flags.patch, files/compiz-manager,
+  metadata.xml:
+  Fix libGL.so.1.2 path in compiz-manager (bug #274762), update KDE4
+  dependencies (bug #277016), fix missing gconf flags in gnome plugin (bug
+  #282807), fix QA warnings, Drop old revisions.
 
 *compiz-0.8.2-r2 (12 Jun 2009)
 



1.1                  x11-wm/compiz/compiz-0.8.2-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r3.ebuild?rev=1.1&content-type=text/plain

Index: compiz-0.8.2-r3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r3.ebuild,v 1.1 2009/08/29 12:28:11 mrpouet Exp $

EAPI="2"

inherit autotools eutils gnome2-utils

DESCRIPTION="3D composite and windowmanager"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2.1 MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="+cairo dbus fuse gnome gtk kde kde3 +svg"

DEPEND="
	dev-libs/glib:2
	dev-libs/libxml2
	dev-libs/libxslt
	media-libs/libpng
	>=media-libs/mesa-6.5.1-r1
	>=x11-base/xorg-server-1.1.1-r1
	x11-libs/libX11[xcb]
	x11-libs/libxcb
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXinerama
	x11-libs/libXrandr
	x11-libs/libICE
	x11-libs/libSM
	>=x11-libs/libXrender-0.8.4
	>=x11-libs/startup-notification-0.7
	cairo? (
			x11-libs/cairo[X]
	)
	dbus? ( >=sys-apps/dbus-1.0 )
	fuse? ( sys-fs/fuse )
	gnome? (
		>=gnome-base/gnome-control-center-2.16.1:2
		gnome-base/gnome-desktop
		gnome-base/gconf:2
	)
	gtk? (
		>=x11-libs/gtk+-2.8.0:2
		>=x11-libs/libwnck-2.18.3
		x11-libs/pango
	)
	kde? (
		|| (
			>=kde-base/kwin-4.2.0
			kde-base/kwin:live
		)
	)
	kde3? (
		|| ( kde-base/kwin:3.5
			kde-base/kdebase:3.5
		)
		dev-libs/dbus-qt3-old
	)
	svg? (
		>=gnome-base/librsvg-2.14.0:2
		>=x11-libs/cairo-1.0
	)
"

RDEPEND="${DEPEND}
	x11-apps/mesa-progs
	x11-apps/xvinfo"

DEPEND="${DEPEND}
	dev-util/pkgconfig
	x11-proto/damageproto
	x11-proto/xineramaproto"

src_prepare() {

	echo "gtk/gnome/compiz-wm.desktop.in" >> "${S}/po/POTFILES.skip"
	echo "metadata/core.xml.in" >> "${S}/po/POTFILES.skip"

	# Missing gconf flags, fix bug #282807
	epatch "${FILESDIR}"/${P}-gtk-gnome-missing-gconf-flags.patch

	if ! use gnome; then
		epatch "${FILESDIR}"/${PN}-no-gconf.patch
	fi
	eautoreconf
}

src_configure() {
	econf --disable-gnome-keybindings \
		--enable-librsvg \
		--with-default-plugins \
		$(use_enable cairo annotate) \
		$(use_enable dbus) \
		$(use_enable dbus dbus-glib) \
		$(use_enable fuse) \
		$(use_enable gnome) \
		$(use_enable gnome gconf) \
		$(use_enable gnome metacity) \
		$(use_enable gtk) \
		$(use_enable kde kde4) \
		$(use_enable kde3 kde)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# Install compiz-manager
	dobin "${FILESDIR}/compiz-manager" || die "dobin failed"

	# Add the full-path to lspci
	sed -i "s#lspci#/usr/sbin/lspci#" "${D}/usr/bin/compiz-manager" || die "sed 1 failed"

	# Fix the hardcoded lib paths
	sed -i "s#/lib/#/$(get_libdir)/#g" "${D}/usr/bin/compiz-manager" || die "sed 2 failed"

	# Create gentoo's config file
	dodir /etc/xdg/compiz || die "dodir failed"

	cat <<- EOF > "${D}/etc/xdg/compiz/compiz-manager"
	COMPIZ_BIN_PATH="/usr/bin/"
	PLUGIN_PATH="/usr/$(get_libdir)/compiz/"
	LIBGL_NVIDIA="/usr/$(get_libdir)/opengl/xorg-x11/lib/libGL.so.1.2"
	LIBGL_FGLRX="/usr/$(get_libdir)/opengl/xorg-x11/lib/libGL.so.1.2"
	KWIN="$(type -p kwin)"
	METACITY="$(type -p metacity)"
	SKIP_CHECKS="yes"
	EOF

	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"

	insinto "/usr/share/applications"
	doins "${FILESDIR}/compiz.desktop" || die "Failed to install compiz.desktop"
}

pkg_preinst() {
	use gnome && gnome2_gconf_savelist
}

pkg_postinst() {
	use gnome && gnome2_gconf_install

	ewarn "If you update to x11-wm/metacity-2.24 after you install ${P},"
	ewarn "gtk-window-decorator will crash until you reinstall ${PN} again."
}

pkg_prerm() {
	use gnome && gnome2_gconf_uninstall
}