[gentoo-commits] repo/gentoo:master commit in: app-misc/pdfpc/

[Ulrich Müller]

commit:     b6a75e9258da04390f5cc419dc381a39166c1ec4
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 24 07:46:57 2022 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Fri Jun 24 07:49:25 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b6a75e92

app-misc/pdfpc: Update vala versions

Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 app-misc/pdfpc/pdfpc-4.5.0-r1.ebuild | 74 ++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)

diff --git a/app-misc/pdfpc/pdfpc-4.5.0-r1.ebuild b/app-misc/pdfpc/pdfpc-4.5.0-r1.ebuild
new file mode 100644
index 000000000000..19911fdc5956
--- /dev/null
+++ b/app-misc/pdfpc/pdfpc-4.5.0-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VALA_MIN_API_VERSION="0.50"
+VALA_MAX_API_VERSION="0.56" # append versions in sed line if increased
+
+#COMMIT_ID=""
+
+inherit cmake vala
+
+DESCRIPTION="Presenter console with multi-monitor support for PDF files"
+HOMEPAGE="https://pdfpc.github.io https://github.com/pdfpc/pdfpc"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit git-r3
+elif [[ ${PV} == *_p* ]]; then
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT_ID}"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gstreamer"
+
+RDEPEND="
+	app-text/discount
+	app-text/poppler:=[cairo]
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libgee:0.8=
+	gnome-base/librsvg
+	net-libs/webkit-gtk:4=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/pango
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-plugins/gst-plugins-gtk:1.0=
+		media-plugins/gst-plugins-cairo:1.0=
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="$(vala_depend)"
+
+DOCS=(
+	CHANGELOG.rst
+	FAQ.rst
+	README.rst
+	SUPPORT.rst
+)
+
+src_prepare() {
+	cmake_src_prepare
+	vala_setup
+	sed -i -e "/find_program/s/valac/& &-0.56 &-0.54 &-0.52 &-0.50/" \
+		cmake/vala/FindVala.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DMOVIES=$(usex gstreamer on off)
+		-DCMAKE_VERBOSE_MAKEFILE=TRUE
+	)
+	cmake_src_configure
+}