[gentoo-commits] repo/gentoo:master commit in: dev-libs/template-glib/

[Matt Turner]

commit:     6af4f1052d4e787d3c1789d324ce60ead4b8b25b
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 24 19:24:26 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Sep 24 20:04:17 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6af4f105

dev-libs/template-glib: Version bump to 3.36.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/template-glib/Manifest                    |  1 +
 dev-libs/template-glib/template-glib-3.36.0.ebuild | 49 ++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-libs/template-glib/Manifest b/dev-libs/template-glib/Manifest
index 59c8c3ce5136..796f7a6fdb1e 100644
--- a/dev-libs/template-glib/Manifest
+++ b/dev-libs/template-glib/Manifest
@@ -1 +1,2 @@
 DIST template-glib-3.34.1.tar.xz 57540 BLAKE2B 2ceff1ef04fe846d8b5a7c4b54d0bc572323e607fb72812bcc93152caf1d4e9de36a27705a53a0c1add924d95a92d597256bc5450f1ff598c1fd5b0157a87051 SHA512 9f518fa3331fdef808f219792e1664787150c9e4b1b1a43662badde4ba8cf6d49faf1f97f0f4faab9e31c86a3f65e637f62d752fa6725c052ae099f29f3999fc
+DIST template-glib-3.36.0.tar.xz 64132 BLAKE2B 10a9fbf8f98efaaf92b8679ea3b08dc510b9b5744239c19f180efc3a1a54f8edec2b1c6775e336d5a143fc8cac566d507337e656154a1984404a84f0b9b88c2b SHA512 51e1adf581fef05ec46ed3dd9ba61c27b02138009e2f994a0dded62216372445e59676d6f8bbca979e44825722c913a1435a8ae7b6d1e7e41dc510654420647b

diff --git a/dev-libs/template-glib/template-glib-3.36.0.ebuild b/dev-libs/template-glib/template-glib-3.36.0.ebuild
new file mode 100644
index 000000000000..56b997acfee1
--- /dev/null
+++ b/dev-libs/template-glib/template-glib-3.36.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala
+
+DESCRIPTION="Templating library for GLib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/template-glib"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="gtk-doc +introspection test vala"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection:=
+" # depends on go-i unconditionally for own functionality, USE flag controls GIR/typelib generation
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	sys-devel/bison
+	sys-devel/flex
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dtracing=false # extra trace debugging that would make things slower
+		-Dprofiling=false # -pg passing
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}