[gentoo-commits] gentoo-x86 commit in dev-java/bcprov: bcprov-1.50.ebuild ChangeLog

[Tom Wijsman (tomwij)]

tomwij      14/02/06 13:58:56

  Modified:             ChangeLog
  Added:                bcprov-1.50.ebuild
  Log:
  Version bump to 1.50.
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.59                 dev-java/bcprov/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/bcprov/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	1 Sep 2013 11:42:36 -0000	1.58
+++ ChangeLog	6 Feb 2014 13:58:56 -0000	1.59
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/bcprov
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/bcprov/ChangeLog,v 1.58 2013/09/01 11:42:36 grobian Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/bcprov/ChangeLog,v 1.59 2014/02/06 13:58:56 tomwij Exp $
+
+*bcprov-1.50 (06 Feb 2014)
+
+  06 Feb 2014; Tom Wijsman <TomWij@g.o> +bcprov-1.50.ebuild:
+  Version bump to 1.50.
 
   01 Sep 2013; Fabian Groffen <grobian@g.o> bcprov-1.38-r2.ebuild:
   Marked *-macos



1.1                  dev-java/bcprov/bcprov-1.50.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/bcprov-1.50.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcprov/bcprov-1.50.ebuild?rev=1.1&content-type=text/plain

Index: bcprov-1.50.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/bcprov/bcprov-1.50.ebuild,v 1.1 2014/02/06 13:58:56 tomwij Exp $

EAPI="5"

JAVA_PKG_IUSE="doc source test"

inherit java-pkg-2 java-ant-2

MY_P="${PN}-jdk15on-${PV/./}"
DESCRIPTION="Java cryptography APIs"
HOMEPAGE="http://www.bouncycastle.org/java.html"
SRC_URI="http://www.bouncycastle.org/download/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x64-macos"

# Tests are currently broken. Needs further investigation.
# java.security.NoSuchAlgorithmException: Cannot find any provider supporting McElieceFujisakiWithSHA256
RESTRICT="test"

# The src_unpack find needs a new find
# https://bugs.gentoo.org/show_bug.cgi?id=182276
DEPEND=">=virtual/jdk-1.5
	userland_GNU? ( >=sys-apps/findutils-4.3 )
	app-arch/unzip
	test? ( dev-java/junit:4 )"
RDEPEND=">=virtual/jre-1.5"

IUSE="userland_GNU"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	default

	cd "${S}" || die
	unpack ./src.zip
}

java_prepare() {
	mkdir "${S}"/classes || die

	if use test ; then
		java-pkg_jar-from --build-only junit-4
	fi
}

src_compile() {
	find . -name "*.java" > "${T}"/src.list

	local cp
	if use test ; then
		cp="-cp junit.jar"
	else
		sed -i '/\/test\//d' "${T}"/src.list || die "Failed to remove test classes"
	fi

	ejavac $cp -encoding ISO-8859-1 -d "${S}"/classes "@${T}"/src.list

	cd "${S}"/classes || die

	jar -cf "${S}"/${PN}.jar * || die "Failed to create jar."
}

src_test() {
	java -cp ${PN}.jar:junit.jar org.bouncycastle.pqc.jcajce.provider.test.AllTests | tee pqc.tests
	java -cp ${PN}.jar:junit.jar org.bouncycastle.ocsp.test.AllTests | tee oscp.tests
	java -cp ${PN}.jar:junit.jar org.bouncycastle.jce.provider.test.AllTests | tee jce.tests

	grep -q FAILURES *.tests && die "Tests failed."
}

src_install() {
	java-pkg_dojar ${PN}.jar

	use source && java-pkg_dosrc org
	use doc && java-pkg_dojavadoc docs
}