[gentoo-commits] repo/gentoo:master commit in: dev-python/moto/

[Michał Górny]

commit:     fa420188a2a93cc94b377941e050076fe4270aa3
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 22 07:08:50 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Aug 22 08:01:31 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa420188

dev-python/moto: Bump to 2.2.4

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/moto/Manifest          |  1 +
 dev-python/moto/moto-2.2.4.ebuild | 75 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index f50448c1a10..1b7f4cf3727 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -3,3 +3,4 @@ DIST moto-2.0.5.tar.gz 1551415 BLAKE2B 452cb94443188e1715145bee574f04924d894a3d6
 DIST moto-2.2.0.tar.gz 1650655 BLAKE2B 9969de2fb323b2deb272eb47727884054a35827a5db382f83a4177cf6cac5339f89164d05c288a977bc1895a204d13d02069e8b37880ea3d04374f6ed4d6be47 SHA512 7eabb515f94920af9b8f028afaaa51e27983f7bfd73f66c29fc191e2f3dd3e8939ddac67de0127c67c35cbc17c3500a7390103b26c85056780c865aadeb5e1d9
 DIST moto-2.2.2.tar.gz 1684678 BLAKE2B ebe1eb08c67ccdb8c484fa8fc75d7ce58750d94620f46b53268d6b6b0732d90160bf7b6837efa492f621e1c001d933f5d59d39c266d65bbb1852f315b3bc03d0 SHA512 a8b192637b701eda0e4a7b11e84f5251386de98590f1d7c33732d8bf12642b39b61f1d360ad39c3e1b0a645268139d9e330d48fbe7029b943094ad317cb45ff6
 DIST moto-2.2.3.tar.gz 1700636 BLAKE2B 926fe245ce457dd79eef6780fc0b984d2ff1cbe95807a3463f0d0080583af2ba356ccfcce22e60927737e1531ec7bc167c5f649e784b191ec821aa56df65277d SHA512 0b46229ae06db7cb2634df3f1b3b1a6b6fc983978a763e8879db0d9e209ccc6b96b28e8e2ee40f6e1a8e39b74d7a2430788126220e3a7dab5e8df217c3c8c005
+DIST moto-2.2.4.tar.gz 1724663 BLAKE2B 3feb39bec246a8157aa542c711289ab0ca257ec510835cd48aa732c3f07903db857971e3d024c1aef35b5a0b55b7c4ecef2b319824c1d76f0076ab8d2d75329e SHA512 8acd8a3156db71af35ad0ac6a5105a6b7739d8ca9881a2cb091637830bc6fbb10d8bf6adfd1a1091556f9269fad737b345d2bdf50e09b54201fe7438674dd906

diff --git a/dev-python/moto/moto-2.2.4.ebuild b/dev-python/moto/moto-2.2.4.ebuild
new file mode 100644
index 00000000000..afcc32f2336
--- /dev/null
+++ b/dev-python/moto/moto-2.2.4.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/boto[${PYTHON_USEDEP}]
+	dev-python/cfn-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	dev-python/dicttoxml[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.9.201[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.12.201[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# unpin indirect dep on ecdsa that's supposed to workaround pip bugs
+	sed -i -e '/ecdsa/s:<0.15::' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local ignore=(
+		# incompatible versions?
+		tests/test_core/test_decorator_calls.py
+		tests/test_s3/test_s3_classdecorator.py
+	)
+
+	# pytest-django causes freezegun try to mangle stuff inside django
+	# which fails when django is not really used
+	epytest -p no:django -m 'not network' ${ignore[@]/#/--ignore }
+}