[gentoo-commits] gentoo-x86 commit in net-misc/ps3mediaserver: metadata.xml ps3mediaserver-1.50.0.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     11/11/30 06:38:30

  Modified:             metadata.xml ChangeLog
  Added:                ps3mediaserver-1.50.0.ebuild
  Log:
  Version bump. Add multiuser use flag to control launcher behavior.
  
  (Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  net-misc/ps3mediaserver/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	4 Nov 2011 04:16:52 -0000	1.3
+++ metadata.xml	30 Nov 2011 06:38:30 -0000	1.4
@@ -9,6 +9,7 @@
 	<name>Mike Gilbert</name>
 </maintainer>
 <use>
+	<flag name="multiuser">Allow renderer customization per-user.</flag>
 	<flag name="transcode">Install optional dependencies for transcoding support via media-video/mplayer</flag>
 	<flag name="tsmuxer">Install optional dependencies for transcoding support via media-video/tsmuxer</flag>
 </use>



1.4                  net-misc/ps3mediaserver/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	4 Nov 2011 04:16:52 -0000	1.3
+++ ChangeLog	30 Nov 2011 06:38:30 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/ps3mediaserver
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v 1.3 2011/11/04 04:16:52 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ChangeLog,v 1.4 2011/11/30 06:38:30 floppym Exp $
+
+*ps3mediaserver-1.50.0 (30 Nov 2011)
+
+  30 Nov 2011; Mike Gilbert <floppym@g.o> +ps3mediaserver-1.50.0.ebuild,
+  metadata.xml:
+  Version bump. Add multiuser use flag to control launcher behavior.
 
 *ps3mediaserver-1.40.0 (04 Nov 2011)
 



1.1                  net-misc/ps3mediaserver/ps3mediaserver-1.50.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.50.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.50.0.ebuild?rev=1.1&content-type=text/plain

Index: ps3mediaserver-1.50.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/ps3mediaserver/ps3mediaserver-1.50.0.ebuild,v 1.1 2011/11/30 06:38:30 floppym Exp $

EAPI="4"

inherit eutils

DESCRIPTION="DLNA compliant UPNP server for streaming media to Playstation 3"
HOMEPAGE="http://code.google.com/p/ps3mediaserver"
SRC_URI="http://ps3mediaserver.googlecode.com/files/pms-generic-linux-unix-${PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="multiuser +transcode tsmuxer"

DEPEND="app-arch/unzip"
RDEPEND=">=virtual/jre-1.6.0
	media-libs/libmediainfo
	media-libs/libzen
	tsmuxer? ( media-video/tsmuxer )
	transcode? ( media-video/mplayer[encode] )"

S=${WORKDIR}/pms-linux-${PV}
PMS_HOME=/opt/${PN}

src_prepare() {
	if use multiuser; then
		echo multiuser is on
		cat > ${PN} <<-EOF
		#!/bin/sh
		if [ ! -e ~/.${PN} ]; then
			echo "Copying ${PMS_HOME} to ~/.${PN}"
			cp -pPR "${PMS_HOME}" ~/.${PN}
		fi
		export PMS_HOME=~/.${PN}
		exec "\${PMS_HOME}/PMS.sh" "\$@"
		EOF
	else
		cat > ${PN} <<-EOF
		#!/bin/sh
		export PMS_HOME=${PMS_HOME}
		exec "\${PMS_HOME}/PMS.sh" "\$@"
		EOF
	fi

	cat > ${PN}.desktop <<-EOF
	[Desktop Entry]
	Name=PS3 Media Server
	GenericName=Media Server
	Exec=${PN}
	Icon=${PN}
	Type=Application
	Categories=Network;
	EOF

	unzip -j pms.jar resources/images/icon-{32,256}.png || die
}

src_install() {
	dobin ${PN}

	exeinto ${PMS_HOME}
	doexe PMS.sh

	insinto ${PMS_HOME}
	doins -r pms.jar *.conf documentation plugins renderers *.xml
	use tsmuxer && dosym /opt/tsmuxer/bin/tsMuxeR ${PMS_HOME}/linux/tsMuxeR
	dodoc CHANGELOG README

	insinto /usr/share/icons/hicolor/32x32/apps
	newins icon-32.png ${PN}.png
	insinto /usr/share/icons/hicolor/256x256/apps
	newins icon-256.png ${PN}.png

	domenu ${PN}.desktop
}

pkg_postinst() {
	ewarn "Don't forget to disable transcoding engines for software"
	ewarn "that you don't have installed (such as having the VLC"
	ewarn "transcoding engine enabled when you only have mencoder)."
	if use multiuser; then
		echo
		ewarn "Make sure to refresh the .${PN} in your home directory if you are"
		ewarn "upgrading from a previous version."
	fi
}