[gentoo-commits] gentoo-x86 commit in dev-embedded/openocd: ChangeLog openocd-0.5.0_pre20110427.ebuild

[Markos Chandras (hwoarang)]

hwoarang    11/04/28 00:30:20

  Modified:             ChangeLog
  Added:                openocd-0.5.0_pre20110427.ebuild
  Log:
  Add new snapshot
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.15                 dev-embedded/openocd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/openocd/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/openocd/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/openocd/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-embedded/openocd/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	17 Mar 2011 12:50:00 -0000	1.14
+++ ChangeLog	28 Apr 2011 00:30:20 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for dev-embedded/openocd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-embedded/openocd/ChangeLog,v 1.14 2011/03/17 12:50:00 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/openocd/ChangeLog,v 1.15 2011/04/28 00:30:20 hwoarang Exp $
+
+*openocd-0.5.0_pre20110427 (28 Apr 2011)
+
+  28 Apr 2011; Markos Chandras <hwoarang@g.o>
+  +openocd-0.5.0_pre20110427.ebuild:
+  Add new snapshot
 
   17 Mar 2011; Markos Chandras <hwoarang@g.o>
   openocd-0.5.0_pre20110317.ebuild, openocd-9999.ebuild:



1.1                  dev-embedded/openocd/openocd-0.5.0_pre20110427.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/openocd/openocd-0.5.0_pre20110427.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/openocd/openocd-0.5.0_pre20110427.ebuild?rev=1.1&content-type=text/plain

Index: openocd-0.5.0_pre20110427.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/openocd/openocd-0.5.0_pre20110427.ebuild,v 1.1 2011/04/28 00:30:20 hwoarang Exp $

EAPI="2"

inherit autotools eutils
if [[ ${PV} == "9999" ]] ; then
	inherit git
	KEYWORDS=""
	EGIT_REPO_URI="git://openocd.git.sourceforge.net/gitroot/openocd/openocd"
else
	KEYWORDS="~amd64 ~x86"
	SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${P}.tar.gz"
fi

DESCRIPTION="OpenOCD - Open On-Chip Debugger"
HOMEPAGE="http://openocd.berlios.de/web/"

LICENSE="GPL-2"
SLOT="0"
IUSE="blaster ftd2xx ftdi parport presto segger versaloon usb"
RESTRICT="strip" # includes non-native binaries

# libftd2xx is the default because it is reported to work better.
DEPEND="dev-lang/jimtcl
	usb? ( dev-libs/libusb )
	presto? ( dev-embedded/libftd2xx )
	ftd2xx? ( dev-embedded/libftd2xx )
	ftdi? ( dev-embedded/libftdi )"
RDEPEND="${DEPEND}"

pkg_setup() {
	if use ftdi && use ftd2xx ; then
		ewarn "You can only use one FTDI library at a time, so picking"
		ewarn "USE=ftdi (open source) over USE=ftd2xx (closed source)"
	fi
}

src_prepare() {
		[[ ${PV} != "9999" ]]  && sed -i -e "/@include version.texi/d" doc/${PN}.texi
		AT_NO_RECURSIVE=yes eautoreconf
}

src_configure() {
	if use usb;then
		myconf="${myconf} --enable-usbprog --enable-jlink --enable-rlink \
			--enable-vsllink --enable-arm-jtag-ew"
	fi
	[[ ${PV} != "9999" ]] && myconf="${myconf} --enable-maintainer-mode"
	# add explicitely the path to libftd2xx
	use ftd2xx && ! use ftdi && LDFLAGS="${LDFLAGS} -L/opt/$(get_libdir)"
	econf \
		--disable-werror \
		--disable-internal-jimtcl \
		--enable-amtjtagaccel \
		--enable-ep93xx \
		--enable-at91rm9200 \
		--enable-gw16012 \
		--enable-oocd_trace \
		$(use_enable blaster usb_flaster_libftdi) \
		$(use_enable ftdi ft2232_libftdi) \
		$(use ftdi || use_enable ftd2xx ft2232_ftd2xx) \
		$(use_enable parport) \
		$(use_enable presto presto_ftd2xx) \
		$(use_enable segger jlink) \
		$(use_enable versaloon vsllink) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README TODO || die
	prepstrip "${D}"/usr/bin
}