[gentoo-commits] repo/gentoo:master commit in: dev-libs/amdgpu-pro-opencl/

[Marek Szuba]

commit:     8ded910c42a3382278b213c2af0911bd0941e91a
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  6 16:36:21 2017 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sun Aug  6 16:38:08 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8ded910c

dev-libs/amdgpu-pro-opencl: add missing file to 17.30.458935

Package-Manager: Portage-2.3.6, Repoman-2.3.1

 .../amdgpu-pro-opencl-17.30.458935-r1.ebuild       | 81 ++++++++++++++++++++++
 1 file changed, 81 insertions(+)

diff --git a/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.30.458935-r1.ebuild b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.30.458935-r1.ebuild
new file mode 100644
index 00000000000..971d4999df4
--- /dev/null
+++ b/dev-libs/amdgpu-pro-opencl/amdgpu-pro-opencl-17.30.458935-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit unpacker versionator
+
+SUPER_PN='amdgpu-pro'
+MY_PV=$(replace_version_separator 2 '-')
+
+DESCRIPTION="Proprietary OpenCL implementation for AMD GPUs"
+HOMEPAGE="https://support.amd.com/en-us/kb-articles/Pages/AMDGPU-PRO-Driver-for-Linux-Release-Notes.aspx"
+SRC_URI="${SUPER_PN}-${MY_PV}.tar.xz"
+
+LICENSE="AMD-GPU-PRO-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="mirror fetch strip"
+
+DEPEND="dev-util/patchelf"
+RDEPEND="dev-libs/ocl-icd"
+
+QA_PREBUILT="/opt/${SUPER_PN}/lib*/*"
+
+S="${WORKDIR}/${SUPER_PN}-${MY_PV}"
+
+pkg_nofetch() {
+	local pkgver=$(get_version_component_range 1-2)
+	einfo "Please download the AMDGPU-Pro Driver ${pkgver} for Ubuntu from"
+	einfo "    ${HOMEPAGE}"
+	einfo "The archive should then be placed into ${DISTDIR}."
+}
+
+src_unpack() {
+	default
+
+	local ids_ver="1.0.0"
+	local libdrm_ver="2.4.70"
+	local patchlevel=$(get_version_component_range 3)
+	cd "${S}" || die
+	unpack_deb opencl-${SUPER_PN}-icd_${MY_PV}_amd64.deb
+	unpack_deb libdrm-${SUPER_PN}-amdgpu1_${libdrm_ver}-${patchlevel}_amd64.deb
+	unpack_deb ids-${SUPER_PN}_${ids_ver}-${patchlevel}_all.deb
+}
+
+src_prepare() {
+	default
+
+	cd "${S}/opt/${SUPER_PN}/lib/x86_64-linux-gnu" || die
+	patchelf --set-rpath '$ORIGIN' libamdocl64.so || die "Failed to fix library rpath"
+}
+
+src_install() {
+
+	into "/opt/${SUPER_PN}"
+	dolib opt/${SUPER_PN}/lib/x86_64-linux-gnu/*
+	insinto "/opt/${SUPER_PN}"
+	doins -r opt/${SUPER_PN}/share
+
+	insinto /etc/OpenCL/vendors/
+	echo "/opt/${SUPER_PN}/$(get_libdir)/libamdocl64.so" > "${SUPER_PN}.icd" || die "Failed to generate ICD file"
+	doins "${SUPER_PN}.icd"
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		ewarn "Please note that using proprietary OpenCL libraries together with the"
+		ewarn "Open Source amdgpu stack is not officially supported by AMD. Do not ask them"
+		ewarn "for support in case of problems with this package."
+		ewarn ""
+		ewarn "Furthermore, if you have the whole AMDGPU-Pro stack installed this package"
+		ewarn "will almost certainly conflict with it. This might change once AMDGPU-Pro"
+		ewarn "has become officially supported by Gentoo."
+	fi
+
+	elog "AMD OpenCL driver relies on dev-libs/ocl-icd to work. To enable it, please run"
+	elog ""
+	elog "    eselect opencl set ocl-icd"
+	elog ""
+}