[gentoo-commits] repo/gentoo:master commit in: media-video/baka-mplayer/files/, media-video/baka-mplayer/

[Andreas Sturmlechner]

commit:     dea05089bb72d9ac4d591b38c4ba5554a73a56f7
Author:     Christopher Steward <cstew764 <AT> gmail <DOT> com>
AuthorDate: Wed Dec 11 14:27:07 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jan 21 19:10:49 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dea05089

media-video/baka-mplayer: fix mpv >=0.23.0 support

Signed-off-by: Christopher Steward <cstew764 <AT> gmail.com>
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../baka-mplayer/baka-mplayer-2.0.4-r1.ebuild      | 51 ++++++++++++++++++++++
 .../files/baka-mplayer-2.0.4-mpv23.patch           | 13 ++++++
 2 files changed, 64 insertions(+)

diff --git a/media-video/baka-mplayer/baka-mplayer-2.0.4-r1.ebuild b/media-video/baka-mplayer/baka-mplayer-2.0.4-r1.ebuild
new file mode 100644
index 00000000000..e13186333ae
--- /dev/null
+++ b/media-video/baka-mplayer/baka-mplayer-2.0.4-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils
+
+DESCRIPTION="Cross-platform libmpv-based multimedia player with uncluttered design"
+HOMEPAGE="http://bakamplayer.u8sand.net/"
+SRC_URI="https://github.com/u8sand/Baka-MPlayer/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-video/mpv[libmpv]
+	x11-libs/libX11"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/Baka-MPlayer-${PV}"
+
+PATCHES=( "${FILESDIR}/${P}-gcc5.patch" "${FILESDIR}/${P}-mpv23.patch" )
+
+src_prepare() {
+	default
+	# no need to install license
+	sed -e '/^INSTALLS/s:license::' -i src/Baka-MPlayer.pro || die
+	# put manual in our docdir
+	sed -e '/^manual.path/s:'${PN}':'${PF}':' -i src/Baka-MPlayer.pro || die
+}
+
+src_configure() {
+	eqmake5 \
+		INSTROOT="${D}" \
+		CONFIG+=install_translations \
+		lrelease="$(qt5_get_bindir)"/lrelease \
+		lupdate="$(qt5_get_bindir)"/lupdate \
+		src/Baka-MPlayer.pro
+}

diff --git a/media-video/baka-mplayer/files/baka-mplayer-2.0.4-mpv23.patch b/media-video/baka-mplayer/files/baka-mplayer-2.0.4-mpv23.patch
new file mode 100644
index 00000000000..ef5551cef81
--- /dev/null
+++ b/media-video/baka-mplayer/files/baka-mplayer-2.0.4-mpv23.patch
@@ -0,0 +1,13 @@
+diff --git a/src/mpvhandler.cpp b/src/mpvhandler.cpp
+index 7ba06e4..b9ccbeb 100644
+--- a/src/mpvhandler.cpp
++++ b/src/mpvhandler.cpp
+@@ -675,7 +675,7 @@ void MpvHandler::LoadFileInfo()
+     fileInfo.media_title = mpv_get_property_string(mpv, "media-title");
+     // get length
+     double len;
+-    mpv_get_property(mpv, "length", MPV_FORMAT_DOUBLE, &len);
++    mpv_get_property(mpv, "duration", MPV_FORMAT_DOUBLE, &len);
+     fileInfo.length                  = (int)len;
+ 
+     LoadTracks();