[gentoo-commits] gentoo-x86 commit in net-libs/aqbanking: ChangeLog aqbanking-5.0.24.0.ebuild

[Hanno Boeck (hanno)]

hanno       12/06/03 17:51:26

  Modified:             ChangeLog
  Added:                aqbanking-5.0.24.0.ebuild
  Log:
  aqbanking bump
  
  (Portage version: 2.1.10.64/cvs/Linux x86_64)

Revision  Changes    Path
1.97                 net-libs/aqbanking/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/ChangeLog?rev=1.97&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/ChangeLog?rev=1.97&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/ChangeLog?r1=1.96&r2=1.97

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v
retrieving revision 1.96
retrieving revision 1.97
diff -u -r1.96 -r1.97
--- ChangeLog	13 May 2012 12:44:56 -0000	1.96
+++ ChangeLog	3 Jun 2012 17:51:26 -0000	1.97
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/aqbanking
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v 1.96 2012/05/13 12:44:56 hanno Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/ChangeLog,v 1.97 2012/06/03 17:51:26 hanno Exp $
+
+*aqbanking-5.0.24.0 (03 Jun 2012)
+
+  03 Jun 2012; Hanno Boeck <hanno@g.o> +aqbanking-5.0.24.0.ebuild:
+  Version bump.
 
 *aqbanking-5.0.23 (13 May 2012)
 



1.1                  net-libs/aqbanking/aqbanking-5.0.24.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/aqbanking-5.0.24.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/aqbanking/aqbanking-5.0.24.0.ebuild?rev=1.1&content-type=text/plain

Index: aqbanking-5.0.24.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/aqbanking/aqbanking-5.0.24.0.ebuild,v 1.1 2012/06/03 17:51:26 hanno Exp $

EAPI=4

DESCRIPTION="Generic Online Banking Interface"
HOMEPAGE="http://www.aquamaniac.de/aqbanking/"
SRC_URI="http://www.aquamaniac.de/sites/download/download.php?package=03&release=94&file=01&dummy=${P}-git.tar.gz -> ${P}-git.tar.gz"
S="${WORKDIR}/${P}-git"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="chipcard debug doc examples gtk ofx"

RDEPEND=">=app-misc/ktoblzcheck-1.37
	>=dev-libs/gmp-5
	>=sys-libs/gwenhywfar-4.3.3[gtk?]
	virtual/libintl
	ofx? ( >=dev-libs/libofx-0.9.4 )
	chipcard? ( >=sys-libs/libchipcard-5.0.2 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	sys-devel/gettext
	doc? ( app-doc/doxygen )"

MAKEOPTS="${MAKEOPTS} -j1" # 5.0.x fails with -j9 on quadcore

src_configure() {
	local backends="aqhbci aqnone aqpaypal"
	use ofx && backends="${backends} aqofxconnect"

	local mytest
	use gtk && mytest="--enable-gui-tests"

	econf \
		$(use_enable debug) \
		$(use_enable doc full-doc) \
		--with-backends="${backends}" \
		--with-docpath=/usr/share/doc/${PF}/apidoc \
		${mytest}
}

src_install() {
	emake DESTDIR="${D}" install

	rm -rf "${ED}"usr/share/doc/aq{banking,hbci,paypal}

	dodoc AUTHORS ChangeLog NEWS README TODO

	newdoc src/plugins/backends/aqhbci/tools/aqhbci-tool/README \
		README.aqhbci-tool
	newdoc src/plugins/backends/aqpaypal/tools/aqpaypal-tool/README \
		README.aqpaypal-tool

	if use examples; then
		docinto tutorials
		dodoc tutorials/*.{c,h} tutorials/README
	fi

	find "${ED}" -name '*.la' -exec rm -f {} +
}