[gentoo-commits] repo/gentoo:master commit in: dev-libs/libofx/

[Sam James]

commit:     0672d60affa9c4842f9dc48895692586de946b4c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 29 22:53:09 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Sep 29 22:53:31 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0672d60a

dev-libs/libofx: add 0.10.3

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/libofx/Manifest             |  1 +
 dev-libs/libofx/libofx-0.10.3.ebuild | 65 ++++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-libs/libofx/Manifest b/dev-libs/libofx/Manifest
index db53570ab1e..c8a6b9e57ad 100644
--- a/dev-libs/libofx/Manifest
+++ b/dev-libs/libofx/Manifest
@@ -1,2 +1,3 @@
 DIST libofx-0.10.1.tar.gz 226512 BLAKE2B bc0fa1ea0d5c7968730b50b9163a045304dd82f7e312e407ce9393a56ea6b1f9d47382b1299ee990640b98d5f047656aa38a9a8da4d8f19d3bea0236e0487cf1 SHA512 4575424abb56b93021ef223f90460979b544c32b4624936bbad16d0b5711afb6b5fa31b7c2cb835ff7a26be8c7ac51951198e5565a098713b8d33f0e17be774a
 DIST libofx-0.10.2.tar.gz 225043 BLAKE2B 2ca8cdd9913f2bddb60600d75acfb114d56d6c59191fe2b836a0c2a988b6d0404821a9f99be1fa4b258afbbc35b0cb254b348a1e7a0f7a8c4010645afff52f91 SHA512 14ba2779d94209312a8a1bbf598e6a31820df4fa7e222ae1abb8d4234a6c7ba7068e06a73ad4ee93bcb53ccb99a8007d799d9e66a9921704dc75c84b0e7dc307
+DIST libofx-0.10.3.tar.gz 225132 BLAKE2B 29dff4cb79a4a535bf255c787e184d103ecdbe975bb4bb223b675bbacaff9f8a228ae0a3dffe7710c2707496ac65c4f48ce993243b8353172c53cb02067d9267 SHA512 6c024628a6a11d9542c669a438223331a033eb820b1a2c3001c60d1ab3fad45ccdec64f9b54dd206fe0058ead8e14e751eb7a3bd88e8f9e1013b0bdd5b6c5242

diff --git a/dev-libs/libofx/libofx-0.10.3.ebuild b/dev-libs/libofx/libofx-0.10.3.ebuild
new file mode 100644
index 00000000000..ae5c04394d4
--- /dev/null
+++ b/dev-libs/libofx/libofx-0.10.3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Library to support the Open Financial eXchange XML format"
+HOMEPAGE="https://github.com/libofx/libofx"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/10"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-util/gengetopt
+	sys-apps/help2man
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( app-crypt/gnupg )
+"
+RDEPEND="
+	>app-text/opensp-1.5
+	app-text/openjade
+	>=dev-cpp/libxmlpp-2.40.1:2.6
+	>=net-misc/curl-7.9.7
+	virtual/libiconv
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# Not included in the tarball
+	sed -i -e '/INSTALL/d' Makefile.am || die
+
+	# bug #566456
+	append-cxxflags -std=c++14
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable doc html-docs) \
+		--disable-static
+}
+
+src_compile() {
+	emake -j1
+
+	if use doc ; then
+		emake doc
+	fi
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -type f -delete || die
+	find "${ED}" -name '*.a' -type f -delete || die
+}