[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

[Conrad Kostecki]

commit:     cb33d759afd231265771d394446d348e2bcadd3e
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Fri May 27 22:45:31 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri May 27 22:47:35 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb33d759

app-emulation/86Box: add 3.5

Bug: https://bugs.gentoo.org/847490
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-3.5.ebuild | 69 ++++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest         |  1 +
 2 files changed, 70 insertions(+)

diff --git a/app-emulation/86Box/86Box-3.5.ebuild b/app-emulation/86Box/86Box-3.5.ebuild
new file mode 100644
index 000000000000..83e0de773c6f
--- /dev/null
+++ b/app-emulation/86Box/86Box-3.5.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput +dynarec experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	app-emulation/faudio
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+	qt5? ( x11-libs/libXi )
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="$(usex dynarec)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index 09f0e0dab7f7..6ea724bacc72 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
 DIST 86Box-3.4.1.tar.gz 4221251 BLAKE2B 20e3dfbab2a624a834766e4b7767fade045358ef394d3178d02b909e1e696b723e89618bf97e0636bfff882353ae77be23fccc4367513f95fc2e4a08c22d53c5 SHA512 76a4f8d129bdad6d4eef5d34c68b4a90840b00ba0bc2771d07a24ffcf7baa8db6ce2a23936675e0126a2938f48486a734bcebae7f2df2bbaf67ffa7e8dc3b5fa
+DIST 86Box-3.5.tar.gz 4260258 BLAKE2B 080f4b3f4937633cb60a9bba5ac9b70756ffd5096843158033c30ee648fa78d40b539a08383bd5d96e3208ad73ad811c21a24cda08d7ad54188b62753ef2ec2f SHA512 8f40d918e0fbae388a4aa4f037adaa7fa1920cafd5c0493f1f052ee59c677a898226ab7958b8f22899e3983664c2e63c9bcbaf82e27b42efebfb22bdcf4717dc