[gentoo-commits] gentoo-x86 commit in dev-python/psycopg: psycopg-2.5.3.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     14/05/26 08:43:54

  Modified:             ChangeLog
  Added:                psycopg-2.5.3.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.174                dev-python/psycopg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/psycopg/ChangeLog?rev=1.174&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/psycopg/ChangeLog?rev=1.174&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/psycopg/ChangeLog?r1=1.173&r2=1.174

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/psycopg/ChangeLog,v
retrieving revision 1.173
retrieving revision 1.174
diff -u -r1.173 -r1.174
--- ChangeLog	11 Apr 2014 19:51:10 -0000	1.173
+++ ChangeLog	26 May 2014 08:43:54 -0000	1.174
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/psycopg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/psycopg/ChangeLog,v 1.173 2014/04/11 19:51:10 sdamashek Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/psycopg/ChangeLog,v 1.174 2014/05/26 08:43:54 patrick Exp $
+
+*psycopg-2.5.3 (26 May 2014)
+
+  26 May 2014; Patrick Lauer <patrick@g.o> +psycopg-2.5.3.ebuild:
+  Bump
 
   11 Apr 2014; Samuel Damashek <sdamashek@g.o> psycopg-2.5.2.ebuild:
   Add python3_4 to 2.5.2 PYTHON_COMPAT



1.1                  dev-python/psycopg/psycopg-2.5.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/psycopg/psycopg-2.5.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/psycopg/psycopg-2.5.3.ebuild?rev=1.1&content-type=text/plain

Index: psycopg-2.5.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/psycopg/psycopg-2.5.3.ebuild,v 1.1 2014/05/26 08:43:54 patrick Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} )

inherit distutils-r1 flag-o-matic

MY_PN="${PN}2"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="PostgreSQL database adapter for Python"
HOMEPAGE="http://initd.org/psycopg/ http://pypi.python.org/pypi/psycopg2"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
IUSE="debug doc examples"

RDEPEND=">=dev-db/postgresql-base-8.1"
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"

RESTRICT="test"

S="${WORKDIR}/${MY_P}"

python_compile() {
	local CFLAGS=${CFLAGS} CXXFLAGS=${CXXFLAGS}

	[[ ${EPYTHON} != python3* ]] && append-flags -fno-strict-aliasing

	distutils-r1_python_compile
}

python_prepare_all() {
	local PATCHES=(
		"${FILESDIR}/${PN}-2.4.2-setup.py.patch"
	)

	if use debug; then
		sed -i 's/^\(define=\)/\1PSYCOPG_DEBUG,/' setup.cfg || die
	fi

#	if use mxdatetime; then
#		sed -i 's/\(use_pydatetime=\)1/\10/' setup.cfg || die
#	fi

	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C doc -j1 html text
}

python_install_all() {
	distutils-r1_python_install_all

	dodoc doc/{HACKING,SUCCESS}

	if use doc; then
		dodoc doc/psycopg2.txt
		dohtml -r doc/html/.
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r examples/.
	fi
}