[gentoo-commits] proj/qt:master commit in: lxqt-base/lxqt-panel/

[Jauhien Piatlicki]

commit:     c9589ec153991e5f6e1e48c5a1cc51a245927270
Author:     Jauhien Piatlicki <jauhien <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 29 17:07:53 2014 +0000
Commit:     Jauhien Piatlicki <jauhien <AT> gentoo <DOT> org>
CommitDate: Wed Oct 29 17:07:53 2014 +0000
URL:        http://sources.gentoo.org/gitweb/?p=proj/qt.git;a=commit;h=c9589ec1

[lxqt-base/lxqt-panel] 0.8.0 release

---
 lxqt-base/lxqt-panel/Manifest                |  1 +
 lxqt-base/lxqt-panel/lxqt-panel-0.8.0.ebuild | 75 ++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
new file mode 100644
index 0000000..7887d14
--- /dev/null
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -0,0 +1 @@
+DIST lxqt-panel-0.8.0.tar.xz 259284 SHA256 5c453372bf6d35f09400788f6dece1403b63e7cf25abe62066fc9e82c5170b78 SHA512 ffa938586eccd743a676a8a0075a236b763bc3652c9a827c9906e83e87a926ba46a5577e047208b873fe6d53a5f39318aa7e3a1a1525ac89396bb63a52d5c09f WHIRLPOOL 8fa8da6635c423e111a7f37c7624ee0b30d78e5b1524bf78f371f4113a558cee6876f7463083b5c37111f5ec2f4a8079abb15590be0ae846521eb78cd9b39771

diff --git a/lxqt-base/lxqt-panel/lxqt-panel-0.8.0.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-0.8.0.ebuild
new file mode 100644
index 0000000..ff6e532
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-0.8.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+inherit cmake-utils
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="http://www.lxqt.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.lxde.org/git/lxde/${PN}.git"
+else
+	SRC_URI="http://lxqt.org/downloads/lxqt/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0"
+IUSE="+alsa +clock colorpicker cpuload +desktopswitch dom +kbindicator +mainmenu
+	+mount networkmonitor pulseaudio +quicklaunch screensaver sensors
+	+showdesktop sysstat +taskbar teatime +tray +volume worldclock"
+REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
+
+DEPEND="
+	dev-qt/linguist-tools:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	>=lxde-base/menu-cache-0.3.3
+	~lxqt-base/liblxqt-${PV}
+	~lxqt-base/liblxqt-mount-${PV}
+	>=lxqt-base/libsysstat-0.2.0
+	~lxqt-base/lxqt-globalkeys-${PV}
+	>=razorqt-base/libqtxdg-1.0.0
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	networkmonitor? ( sys-libs/libstatgrab )
+	sensors? ( sys-apps/lm_sensors )
+	sysstat? ( >=lxqt-base/libsysstat-0.2.0 )
+	volume? ( alsa? ( media-libs/alsa-lib )
+		pulseaudio? ( media-sound/pulseaudio ) )
+	worldclock? ( dev-libs/icu:= )"
+RDEPEND="${DEPEND}
+	>=lxde-base/lxmenu-data-0.1.2"
+
+src_configure() {
+	local mycmakeargs i y
+	for i in clock colorpicker cpuload desktopswitch dom kbindicator mainmenu mount \
+		networkmonitor quicklaunch screensaver sensors showdesktop sysstat \
+		taskbar teatime tray volume worldclock; do
+		y=$(tr '[:lower:]' '[:upper:]' <<< "${i}")
+		mycmakeargs+=( $(cmake-utils_use ${i} ${y}_PLUGIN) )
+	done
+
+	if use volume; then
+		mycmakeargs+=( $(cmake-utils_use alsa VOLUME_USE_ALSA)
+			$(cmake-utils_use pulseaudio VOLUME_USE_PULSEAUDIO) )
+	fi
+
+	mycmakeargs+=(
+		-DUSE_QT5=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install(){
+	cmake-utils_src_install
+	doman panel/man/*.1
+}