[gentoo-commits] gentoo-x86 commit in dev-libs/kpathsea: kpathsea-6.2.0_p20140523.ebuild ChangeLog

[Manuel Rueger (mrueg)]

mrueg       14/10/05 18:45:07

  Modified:             ChangeLog
  Added:                kpathsea-6.2.0_p20140523.ebuild
  Log:
  Version bump for texlive-2014. Initial commit based on ebuild patch from Franz Fellner (bug #503282) and tarballs from exherbo.
  
  (Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.44                 dev-libs/kpathsea/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	31 Aug 2013 09:41:16 -0000	1.43
+++ ChangeLog	5 Oct 2014 18:45:07 -0000	1.44
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/kpathsea
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/ChangeLog,v 1.43 2013/08/31 09:41:16 grobian Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/ChangeLog,v 1.44 2014/10/05 18:45:07 mrueg Exp $
+
+*kpathsea-6.2.0_p20140523 (05 Oct 2014)
+
+  05 Oct 2014; Manuel Rüger <mrueg@g.o> +kpathsea-6.2.0_p20140523.ebuild:
+  Version bump for texlive-2014. Initial commit based on ebuild patch from Franz
+  Fellner (bug #503282) and tarballs from exherbo.
 
   31 Aug 2013; Fabian Groffen <grobian@g.o> +files/texmf-update-r1,
   kpathsea-6.1.1_p20130530.ebuild:



1.1                  dev-libs/kpathsea/kpathsea-6.2.0_p20140523.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/kpathsea-6.2.0_p20140523.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/kpathsea-6.2.0_p20140523.ebuild?rev=1.1&content-type=text/plain

Index: kpathsea-6.2.0_p20140523.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/kpathsea-6.2.0_p20140523.ebuild,v 1.1 2014/10/05 18:45:07 mrueg Exp $

EAPI=5

inherit texlive-common eutils libtool prefix

TEXMFD_VERSION=5
TL_VERSION=2014
TEXMF_PATH=/usr/share/texmf-dist

DESCRIPTION="Library implementing generic path searching, configuration, and TeX-specific file searching"
HOMEPAGE="http://tug.org/texlive/"
SRC_URI="mirror://gentoo/texlive-${PV#*_p}-source.tar.xz
	mirror://gentoo/${PN}-texmf.d-${TEXMFD_VERSION}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="doc source static-libs"

DEPEND="!<app-text/texlive-core-${TL_VERSION}
	!app-text/ptex"
RDEPEND="${DEPEND}"

S=${WORKDIR}/texlive-${PV#*_p}-source/texk/${PN}

EXTRA_TL_MODULES="kpathsea"
EXTRA_TL_DOC_MODULES="kpathsea.doc"

for i in ${EXTRA_TL_MODULES} ; do
	SRC_URI+=" mirror://gentoo/texlive-module-${i}-${TL_VERSION}.tar.xz"
done

SRC_URI+=" doc? ( "
for i in ${EXTRA_TL_DOC_MODULES} ; do
	SRC_URI+=" mirror://gentoo/texlive-module-${i}-${TL_VERSION}.tar.xz"
done
SRC_URI+=" )"

src_prepare() {
	cd "${WORKDIR}/texlive-${PV#*_p}-source"
	S="${WORKDIR}/texlive-${PV#*_p}-source" elibtoolize #sane .so versionning on gfbsd
	cp "${FILESDIR}/texmf-update-r1" "${S}"/texmf-update
	eprefixify "${S}"/texmf-update
}

src_configure() {
	# Too many regexps use A-Z a-z constructs, what causes problems with locales
	# that don't have the same alphabetical order than ascii. Bug #347798
	# So we set LC_ALL to C in order to avoid problems.
	export LC_ALL=C

	# Disable largefile because it seems to cause problems on big endian 32 bits
	# systems...
	econf \
		--disable-largefile \
		$(use_enable static-libs static)
}

src_install() {
	emake DESTDIR="${D}" web2cdir="${EPREFIX}/usr/share/texmf-dist/web2c" install
	find "${D}" -name '*.la' -delete || die

	dodir /usr/share # just in case
	cp -pR "${WORKDIR}"/texmf-dist "${ED}/usr/share/" || die "failed to install texmf trees"
	if use source ; then
		cp -pR "${WORKDIR}"/tlpkg "${ED}/usr/share/" || die "failed to install tlpkg files"
	fi

	# The default configuration expects it to be world writable, bug #266680
	# People can still change it with texconfig though.
	dodir /var/cache/fonts
	fperms 1777 /var/cache/fonts

	# Take care of fmtutil.cnf and texmf.cnf
	dodir /etc/texmf/{fmtutil.d,texmf.d}

	# Remove default texmf.cnf to ship our own, greatly based on texlive dvd's
	# texmf.cnf
	# It will also be generated from /etc/texmf/texmf.d files by texmf-update
	rm -f "${ED}${TEXMF_PATH}/web2c/texmf.cnf"

	insinto /etc/texmf/texmf.d
	doins "${WORKDIR}/texmf.d/"*.cnf

	# Remove fmtutil.cnf, it will be regenerated from /etc/texmf/fmtutil.d files
	# by texmf-update
	rm -f "${ED}${TEXMF_PATH}/web2c/fmtutil.cnf"

	dosym /etc/texmf/web2c/fmtutil.cnf ${TEXMF_PATH}/web2c/fmtutil.cnf
	dosym /etc/texmf/web2c/texmf.cnf ${TEXMF_PATH}/web2c/texmf.cnf

	newsbin "${S}/texmf-update" texmf-update

	# Keep it as that's where the formats will go
	keepdir /var/lib/texmf

	dodoc ChangeLog NEWS PROJECTS README
}

pkg_postinst() {
	etexmf-update
}

pkg_postrm() {
	etexmf-update
}