[gentoo-commits] gentoo-x86 commit in dev-python/sqlalchemy: ChangeLog sqlalchemy-0.5.2-r1.ebuild

[Patrick Lauer (patrick)]

patrick     09/04/01 11:45:15

  Modified:             ChangeLog
  Added:                sqlalchemy-0.5.2-r1.ebuild
  Log:
  Bump to EAPI-2 to force sqlite deps so that tests have a chance of not failing
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.26                 dev-python/sqlalchemy/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sqlalchemy/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sqlalchemy/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sqlalchemy/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	20 Mar 2009 13:15:50 -0000	1.25
+++ ChangeLog	1 Apr 2009 11:45:14 -0000	1.26
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/sqlalchemy
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.25 2009/03/20 13:15:50 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.26 2009/04/01 11:45:14 patrick Exp $
+
+*sqlalchemy-0.5.2-r1 (01 Apr 2009)
+
+  01 Apr 2009; Patrick Lauer <patrick@g.o>
+  +sqlalchemy-0.5.2-r1.ebuild:
+  Bump to EAPI-2 to force sqlite deps so that tests have a chance of not
+  failing
 
   20 Mar 2009; Joseph Jezak <josejx@g.o> sqlalchemy-0.4.7_p1.ebuild,
   sqlalchemy-0.5.2.ebuild:



1.1                  dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: sqlalchemy-0.5.2-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.5.2-r1.ebuild,v 1.1 2009/04/01 11:45:14 patrick Exp $

EAPI="2"

NEED_PYTHON=2.4

inherit distutils

MY_P=SQLAlchemy-${PV/_}

DESCRIPTION="Python SQL toolkit and Object Relational Mapper."
HOMEPAGE="http://www.sqlalchemy.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
IUSE="doc examples firebird mssql mysql postgres +sqlite test"
KEYWORDS="~amd64 ~ppc ~x86"

# note: if you use psycopg-1, then you need egenix-mx-base
RDEPEND="firebird? ( dev-python/kinterbasdb )
	mssql? ( dev-python/pymssql )
	mysql? ( dev-python/mysql-python )
	postgres? (
		|| (
			( >=dev-python/psycopg-2 )
			( <dev-python/psycopg-2 dev-python/egenix-mx-base )
		)
	)
	sqlite? (
		>=dev-db/sqlite-3.3.13
		|| ( dev-python/pysqlite >=dev-lang/python-2.5 )
	)"

DEPEND="dev-python/setuptools
	test? (
		>=dev-db/sqlite-3.3.13
		|| ( dev-python/pysqlite >=dev-lang/python-2.5[sqlite] )
	)"

S="${WORKDIR}/${MY_P}"

src_install() {
	distutils_src_install

	use doc && dohtml doc/*

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}

src_test() {
	PYTHONPATH="./test/" "${python}" test/alltests.py || die "tests failed"
}