[gentoo-commits] repo/gentoo:master commit in: xfce-extra/xfce4-screensaver/

[Michał Górny]

commit:     224404f0d9bac6bba247466a263b878e1977f01c
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 16 18:10:00 2018 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Oct 16 18:10:29 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=224404f0

xfce-extra/xfce4-screensaver: New package

New screensaver application for XFCE desktop.  Early release for true
Gentoo ricers!

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-extra/xfce4-screensaver/Manifest              |  1 +
 xfce-extra/xfce4-screensaver/metadata.xml          | 11 ++++
 .../xfce4-screensaver-0.1.0.ebuild                 | 69 ++++++++++++++++++++++
 3 files changed, 81 insertions(+)

diff --git a/xfce-extra/xfce4-screensaver/Manifest b/xfce-extra/xfce4-screensaver/Manifest
new file mode 100644
index 00000000000..38d6b8530ee
--- /dev/null
+++ b/xfce-extra/xfce4-screensaver/Manifest
@@ -0,0 +1 @@
+DIST xfce4-screensaver-0.1.0.tar.bz2 525080 BLAKE2B be1b4add2f72cf7d93bcb651852bb398c38e7d4637c03d90ea277dc3ea50147e8bca9a870b8b5fe2353fd71ad180684214cdeb0e18808f3ced234f9a03b2bf13 SHA512 a925deada7313e3d156d4b19fd38e50538e2ac429c657f9f29b727c4c20ccd83a07dafdc4fa14fca26bcc09961ee42700685097260473a5fdec8877114a8a048

diff --git a/xfce-extra/xfce4-screensaver/metadata.xml b/xfce-extra/xfce4-screensaver/metadata.xml
new file mode 100644
index 00000000000..f97bcaffd83
--- /dev/null
+++ b/xfce-extra/xfce4-screensaver/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>xfce@g.o</email>
+	</maintainer>
+	<use>
+		<flag name='consolekit'>Enable ConsoleKit support</flag>
+		<flag name='locking'>Enable screen locking support</flag>
+	</use>
+</pkgmetadata>

diff --git a/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.0.ebuild b/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.0.ebuild
new file mode 100644
index 00000000000..33e37d91f14
--- /dev/null
+++ b/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Screen saver and locker (port of MATE screensaver)"
+HOMEPAGE="https://git.xfce.org/apps/xfce4-screensaver/about/"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="consolekit +locking opengl pam systemd"
+
+# Xrandr: optional but automagic
+RDEPEND="
+	dev-libs/dbus-glib
+	>=dev-libs/glib-2.50:2
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libICE:=
+	x11-libs/libX11:=
+	x11-libs/libXScrnSaver:=
+	x11-libs/libXext:=
+	x11-libs/libXxf86misc:=
+	x11-libs/libXxf86vm:=
+	>=x11-libs/libXrandr-1.3:=
+	>=x11-libs/libxklavier-5.2:=
+	x11-misc/xscreensaver
+	>=xfce-base/garcon-0.5.0:=
+	>=xfce-base/libxfce4ui-4.12.1:=
+	>=xfce-base/libxfce4util-4.12.1:=
+	>=xfce-base/xfconf-4.12.1:=
+	consolekit? ( sys-auth/consolekit )
+	locking? (
+		pam? ( virtual/pam )
+	)
+	opengl? ( virtual/opengl )
+	systemd? ( sys-apps/systemd:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	dev-util/intltool
+	sys-apps/dbus
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		# disable docbook for now
+		ac_cv_path_XMLTO=no
+
+		# xscreensaver dirs autodetection doesn't seem to work
+		--with-xscreensaverdir=/usr/share/xscreensaver/config
+		--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+
+		$(use_with opengl libgl)
+		$(use_enable locking)
+		$(use_enable pam)
+		$(use_with consolekit console-kit)
+		$(use_with systemd)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}