[gentoo-commits] repo/gentoo:master commit in: dev-python/pycryptodome/

[Michał Górny]

commit:     adf5908c3d5441b7499f581a3d7b3ef2870f0427
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 28 16:13:18 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 28 16:18:54 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=adf5908c

dev-python/pycryptodome: Bump to 3.17.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pycryptodome/Manifest                   |  1 +
 dev-python/pycryptodome/pycryptodome-3.17.0.ebuild | 58 ++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/pycryptodome/Manifest b/dev-python/pycryptodome/Manifest
index b9c506619f7f..6920e5e656b4 100644
--- a/dev-python/pycryptodome/Manifest
+++ b/dev-python/pycryptodome/Manifest
@@ -1 +1,2 @@
 DIST pycryptodome-3.16.0.gh.tar.gz 16548063 BLAKE2B 4adf1c3027fe593e9a01eb0ea3da1f81ddcedd731a284a3f98dd02f07ba9eaa80e906bbcea1432fe64f08f0857033cfdbe43acd415fb3081718a301fbbb5ca16 SHA512 945c5bda213a08ba12a0ace8e4bf76730461f8dfce94fa426a97dfab846234ea06e121b176ae823d0f7da9316de50aafde6507a2f17efec4d4a0629d4d68d870
+DIST pycryptodome-3.17.0.gh.tar.gz 16714317 BLAKE2B a7a96ba4d10078ba4d9bc02b384c982ad7307065fd6c9118def43bebc073eccdfc11a766742e5d0207e9cce32aca2fe3da51f8a59964de8c15db6808cc2aae03 SHA512 c0a0754c0dd1d8138e8dd27c034e3f3469237eb5f205d86d0c5e2377fd7672c6ed0df9717292a73d380daaabe88c3be80b575ca1149f4c70f08d82aed0d4b39c

diff --git a/dev-python/pycryptodome/pycryptodome-3.17.0.ebuild b/dev-python/pycryptodome/pycryptodome-3.17.0.ebuild
new file mode 100644
index 000000000000..0991832e809c
--- /dev/null
+++ b/dev-python/pycryptodome/pycryptodome-3.17.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A self-contained cryptographic library for Python"
+HOMEPAGE="
+	https://www.pycryptodome.org/
+	https://github.com/Legrandin/pycryptodome/
+	https://pypi.org/project/pycryptodome/
+"
+SRC_URI="
+	https://github.com/Legrandin/pycryptodome/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2 Unlicense"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="
+	dev-libs/gmp:0=
+	>=dev-libs/libtomcrypt-1.18.2-r1:=
+"
+BDEPEND="
+	virtual/python-cffi[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	${BDEPEND}
+	!dev-python/pycrypto
+"
+
+PATCHES=(
+	"${FILESDIR}/pycryptodome-3.10.1-system-libtomcrypt.patch"
+)
+
+python_prepare_all() {
+	# make sure we're unbundling it correctly
+	rm -r src/libtom || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTHONPATH=${S}/test_vectors:${PYTHONPATH}
+	"${EPYTHON}" - <<-EOF || die
+		import sys
+		from Crypto import SelfTest
+		SelfTest.run(verbosity=2, stream=sys.stdout)
+	EOF
+}