[gentoo-commits] gentoo-x86 commit in net-misc/badvpn: ChangeLog badvpn-1.999.126.ebuild

[Julian Ospald (hasufell)]

hasufell    12/12/26 02:22:00

  Modified:             ChangeLog
  Added:                badvpn-1.999.126.ebuild
  Log:
  version bump by Ambroz Bizjak wrt #448226
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.10                 net-misc/badvpn/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	11 Dec 2012 16:56:32 -0000	1.9
+++ ChangeLog	26 Dec 2012 02:22:00 -0000	1.10
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/badvpn
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v 1.9 2012/12/11 16:56:32 axs Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v 1.10 2012/12/26 02:22:00 hasufell Exp $
+
+*badvpn-1.999.126 (26 Dec 2012)
+
+  26 Dec 2012; Julian Ospald <hasufell@g.o> +badvpn-1.999.126.ebuild:
+  version bump by Ambroz Bizjak wrt #448226
 
   11 Dec 2012; Ian Stakenvicius <axs@g.o> badvpn-1.999.123-r3.ebuild:
   virtualize udev dependency



1.1                  net-misc/badvpn/badvpn-1.999.126.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/badvpn-1.999.126.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/badvpn-1.999.126.ebuild?rev=1.1&content-type=text/plain

Index: badvpn-1.999.126.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/badvpn-1.999.126.ebuild,v 1.1 2012/12/26 02:22:00 hasufell Exp $

EAPI=5
inherit eutils cmake-utils user toolchain-funcs

MY_P=${PN}-${PV/_rc/rc}
DESCRIPTION="Peer-to-peer VPN, NCD scripting language, tun2socks proxifier"
HOMEPAGE="http://code.google.com/p/badvpn/"
SRC_URI="http://badvpn.googlecode.com/files/${MY_P}.tar.bz2"

LICENSE="BSD"
KEYWORDS="~amd64 ~arm ~x86"
SLOT="0"
TARGETS="+client +ncd +server +tun2socks +udpgw"
IUSE="${TARGETS} debug"
# tests are only ncd related
RESTRICT="!ncd? ( test )"

COMMON_DEPEND="
	client? (
		dev-libs/nspr
		dev-libs/nss
		dev-libs/openssl
	)
	server? (
		dev-libs/nspr
		dev-libs/nss
		dev-libs/openssl
	)
	ncd? (
		dev-libs/openssl
	)"
RDEPEND="${COMMON_DEPEND}
	ncd? (
		sys-apps/iproute2
		>=virtual/udev-171
	)"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"
# we need at least one target
REQUIRED_USE="|| ( ${TARGETS//+/} )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	enewuser ${PN}
}

src_prepare() {
	# allow user to easily apply patches
	epatch_user
}

src_configure() {
	local mycmakeargs=(
		-DBUILD_NOTHING_BY_DEFAULT=1
		$(cmake-utils_use_build client CLIENT)
		$(cmake-utils_use_build server SERVER)
		$(cmake-utils_use_build ncd NCD)
		$(cmake-utils_use_build tun2socks TUN2SOCKS)
		$(cmake-utils_use_build udpgw UDPGW)
	)

	cmake-utils_src_configure
}

src_test() {
	# OOHMSA: do this on portage level?
	tc-is-cross-compiler && die "these tests do not work when cross compiling!"

	einfo "Running NCD tests"
	cd "${S}"/ncd/tests || die
	bash ./run_tests "${CMAKE_BUILD_DIR}/ncd/badvpn-ncd" \
		|| die "one or more tests failed"
}

src_install() {
	cmake-utils_src_install
	dodoc ChangeLog

	if use server; then
		newinitd "${FILESDIR}"/${PN}-server.init ${PN}-server
		newconfd "${FILESDIR}"/${PN}-server.conf ${PN}-server
	fi

	if use ncd; then
		newinitd "${FILESDIR}"/${PN}-ncd.init ${PN}-ncd
		newconfd "${FILESDIR}"/${PN}-ncd.conf ${PN}-ncd
	fi
}