[gentoo-commits] gentoo-x86 commit in gnustep-base/gnustep-gui: ChangeLog gnustep-gui-0.18.0.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    10/05/10 19:01:39

  Modified:             ChangeLog
  Added:                gnustep-gui-0.18.0.ebuild
  Log:
  Stable release bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.81                 gnustep-base/gnustep-gui/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog?r1=1.80&r2=1.81

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -u -r1.80 -r1.81
--- ChangeLog	9 Mar 2010 18:43:56 -0000	1.80
+++ ChangeLog	10 May 2010 19:01:39 -0000	1.81
@@ -1,6 +1,12 @@
 # ChangeLog for gnustep-base/gnustep-gui
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog,v 1.80 2010/03/09 18:43:56 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/ChangeLog,v 1.81 2010/05/10 19:01:39 voyageur Exp $
+
+*gnustep-gui-0.18.0 (10 May 2010)
+
+  10 May 2010; Bernard Cafarelli <voyageur@g.o>
+  +gnustep-gui-0.18.0.ebuild:
+  Stable release bump
 
 *gnustep-gui-0.16.0-r1 (09 Mar 2010)
 



1.1                  gnustep-base/gnustep-gui/gnustep-gui-0.18.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-gui/gnustep-gui-0.18.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnustep-base/gnustep-gui/gnustep-gui-0.18.0.ebuild?rev=1.1&content-type=text/plain

Index: gnustep-gui-0.18.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-gui/gnustep-gui-0.18.0.ebuild,v 1.1 2010/05/10 19:01:39 voyageur Exp $

EAPI="3"

inherit gnustep-base multilib

DESCRIPTION="Library of GUI classes written in Obj-C"
HOMEPAGE="http://www.gnustep.org/"
SRC_URI="ftp://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"

KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
SLOT="0"
LICENSE="LGPL-2.1"

IUSE="jpeg gif png portaudio cups"

DEPEND="${GNUSTEP_CORE_DEPEND}
	>=gnustep-base/gnustep-base-1.20.0
	x11-libs/libXt
	>=media-libs/tiff-3
	jpeg? ( >=media-libs/jpeg-6b:0 )
	gif? ( >=media-libs/giflib-4.1 )
	png? ( >=media-libs/libpng-1.2 )
	!x86-fbsd? ( portaudio? ( =media-libs/portaudio-19* ) )
	cups? ( >=net-print/cups-1.1 )
	media-libs/audiofile
	app-text/aspell"
RDEPEND="${DEPEND}"

src_configure() {
	egnustep_env

	local myconf=
	use gif && myconf="--disable-ungif --enable-libgif"

	econf \
		--with-tiff-include="${EPREFIX}"/usr/include \
		--with-tiff-library="${EPREFIX}"/usr/$(get_libdir) \
		$(use_enable jpeg) \
		$(use_enable png) \
		$(use_enable portaudio gsnd) \
		$(use_enable cups) \
		${myconf} || die "configure failed"
}

pkg_postinst() {
	ewarn "The shared library version has changed in this release."
	ewarn "You will need to recompile all Applications/Tools/etc in order"
	ewarn "to use this library. Please run revdep-rebuild to do so"
}