[gentoo-commits] gentoo-x86 commit in net-analyzer/rrdtool: rrdtool-1.3.6.ebuild ChangeLog rrdtool-1.2.30.ebuild

[Peter Volkov (pva)]

pva         09/01/22 11:38:14

  Modified:             ChangeLog
  Added:                rrdtool-1.3.6.ebuild rrdtool-1.2.30.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc23/cvs/Linux i686)

Revision  Changes    Path
1.167                net-analyzer/rrdtool/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/rrdtool/ChangeLog?rev=1.167&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/rrdtool/ChangeLog?rev=1.167&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/rrdtool/ChangeLog?r1=1.166&r2=1.167

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/ChangeLog,v
retrieving revision 1.166
retrieving revision 1.167
diff -u -r1.166 -r1.167
--- ChangeLog	21 Dec 2008 17:53:14 -0000	1.166
+++ ChangeLog	22 Jan 2009 11:38:14 -0000	1.167
@@ -1,6 +1,13 @@
 # ChangeLog for net-analyzer/rrdtool
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/ChangeLog,v 1.166 2008/12/21 17:53:14 pva Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/ChangeLog,v 1.167 2009/01/22 11:38:14 pva Exp $
+
+*rrdtool-1.3.6 (22 Jan 2009)
+*rrdtool-1.2.30 (22 Jan 2009)
+
+  22 Jan 2009; Peter Volkov <pva@g.o> +rrdtool-1.2.30.ebuild,
+  +rrdtool-1.3.6.ebuild:
+  Version bump.
 
 *rrdtool-1.3.5 (21 Dec 2008)
 *rrdtool-1.2.29 (21 Dec 2008)



1.1                  net-analyzer/rrdtool/rrdtool-1.3.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.3.6.ebuild?rev=1.1&content-type=text/plain

Index: rrdtool-1.3.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.3.6.ebuild,v 1.1 2009/01/22 11:38:14 pva Exp $

inherit eutils flag-o-matic multilib perl-module

DESCRIPTION="A system to store and display time-series data"
HOMEPAGE="http://oss.oetiker.ch/rrdtool/"
SRC_URI="http://oss.oetiker.ch/rrdtool/pub/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc perl python ruby rrdcgi tcl"

# This versions are minimal versions upstream tested with.
RDEPEND="
	>=media-libs/libpng-1.2.10
	>=dev-libs/libxml2-2.6.31
	>=x11-libs/cairo-1.4.6
	>=dev-libs/glib-2.12.12
	>=x11-libs/pango-1.17
	tcl? ( dev-lang/tcl )
	perl? ( dev-lang/perl )
	python? ( dev-lang/python )
	ruby? ( dev-lang/ruby
			!dev-ruby/ruby-rrd )"

DEPEND="${RDEPEND}
	sys-apps/gawk"

pkg_setup() {
	if ! built_with_use x11-libs/cairo svg; then
		eerror "${PN} requires x11-libs/cairo to be built with svg USE flag."
		die "Rebuild x11-libs/cairo with svg USE flag enabled."
	fi
	use perl && perl-module_pkg_setup
}

src_compile() {
	filter-flags -ffast-math

	export RRDDOCDIR=/usr/share/doc/${PF}

	econf $(use_enable rrdcgi) \
		$(use_enable ruby) \
		$(use_enable ruby ruby-site-install) \
		$(use_enable perl) \
		$(use_enable perl perl-site-install) \
		$(use_enable tcl) \
		$(use_with tcl tcllib /usr/$(get_libdir)) \
		$(use_enable python)

	emake || die "make failed"
}

src_install() {
	# -j1 see bug #239101 for details
	emake -j1 DESTDIR="${D}" install || die "make install failed"

	if ! use doc ; then
		rm -rf "${D}"/usr/share/doc/${PF}/{html,txt}
	fi

	use perl && fixlocalpod

	dodoc CHANGES CONTRIBUTORS NEWS README THREADS TODO
}

pkg_preinst() {
	use perl && perl-module_pkg_preinst
}

pkg_postinst() {
	use perl && perl-module_pkg_postinst
	ewarn "rrdtool dump 1.3 does emit completely legal xml. Basically this means that"
	ewarn "it contains an xml header and a DOCTYPE definition. Unfortunately this"
	ewarn "causes older versions of rrdtool restore to be unhappy."
	ewarn
	ewarn "To restore a new dump with ann old rrdtool restore version, either remove"
	ewarn "the xml header and the doctype by hand (both on the first line of the dump)"
	ewarn "or use rrdtool dump --no-header."
}

pkg_prerm() {
	use perl && perl-module_pkg_prerm
}

pkg_postrm() {
	use perl && perl-module_pkg_postrm
}



1.1                  net-analyzer/rrdtool/rrdtool-1.2.30.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.2.30.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.2.30.ebuild?rev=1.1&content-type=text/plain

Index: rrdtool-1.2.30.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rrdtool/rrdtool-1.2.30.ebuild,v 1.1 2009/01/22 11:38:14 pva Exp $

inherit eutils flag-o-matic multilib perl-module

DESCRIPTION="A system to store and display time-series data"
HOMEPAGE="http://oss.oetiker.ch/rrdtool/"
SRC_URI="http://oss.oetiker.ch/rrdtool/pub/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc perl python ruby rrdcgi tcl"

RDEPEND="tcl? ( dev-lang/tcl )
	>=sys-libs/zlib-1.2.1
	>=media-libs/freetype-2.1.5
	>=media-libs/libart_lgpl-2.3.16
	>=media-libs/libpng-1.2.5
	rrdcgi? ( >=dev-libs/cgilib-0.5 )
	ruby? ( !dev-ruby/ruby-rrd )"

DEPEND="${RDEPEND}
	perl? ( dev-lang/perl )
	python? ( dev-lang/python )
	ruby? ( dev-lang/ruby )
	sys-apps/gawk"

TCLVER=""

HTMLDOC_DIR="${PF}/html"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PN}-1.2.15-newstyle-resize.patch"
}

pkg_setup() {
	use perl && perl-module_pkg_setup
}

src_compile() {
	filter-mfpmath sse
	filter-flags -ffast-math

	export RRDDOCDIR=/usr/share/doc/${PF}

	econf $(use_enable rrdcgi) \
		$(use_enable ruby) \
		$(use_enable ruby ruby-site-install) \
		$(use_enable perl) \
		$(use_enable perl perl-site-install) \
		$(use_enable tcl) \
		$(use_with tcl tcllib /usr/$(get_libdir)) \
		$(use_enable python) || die "econf failed."

	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	if ! use doc ; then
		rm -rf "${D}"/usr/share/doc/${PF}/{html,txt}
	fi

	use perl && fixlocalpod

	dodoc CHANGES CONTRIBUTORS NEWS README THREADS TODO
}

pkg_preinst() {
	use perl && perl-module_pkg_preinst
}

pkg_postinst() {
	use perl && perl-module_pkg_postinst
}

pkg_prerm() {
	use perl && perl-module_pkg_prerm
}

pkg_postrm() {
	use perl && perl-module_pkg_postrm
}