[gentoo-commits] gentoo-x86 commit in app-mobilephone/wammu: ChangeLog wammu-0.35.ebuild

[Christian Faulhammer (fauli)]

fauli       10/12/29 20:56:05

  Modified:             ChangeLog
  Added:                wammu-0.35.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.9.25/cvs/Linux i686)

Revision  Changes    Path
1.45                 app-mobilephone/wammu/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/wammu/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/wammu/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/wammu/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	10 Oct 2010 16:38:38 -0000	1.44
+++ ChangeLog	29 Dec 2010 20:56:05 -0000	1.45
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/wammu
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v 1.44 2010/10/10 16:38:38 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/ChangeLog,v 1.45 2010/12/29 20:56:05 fauli Exp $
+
+*wammu-0.35 (29 Dec 2010)
+
+  29 Dec 2010; Christian Faulhammer <fauli@g.o> +wammu-0.35.ebuild:
+  version bump
 
   10 Oct 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
   wammu-0.34.ebuild:



1.1                  app-mobilephone/wammu/wammu-0.35.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/wammu/wammu-0.35.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/wammu/wammu-0.35.ebuild?rev=1.1&content-type=text/plain

Index: wammu-0.35.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/wammu/wammu-0.35.ebuild,v 1.1 2010/12/29 20:56:05 fauli Exp $

EAPI="3"

PYTHON_DEPEND="2"

inherit distutils

DESCRIPTION="Front-end for gammu to access mobile phones easily"
HOMEPAGE="http://www.wammu.eu/"
SRC_URI="http://dl.cihar.com/wammu/v0/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="bluetooth"

RDEPEND=">=app-mobilephone/gammu-1.25.0[python]
	>=dev-python/wxpython-2.8
	bluetooth? (
		|| (
			dev-python/pybluez
			net-wireless/gnome-bluetooth
		)
	)"
DEPEND="${RDEPEND}"

# Supported languages and translated documentation
# Be sure all languages are prefixed with a single space!
MY_AVAILABLE_LINGUAS=" af bg ca cs da de el es et fi fr gl he hu id it ko nl pl pt_BR ru sk sv zh_CN zh_TW"
IUSE="${IUSE} ${MY_AVAILABLE_LINGUAS// / linguas_}"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	local lang support_linguas=no
	for lang in ${MY_AVAILABLE_LINGUAS} ; do
		if use linguas_${lang} ; then
			support_linguas=yes
			break
		fi
	done
	# install all languages when all selected LINGUAS aren't supported
	if [ "${support_linguas}" = "yes" ]; then
		for lang in ${MY_AVAILABLE_LINGUAS} ; do
			if ! use linguas_${lang} ; then
				rm -r locale/${lang} || die
			fi
		done
	fi

	python_convert_shebangs -r 2 .
}

src_compile() {
	# SKIPWXCHECK: else 'import wx' results in
	# Xlib: connection to ":0.0" refused by server
	SKIPWXCHECK=yes distutils_src_compile
}

src_install() {
	DOCS="AUTHORS FAQ"
	SKIPWXCHECK=yes distutils_src_install
}