[gentoo-commits] gentoo-x86 commit in dev-qt/qt-creator: qt-creator-2.7.1.ebuild qt-creator-2.7.0.ebuild ChangeLog

[Davide Pesavento (pesa)]

pesa        13/06/03 08:01:44

  Modified:             qt-creator-2.7.0.ebuild ChangeLog
  Added:                qt-creator-2.7.1.ebuild
  Log:
  Version bump, also fixing bug 449992.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.4                  dev-qt/qt-creator/qt-creator-2.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.0.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.0.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.0.ebuild?r1=1.3&r2=1.4

Index: qt-creator-2.7.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.0.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- qt-creator-2.7.0.ebuild	24 Apr 2013 08:25:19 -0000	1.3
+++ qt-creator-2.7.0.ebuild	3 Jun 2013 08:01:44 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.0.ebuild,v 1.3 2013/04/24 08:25:19 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.0.ebuild,v 1.4 2013/06/03 08:01:44 pesa Exp $
 
 EAPI=5
 
@@ -19,7 +19,8 @@
 else
 	MY_PV=${PV/_/-}
 	MY_P=${PN}-${MY_PV}-src
-	SRC_URI="http://releases.qt-project.org/qtcreator/${MY_PV}/${MY_P}.tar.gz"
+	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
+	SRC_URI="http://download.qt-project.org/${MY_REL}_releases/${PN/-}/${PV%.*}/${MY_PV}/${MY_P}.tar.gz"
 	S=${WORKDIR}/${MY_P}
 fi
 



1.9                  dev-qt/qt-creator/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	24 Apr 2013 08:25:19 -0000	1.8
+++ ChangeLog	3 Jun 2013 08:01:44 -0000	1.9
@@ -1,6 +1,12 @@
 # ChangeLog for dev-qt/qt-creator
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v 1.8 2013/04/24 08:25:19 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v 1.9 2013/06/03 08:01:44 pesa Exp $
+
+*qt-creator-2.7.1 (03 Jun 2013)
+
+  03 Jun 2013; Davide Pesavento <pesa@g.o> +qt-creator-2.7.1.ebuild,
+  qt-creator-2.7.0.ebuild:
+  Version bump, also fixing bug 449992.
 
   24 Apr 2013; Agostino Sarubbo <ago@g.o> qt-creator-2.7.0.ebuild:
   Add ~ppc, wrt bug #460762



1.1                  dev-qt/qt-creator/qt-creator-2.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.1.ebuild?rev=1.1&content-type=text/plain

Index: qt-creator-2.7.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/qt-creator-2.7.1.ebuild,v 1.1 2013/06/03 08:01:44 pesa Exp $

EAPI=5

PLOCALES="cs de es fr hu it ja pl ru sl uk zh_CN zh_TW"

inherit eutils l10n multilib qt4-r2

DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
HOMEPAGE="http://qt-project.org/wiki/Category:Tools::QtCreator"
LICENSE="LGPL-2.1"

if [[ ${PV} == *9999* ]]; then
	inherit git-2
	EGIT_REPO_URI="git://gitorious.org/${PN}/${PN}.git
		https://git.gitorious.org/${PN}/${PN}.git"
else
	MY_PV=${PV/_/-}
	MY_P=${PN}-${MY_PV}-src
	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
	SRC_URI="http://download.qt-project.org/${MY_REL}_releases/${PN/-}/${PV%.*}/${MY_PV}/${MY_P}.tar.gz"
	S=${WORKDIR}/${MY_P}
fi

SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"

QTC_PLUGINS=(android autotools:autotoolsprojectmanager bazaar
	clearcase cmake:cmakeprojectmanager cvs fakevim git
	madde mercurial perforce qnx subversion valgrind)
IUSE="debug doc examples test ${QTC_PLUGINS[@]%:*}"

# minimum Qt version required
QT_PV="4.8.0:4"

CDEPEND="
	=dev-libs/botan-1.10*
	>=dev-qt/qtcore-${QT_PV}[ssl]
	>=dev-qt/qtdeclarative-${QT_PV}
	>=dev-qt/qtgui-${QT_PV}
	>=dev-qt/qthelp-${QT_PV}[doc?]
	>=dev-qt/qtscript-${QT_PV}
	>=dev-qt/qtsql-${QT_PV}
	>=dev-qt/qtsvg-${QT_PV}
"
DEPEND="${CDEPEND}
	virtual/pkgconfig
	test? ( >=dev-qt/qttest-${QT_PV} )
"
RDEPEND="${CDEPEND}
	>=sys-devel/gdb-7.2[python]
	examples? ( >=dev-qt/qtdemo-${QT_PV} )
"
PDEPEND="
	autotools? ( sys-devel/autoconf )
	bazaar? ( dev-vcs/bzr )
	cmake? ( dev-util/cmake )
	cvs? ( dev-vcs/cvs )
	git? ( dev-vcs/git )
	mercurial? ( dev-vcs/mercurial )
	subversion? ( dev-vcs/subversion )
	valgrind? ( dev-util/valgrind )
"

src_prepare() {
	qt4-r2_src_prepare

	# disable unwanted plugins
	for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
		if ! use ${plugin%:*}; then
			einfo "Disabling ${plugin%:*} plugin"
			sed -i -re "/(^|SUBDIRS\s+\+=)\s+plugin_${plugin#*:}\>/d" src/plugins/plugins.pro \
				|| die "failed to disable ${plugin} plugin"
		fi
	done

	# fix translations
	sed -i -e "/^LANGUAGES =/ s:=.*:= $(l10n_get_locales):" \
		share/qtcreator/translations/translations.pro || die
}

src_configure() {
	EQMAKE4_EXCLUDE="share/qtcreator/templates/*" \
	eqmake4 qtcreator.pro \
		IDE_LIBRARY_BASENAME="$(get_libdir)" \
		IDE_PACKAGE_MODE=1 \
		TEST=$(use test && echo 1 || echo 0) \
		USE_SYSTEM_BOTAN=1
}

src_test() {
	echo ">>> Test phase [QTest]: ${CATEGORY}/${PF}"
	cd tests/auto || die
	eqmake4 IDE_LIBRARY_BASENAME="$(get_libdir)"
	emake check
}

src_install() {
	emake INSTALL_ROOT="${ED}usr" install

	dodoc dist/{changes-*,known-issues}

	# install documentation
	if use doc; then
		emake docs
		insinto /usr/share/doc/${PF}
		doins share/doc/qtcreator/qtcreator{,-dev}.qch
		docompress -x /usr/share/doc/${PF}/qtcreator{,-dev}.qch
	fi

	# install desktop file
	make_desktop_entry qtcreator 'Qt Creator' QtProject-qtcreator 'Qt;Development;IDE'
}