[gentoo-commits] gentoo-x86 commit in net-print/cups-filters: cups-filters-9999.ebuild ChangeLog cups-filters-1.0.54.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    14/06/06 22:43:10

  Modified:             cups-filters-9999.ebuild ChangeLog
  Added:                cups-filters-1.0.54.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)

Revision  Changes    Path
1.47                 net-print/cups-filters/cups-filters-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild?r1=1.46&r2=1.47

Index: cups-filters-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- cups-filters-9999.ebuild	11 May 2014 19:12:35 -0000	1.46
+++ cups-filters-9999.ebuild	6 Jun 2014 22:43:10 -0000	1.47
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.46 2014/05/11 19:12:35 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.47 2014/06/06 22:43:10 dilfridge Exp $
 
 EAPI=5
 
@@ -30,7 +30,7 @@
 	media-libs/fontconfig
 	media-libs/freetype:2
 	media-libs/lcms:2
-	>net-print/cups-1.5.9999
+	>=net-print/cups-1.7.3
 	!<=net-print/cups-1.5.9999
 	sys-devel/bc
 	sys-libs/zlib
@@ -72,7 +72,7 @@
 }
 
 src_compile() {
-	default
+	MAKEOPTS=-j1 default
 
 	if use perl; then
 		pushd "${S}/scripting/perl" > /dev/null



1.128                net-print/cups-filters/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	24 May 2014 20:33:59 -0000	1.127
+++ ChangeLog	6 Jun 2014 22:43:10 -0000	1.128
@@ -1,6 +1,12 @@
 # ChangeLog for net-print/cups-filters
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.127 2014/05/24 20:33:59 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.128 2014/06/06 22:43:10 dilfridge Exp $
+
+*cups-filters-1.0.54 (06 Jun 2014)
+
+  06 Jun 2014; Andreas K. Huettel <dilfridge@g.o>
+  +cups-filters-1.0.54.ebuild, cups-filters-9999.ebuild:
+  Version bump
 
   24 May 2014; Andreas K. Huettel <dilfridge@g.o>
   -cups-filters-1.0.43-r1.ebuild:



1.1                  net-print/cups-filters/cups-filters-1.0.54.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.54.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/cups-filters/cups-filters-1.0.54.ebuild?rev=1.1&content-type=text/plain

Index: cups-filters-1.0.54.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-1.0.54.ebuild,v 1.1 2014/06/06 22:43:10 dilfridge Exp $

EAPI=5

GENTOO_DEPEND_ON_PERL=no

inherit base eutils perl-module autotools systemd

if [[ "${PV}" == "9999" ]] ; then
	inherit bzr
	EBZR_REPO_URI="http://bzr.linuxfoundation.org/openprinting/cups-filters"
	KEYWORDS=""
else
	SRC_URI="http://www.openprinting.org/download/${PN}/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~m68k-mint"
fi
DESCRIPTION="Cups PDF filters"
HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/openprinting/pdfasstandardprintjobformat"

LICENSE="MIT GPL-2"
SLOT="0"
IUSE="dbus +foomatic jpeg perl png static-libs tiff zeroconf"

RDEPEND="
	>=app-text/ghostscript-gpl-9.09
	app-text/poppler:=[cxx,jpeg?,lcms,tiff?,xpdf-headers(+)]
	>=app-text/qpdf-3.0.2:=
	media-libs/fontconfig
	media-libs/freetype:2
	media-libs/lcms:2
	>=net-print/cups-1.7.3
	!<=net-print/cups-1.5.9999
	sys-devel/bc
	sys-libs/zlib
	dbus? ( sys-apps/dbus )
	foomatic? ( !net-print/foomatic-filters )
	jpeg? ( virtual/jpeg:0 )
	perl? ( dev-lang/perl:= )
	png? ( media-libs/libpng:0= )
	tiff? ( media-libs/tiff )
	zeroconf? ( net-dns/avahi[dbus] )
"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}/${P}-uclibc.patch"
)

src_prepare() {
	base_src_prepare
	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
	eautoreconf
}

src_configure() {
	econf \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		$(use_enable dbus) \
		$(use_enable zeroconf avahi) \
		$(use_enable static-libs static) \
		--with-fontdir="fonts/conf.avail" \
		--with-pdftops=pdftops \
		--enable-imagefilters \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_with tiff) \
		--with-rcdir=no \
 		--with-browseremoteprotocols=DNSSD,CUPS \
		--without-php
}

src_compile() {
	MAKEOPTS=-j1 default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_prep
		perl-module_src_compile
		popd > /dev/null
	fi
}

src_install() {
	default

	if use perl; then
		pushd "${S}/scripting/perl" > /dev/null
		perl-module_src_install
		fixlocalpod
		popd > /dev/null
	fi

	# workaround: some printer drivers still require pstoraster and pstopxl, bug #383831
	dosym /usr/libexec/cups/filter/gstoraster /usr/libexec/cups/filter/pstoraster
	dosym /usr/libexec/cups/filter/gstopxl /usr/libexec/cups/filter/pstopxl

	prune_libtool_files --all

	cp "${FILESDIR}"/cups-browsed.init.d "${T}"/cups-browsed || die

	if ! use zeroconf ; then
		sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${S}"/utils/cups-browsed.service || die
	fi

	if ! use foomatic ; then
		# this needs an upstream solution / configure switch
		rm -v "${ED}/usr/libexec/cups/filter/foomatic-rip" || die
		rm -v "${ED}/usr/share/man/man1/foomatic-rip.1" || die
	fi

	doinitd "${T}"/cups-browsed
	systemd_dounit "${S}/utils/cups-browsed.service"
}

pkg_postinst() {
	perl-module_pkg_postinst

	elog "This version of cups-filters includes cups-browsed, a daemon that autodiscovers"
	elog "remote queues via avahi or cups-1.5 browsing protocol and adds them to your cups"
	elog "configuration. You may want to add it to your default runlevel."

	if ! use foomatic ; then
		ewarn "You are disabling the foomatic code in cups-filters. Please do that ONLY if absolutely."
		ewarn "necessary. net-print/foomatic-filters as replacement is deprecated and unmaintained."
	fi
}