[gentoo-commits] gentoo-x86 commit in dev-db/libdbi-drivers: libdbi-drivers-0.8.3.ebuild ChangeLog libdbi-drivers-0.8.3-r1.ebuild

[Robin H. Johnson (robbat2)]

robbat2     09/10/26 07:19:33

  Modified:             libdbi-drivers-0.8.3.ebuild ChangeLog
  Added:                libdbi-drivers-0.8.3-r1.ebuild
  Log:
  Bug #289519: Fixup for Firebird compile. Bug #256411: Fix for Oracle compile. Bug #254851: USE-default for tinderbox build.
  (Portage version: 2.2_rc46/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild?r1=1.17&r2=1.18

Index: libdbi-drivers-0.8.3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild,v
retrieving revision 1.17
retrieving revision 1.18
diff -p -w -b -B -u -u -r1.17 -r1.18
--- libdbi-drivers-0.8.3.ebuild	24 Feb 2009 17:44:47 -0000	1.17
+++ libdbi-drivers-0.8.3.ebuild	26 Oct 2009 07:19:33 -0000	1.18
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild,v 1.17 2009/02/24 17:44:47 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild,v 1.18 2009/10/26 07:19:33 robbat2 Exp $
 
 inherit eutils autotools
 
@@ -27,6 +27,8 @@ S="${WORKDIR}/${MY_P}"
 src_unpack() {
 	unpack ${A}
 	epatch "${FILESDIR}"/${PN}-0.8.3-doc-build-fix.patch
+	epatch "${FILESDIR}"/${PN}-0.8.3-oracle-build-fix.patch
+	epatch "${FILESDIR}"/${PN}-0.8.3-firebird-fix.patch
 	cd "${S}"
 	eautoreconf
 }



1.49                 dev-db/libdbi-drivers/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -p -w -b -B -u -u -r1.48 -r1.49
--- ChangeLog	24 Feb 2009 17:44:47 -0000	1.48
+++ ChangeLog	26 Oct 2009 07:19:33 -0000	1.49
@@ -1,6 +1,15 @@
 # ChangeLog for dev-db/libdbi-drivers
-# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v 1.48 2009/02/24 17:44:47 armin76 Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v 1.49 2009/10/26 07:19:33 robbat2 Exp $
+
+*libdbi-drivers-0.8.3-r1 (26 Oct 2009)
+
+  26 Oct 2009; Robin H. Johnson <robbat2@g.o>
+  libdbi-drivers-0.8.3.ebuild, +libdbi-drivers-0.8.3-r1.ebuild,
+  +files/libdbi-drivers-0.8.3-firebird-fix.patch,
+  +files/libdbi-drivers-0.8.3-oracle-build-fix.patch:
+  Bug #289519: Fixup for Firebird compile. Bug #256411: Fix for Oracle
+  compile. Bug #254851: USE-default for tinderbox build.
 
   24 Feb 2009; Raúl Porcel <armin76@g.o>
   libdbi-drivers-0.8.3.ebuild:



1.1                  dev-db/libdbi-drivers/libdbi-drivers-0.8.3-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: libdbi-drivers-0.8.3-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3-r1.ebuild,v 1.1 2009/10/26 07:19:33 robbat2 Exp $

EAPI=1
inherit eutils autotools

MY_PV="${PV}-1"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="The libdbi-drivers project maintains drivers for libdbi."
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
HOMEPAGE="http://libdbi-drivers.sourceforge.net/"
LICENSE="LGPL-2.1"
DEPEND=">=dev-db/libdbi-0.8.3
		mysql? ( virtual/mysql )
		postgres? ( virtual/postgresql-server )
		sqlite? ( <dev-db/sqlite-3 )
		sqlite3? ( >=dev-db/sqlite-3 )
		!bindist? ( firebird? ( dev-db/firebird ) )
		doc? ( app-text/openjade )"

IUSE="mysql postgres sqlite oci8 firebird +sqlite3 bindist doc"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
SLOT=0
S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	epatch "${FILESDIR}"/${PN}-0.8.3-doc-build-fix.patch
	epatch "${FILESDIR}"/${PN}-0.8.3-oracle-build-fix.patch
	epatch "${FILESDIR}"/${PN}-0.8.3-firebird-fix.patch
	cd "${S}"
	eautoreconf
}

pkg_setup() {
	local drivers=""
	use mysql && drivers="${drivers} mysql"
	use postgres && drivers="${drivers} pgsql"
	use sqlite && drivers="${drivers} sqlite"
	use sqlite3 && drivers="${drivers} sqlite3"
	if use firebird; then
		if use bindist; then
			eerror "The Interbase Public License is incompatible with LGPL, see bug #200284."
			eerror "Disabling firebird in the build"
		else
			drivers="${drivers} firebird"
		fi
	fi
	if use oci8; then
		if [ -z "${ORACLE_HOME}" ]; then
			die "\$ORACLE_HOME is not set!"
		fi
		drivers="${drivers} oracle"
	fi
	# safety check
	if [ -z "${drivers// /}" ]; then
		die "No supported databases in your USE flags! (mysql, postgres, sqlite, sqlite3, oracle, firebird)"
	fi
}

src_compile() {
	local myconf=""
	# WARNING: the configure script does NOT work correctly
	# --without-$driver does NOT work
	# so do NOT use `use_with...`
	use mysql && myconf="${myconf} --with-mysql"
	use postgres && myconf="${myconf} --with-pgsql"
	use sqlite && myconf="${myconf} --with-sqlite"
	use sqlite3 && myconf="${myconf} --with-sqlite3"
	use !bindist && use firebird && myconf="${myconf} --with-firebird"
	if use oci8; then
		if [ -z "${ORACLE_HOME}" ]; then
			die "\$ORACLE_HOME is not set!"
		fi
		myconf="${myconf} --with-oracle-dir=${ORACLE_HOME} --with-oracle"
	fi

	econf $(use_enable doc docs) ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install () {
	emake install DESTDIR="${D}" || die "make install failed"
	dodoc AUTHORS ChangeLog NEWS README README.osx TODO
}
src_test() {
	if [ -z "${WANT_INTERACTIVE_TESTS}" ]; then
		ewarn "Tests disabled due to interactivity."
		ewarn "Run with WANT_INTERACTIVE_TESTS=1 if you want them."
		return 0
	fi
	einfo "Running interactive tests"
	emake check || die "Tests failed"
}